lib/Object/Remote/Logging/Router.pm

   1 package Object::Remote::Logging::Router;
   2
   3 use Moo;
   4 use Scalar::Util qw(weaken);
   5 use Sys::Hostname;
   6
   7 with 'Log::Contextual::Role::Router';
   8 with 'Object::Remote::Role::LogForwarder';
   9
  10 has _controller_package => ( is => 'rwp' );
  11 #lookup table for package names that should not
  12 #be forwarded across Object::Remote connections
  13 has _connections => ( is => 'ro', required => 1, default => sub { [] } );
  14 has _remote_metadata => ( is => 'rw' );
  15
  16 sub before_import {
  17   my ($self, $controller, $importer, $spec) = @_;
  18 }
  19
  20 sub after_import { }
  21
  22 sub _get_loggers {
  23   my ($self, %metadata) = @_;
  24   my $package = $metadata{package};
  25   my $level = $metadata{level};
  26   my $is_level = "is_$level";
  27   my $need_clean = 0;
  28   my @loggers;
  29
  30   foreach my $selector (@{$self->_connections}) {
  31     unless(defined $selector) {
  32       $need_clean = 1;
  33       next;
  34     }
  35
  36     foreach my $logger ($selector->($package, { %metadata })) {
  37       next unless defined $logger;
  38       my $method = $logger->can($is_level);
  39       next unless defined $method;
  40       next unless $logger->$method;
  41       push(@loggers, $logger);
  42     }
  43   }
  44
  45   $self->_clean_connections if $need_clean;
  46
  47   return @loggers;
  48 }
  49
  50 sub _invoke_logger {
  51   my ($self, $logger, $level_name, $content, $metadata) = @_;
  52   #Invoking the logger like this gets all available data to the
  53   #logging object with out losing any information from the structure.
  54   #This is not a backwards compatible way to invoke the loggers
  55   #but it enables a lot of flexibility in the logger.
  56   #The l-c router could have this method invoke the logger in
  57   #a backwards compatible way and router sub classes invoke
  58   #it in non-backwards compatible ways if desired
  59   $logger->$level_name($content, $metadata);
  60 }
  61
  62 sub handle_log_request {
  63   my ($self, $metadata_in, $generator, @args) = @_;
  64   my %metadata = %{$metadata_in};
  65   my $level = $metadata{level};
  66   my $package = $metadata{package};
  67   my $need_clean = 0;
  68
  69   #caller_level is useless when log forwarding is in place
  70   #so we won't tempt people with using it for now - access
  71   #to caller level will be available in the future
  72   my $caller_level = delete $metadata{caller_level};
  73   $metadata{object_remote} = $self->_remote_metadata;
  74   $metadata{timestamp} = time;
  75   $metadata{pid} = $$;
  76   $metadata{hostname} = hostname;
  77
  78   my @caller_info = caller($caller_level);
  79   $metadata{filename} = $caller_info[1];
  80   $metadata{line} = $caller_info[2];
  81
  82   @caller_info = caller($caller_level + 1);
  83   $metadata{method} = $caller_info[3];
  84   $metadata{method} =~ s/^${package}::// if defined $metadata{method};
  85
  86   foreach my $logger ($self->_get_loggers(%metadata)) {
  87     $self->_invoke_logger($logger, $level, [ $generator->(@args) ], \%metadata);
  88   }
  89 }
  90
  91 sub connect {
  92   my ($self, $destination, $is_weak) = @_;
  93   my $wrapped;
  94
  95   if (ref($destination) ne 'CODE') {
  96     $wrapped = sub { $destination };
  97   } else {
  98     $wrapped = $destination;
  99   }
 100
 101   push(@{$self->_connections}, $wrapped);
 102   weaken($self->_connections->[-1]) if $is_weak;
 103 }
 104
 105 sub _clean_connections {
 106   my ($self) = @_;
 107   @{$self->{_connections}} = grep { defined } @{$self->{_connections}};
 108 }
 109
 110 1;