lib/Object/Remote/Logging/Router.pm

   1 package Object::Remote::Logging::Router;
   2
   3 use Moo;
   4 use Scalar::Util qw(weaken);
   5
   6 with 'Log::Contextual::Role::Router';
   7 with 'Object::Remote::Role::LogForwarder';
   8
   9 has _controller_package => ( is => 'rwp' );
  10 #lookup table for package names that should not
  11 #be forwarded across Object::Remote connections
  12 has _connections => ( is => 'ro', required => 1, default => sub { [] } );
  13 has _remote_metadata => ( is => 'rw' );
  14
  15 sub before_import {
  16   my ($self, $controller, $importer, $spec) = @_;
  17 }
  18
  19 sub after_import { }
  20
  21 sub _get_loggers {
  22   my ($self, %metadata) = @_;
  23   my $package = $metadata{package};
  24   my $level = $metadata{level};
  25   my $is_level = "is_$level";
  26   my $need_clean = 0;
  27   my @loggers;
  28
  29   foreach my $selector (@{$self->_connections}) {
  30     unless(defined $selector) {
  31       $need_clean = 1;
  32       next;
  33     }
  34
  35     foreach my $logger ($selector->($package, { %metadata })) {
  36       next unless defined $logger;
  37       my $method = $logger->can($is_level);
  38       next unless defined $method;
  39       next unless $logger->$method;
  40       push(@loggers, $logger);
  41     }
  42   }
  43
  44   $self->_clean_connections if $need_clean;
  45
  46   return @loggers;
  47 }
  48
  49 sub _invoke_logger {
  50   my ($self, $logger, $level_name, $content, $metadata) = @_;
  51   #Invoking the logger like this gets all available data to the
  52   #logging object with out losing any information from the structure.
  53   #This is not a backwards compatible way to invoke the loggers
  54   #but it enables a lot of flexibility in the logger.
  55   #The l-c router could have this method invoke the logger in
  56   #a backwards compatible way and router sub classes invoke
  57   #it in non-backwards compatible ways if desired
  58   $logger->$level_name($content, $metadata);
  59 }
  60
  61 sub handle_log_request {
  62   my ($self, $metadata_in, $generator, @args) = @_;
  63   my %metadata = %{$metadata_in};
  64   my $level = $metadata{level};
  65   my $package = $metadata{package};
  66   my $need_clean = 0;
  67
  68   #caller_level is useless when log forwarding is in place
  69   #so we won't tempt people with using it for now - access
  70   #to caller level will be available in the future
  71   my $caller_level = delete $metadata{caller_level};
  72   $metadata{object_remote} = $self->_remote_metadata;
  73   $metadata{timestamp} = time;
  74
  75   my @caller_info = caller($caller_level);
  76   $metadata{filename} = $caller_info[1];
  77   $metadata{line} = $caller_info[2];
  78
  79   @caller_info = caller($caller_level + 1);
  80   $metadata{method} = $caller_info[3];
  81   $metadata{method} =~ s/^${package}::// if defined $metadata{method};
  82
  83   foreach my $logger ($self->_get_loggers(%metadata)) {
  84     $self->_invoke_logger($logger, $level, [ $generator->(@args) ], \%metadata);
  85   }
  86 }
  87
  88 sub connect {
  89   my ($self, $destination, $is_weak) = @_;
  90   my $wrapped;
  91
  92   if (ref($destination) ne 'CODE') {
  93     $wrapped = sub { $destination };
  94   } else {
  95     $wrapped = $destination;
  96   }
  97
  98   push(@{$self->_connections}, $wrapped);
  99   weaken($self->_connections->[-1]) if $is_weak;
 100 }
 101
 102 sub _clean_connections {
 103   my ($self) = @_;
 104   @{$self->{_connections}} = grep { defined } @{$self->{_connections}};
 105 }
 106
 107 1;