lib/Object/Remote/Handle.pm

   1 package Object::Remote::Handle;
   2
   3 use Object::Remote::Proxy;
   4 use Scalar::Util qw(weaken blessed);
   5 use Object::Remote::Future;
   6 use Module::Runtime qw(use_module);
   7 use Moo;
   8
   9 has connection => (
  10   is => 'ro', required => 1,
  11   coerce => sub {
  12     blessed($_[0])
  13       ? $_[0]
  14       : use_module('Object::Remote::Connection')->new_from_spec($_[0])
  15   },
  16 );
  17
  18 has id => (is => 'rwp');
  19
  20 has disarmed_free => (is => 'rwp');
  21
  22 sub disarm_free { $_[0]->_set_disarmed_free(1); $_[0] }
  23
  24 sub proxy {
  25   bless({ remote => $_[0], method => 'call' }, 'Object::Remote::Proxy');
  26 }
  27
  28 sub BUILD {
  29   my ($self, $args) = @_;
  30   if ($self->id) {
  31     $self->disarm_free;
  32   } else {
  33     die "No id supplied and no class either" unless $args->{class};
  34     ref($_) eq 'HASH' and $_ = [ %$_ ] for $args->{args};
  35     $self->_set_id(
  36       await_future(
  37         $self->connection->send_class_call(
  38           0, $args->{class},
  39           $args->{constructor}||'new', @{$args->{args}||[]}
  40         )
  41       )->{remote}->disarm_free->id
  42     );
  43   }
  44   $self->connection->register_remote($self);
  45 }
  46
  47 sub call {
  48   my ($self, $method, @args) = @_;
  49   my $w = wantarray;
  50   $method = "start::${method}" if (caller(0)||'') eq 'start';
  51   future {
  52     $self->connection->send(call => $self->id, $w, $method, @args)
  53   };
  54 }
  55
  56 sub call_discard {
  57   my ($self, $method, @args) = @_;
  58   $self->connection->send_discard(call => $self->id, $method, @args);
  59 }
  60
  61 sub call_discard_free {
  62   my ($self, $method, @args) = @_;
  63   $self->disarm_free;
  64   $self->connection->send_discard(call_free => $self->id, $method, @args);
  65 }
  66
  67 sub DEMOLISH {
  68   my ($self, $gd) = @_;
  69   return if $gd or $self->disarmed_free;
  70   $self->connection->send_free($self->id);
  71 }
  72
  73 1;