lib/Object/Remote/Handle.pm

   1 package Object::Remote::Handle;
   2
   3 use Object::Remote::Proxy;
   4 use Scalar::Util qw(weaken blessed);
   5 use Object::Remote::Logging qw ( :log :dlog router );
   6 use Object::Remote::Future;
   7 #must find way to exclude certain log events
   8 #from being forwarded - log events generated in
   9 #response to log events cause exploding
  10 #use Object::Remote::Logging qw(:log);
  11 use Module::Runtime qw(use_module);
  12 use Moo;
  13
  14 BEGIN { router()->exclude_forwarding }
  15
  16 has connection => (
  17   is => 'ro', required => 1,
  18   coerce => sub {
  19     blessed($_[0])
  20       ? $_[0]
  21       : use_module('Object::Remote::Connection')->new_from_spec($_[0])
  22   },
  23 );
  24
  25 has id => (is => 'rwp');
  26
  27 has disarmed_free => (is => 'rwp');
  28
  29 sub disarm_free { $_[0]->_set_disarmed_free(1); $_[0] }
  30
  31 sub proxy {
  32   bless({ remote => $_[0], method => 'call' }, 'Object::Remote::Proxy');
  33 }
  34
  35 sub BUILD {
  36   my ($self, $args) = @_;
  37   log_trace { "constructing remote handle" };
  38   if ($self->id) {
  39     log_trace { "disarming free for this handle" };
  40     $self->disarm_free;
  41   } else {
  42     die "No id supplied and no class either" unless $args->{class};
  43     ref($_) eq 'HASH' and $_ = [ %$_ ] for $args->{args};
  44     log_trace { "fetching id for handle and disarming free on remote side" };
  45     $self->_set_id(
  46       await_future(
  47         $self->connection->send_class_call(
  48           0, $args->{class},
  49           $args->{constructor}||'new', @{$args->{args}||[]}
  50         )
  51       )->{remote}->disarm_free->id
  52     );
  53   }
  54   Dlog_trace { "finished constructing remote handle; id is $_" } $self->id;
  55   $self->connection->register_remote($self);
  56 }
  57
  58 sub call {
  59   my ($self, $method, @args) = @_;
  60   my $w = wantarray;
  61   log_trace { my $def = defined $w ? 1 : 0; "call() has been invoked on a remote handle; wantarray: '$def'" };
  62   $method = "start::${method}" if (caller(0)||'') eq 'start';
  63   future {
  64     $self->connection->send(call => $self->id, $w, $method, @args)
  65   };
  66 }
  67
  68 sub call_discard {
  69   my ($self, $method, @args) = @_;
  70   log_trace { "invoking send_discard() with 'call' for method '$method' on connection for remote handle" };
  71   $self->connection->send_discard(call => $self->id, $method, @args);
  72 }
  73
  74 sub call_discard_free {
  75   my ($self, $method, @args) = @_;
  76   $self->disarm_free;
  77   log_trace { "invoking send_discard() with 'call_free' for method '$method' on connection for remote handle" };
  78   $self->connection->send_discard(call_free => $self->id, $method, @args);
  79 }
  80
  81 sub DEMOLISH {
  82   my ($self, $gd) = @_;
  83   Dlog_trace { "Demolishing remote handle $_" } $self->id;
  84   return if $gd or $self->disarmed_free;
  85   $self->connection->send_free($self->id);
  86 }
  87
  88 1;