lib/Object/Remote/Future.pm

   1 package Object::Remote::Future;
   2
   3 use strict;
   4 use warnings;
   5 use base qw(Exporter);
   6
   7 use CPS::Future;
   8
   9 our @EXPORT = qw(future await_future await_all);
  10
  11 sub future (&) {
  12   my $f = $_[0]->(CPS::Future->new);
  13   return $f if ((caller(1)||'') eq 'start');
  14   await_future($f);
  15 }
  16
  17 sub await_future {
  18   my $f = shift;
  19   return $f if $f->is_ready;
  20   require Object::Remote;
  21   my $loop = Object::Remote->current_loop;
  22   $f->on_ready(sub { $loop->stop });
  23   $loop->run;
  24   return wantarray ? $f->get : ($f->get)[0];
  25 }
  26
  27 sub await_all {
  28   await_future(CPS::Future->needs_all(@_));
  29   map $_->get, @_;
  30 }
  31
  32 package start;
  33
  34 sub AUTOLOAD {
  35   my $invocant = shift;
  36   my ($method) = our $AUTOLOAD =~ /^start::(.+)$/;
  37   if (ref($invocant) eq 'ARRAY') {
  38     return [ map $_->${\"start::${method}"}, @$invocant ];
  39   }
  40   my $res;
  41   unless (eval { $res = $invocant->$method(@_); 1 }) {
  42     my $f = CPS::Future->new;
  43     $f->fail($@);
  44     return $f;
  45   }
  46   unless (Scalar::Util::blessed($res) and $res->isa('CPS::Future')) {
  47     my $f = CPS::Future->new;
  48     $f->done($res);
  49     return $f;
  50   }
  51   return $res;
  52 }
  53
  54 1;