lib/Object/Remote/FatNode.pm

   1 package Object::Remote::FatNode;
   2
   3 use strictures 1;
   4 use Config;
   5 use B qw(perlstring);
   6
   7 my @exclude_mods = qw(XSLoader.pm DynaLoader.pm);
   8
   9 sub stripspace {
  10   my ($text) = @_;
  11   $text =~ /^(\s+)/ && $text =~ s/^$1//mg;
  12   $text;
  13 }
  14
  15 my %maybe_libs = map +($_ => 1), grep defined, (values %Config, '.');
  16
  17 my @extra_libs = grep not(ref($_) or $maybe_libs{$_}), @INC;
  18
  19 my $extra_libs = join '', map "  -I$_\n", @extra_libs;
  20
  21 my $command = qq(
  22   $^X
  23   $extra_libs
  24   -mObject::Remote
  25   -mObject::Remote::Connector::STDIO
  26   -mCPS::Future
  27   -mMRO::Compat
  28   -mClass::C3
  29   -mClass::C3::next
  30   -mAlgorithm::C3
  31   -mObject::Remote::ModuleLoader
  32   -mObject::Remote::Node
  33   -mMethod::Generate::BuildAll
  34   -mMethod::Generate::DemolishAll
  35   -mJSON::PP
  36   -e 'print join "\\n", \%INC'
  37 );
  38
  39 $command =~ s/\n/ /g;
  40
  41 chomp(my @inc = qx($command));
  42
  43 my %exclude = map { $_ => 1 } @exclude_mods;
  44 my %mods = reverse @inc;
  45
  46 foreach(keys(%mods)) {
  47   if ($exclude{ $mods{$_} }) {
  48     delete($mods{$_});
  49   }
  50 }
  51
  52 sub filter_not_core {
  53   not (
  54     /^\Q$Config{privlibexp}/ or /^\Q$Config{archlibexp}/
  55   )
  56 }
  57
  58 my @file_names = keys %mods;
  59 my @before_inc = grep { filter_not_core() } @file_names;
  60 my @after_inc;
  61
  62 my $start = stripspace <<'END_START';
  63   # This chunk of stuff was generated by Object::Remote::FatNode. To find
  64   # the original file's code, look for the end of this BEGIN block or the
  65   # string 'FATPACK'
  66   BEGIN {
  67   my (%fatpacked,%fatpacked_extra);
  68 END_START
  69
  70 $start .= 'my %exclude = map { $_ => 1 } (\'' . join("','", @exclude_mods) . "');\n";
  71
  72 my $end = stripspace <<'END_END';
  73   s/^  //mg for values %fatpacked, values %fatpacked_extra;
  74
  75   sub load_from_hash {
  76     if (my $fat = $_[0]->{$_[1]}) {
  77       if ($exclude{$_[1]}) {
  78         warn "Will not pre-load '$_[1]'";
  79         return undef;
  80       }
  81
  82       #warn "Handling $_[1]";
  83       open my $fh, '<', \$fat;
  84       return $fh;
  85     }
  86
  87     #Uncomment this to find brokenness
  88     #warn "Missing $_[1]";
  89     return;
  90   }
  91
  92   unshift @INC, sub { load_from_hash(\%fatpacked, $_[1]) };
  93   push @INC, sub { load_from_hash(\%fatpacked_extra, $_[1]) };
  94
  95   } # END OF FATPACK CODE
  96
  97   use strictures 1;
  98   use Object::Remote::Node;
  99   Object::Remote::Node->run;
 100 END_END
 101
 102 my %files = map +($mods{$_} => scalar do { local (@ARGV, $/) = ($_); <> }),
 103               @before_inc, @after_inc;
 104
 105 sub generate_fatpack_hash {
 106   my ($hash_name, $orig) = @_;
 107   (my $stub = $orig) =~ s/\.pm$//;
 108   my $name = uc join '_', split '/', $stub;
 109   my $data = $files{$orig} or die $orig; $data =~ s/^/  /mg;
 110   return '$'.$hash_name.'{'.perlstring($orig).qq!} = <<'${name}';\n!
 111   .qq!${data}${name}\n!;
 112 }
 113
 114 my @segments = (
 115   map(generate_fatpack_hash('fatpacked', $_), sort map $mods{$_}, @before_inc),
 116   map(generate_fatpack_hash('fatpacked_extra', $_), sort map $mods{$_}, @after_inc),
 117 );
 118
 119 our $DATA = join "\n", $start, @segments, $end;
 120
 121 1;