lib/Object/Remote/FatNode.pm

   1 package Object::Remote::FatNode;
   2
   3 use strictures 1;
   4 use Config;
   5 use B qw(perlstring);
   6
   7 sub stripspace {
   8   my ($text) = @_;
   9   $text =~ /^(\s+)/ && $text =~ s/^$1//mg;
  10   $text;
  11 }
  12
  13 my %maybe_libs = map +($_ => 1), grep defined, (values %Config, '.');
  14
  15 my @extra_libs = grep not(ref($_) or $maybe_libs{$_}), @INC;
  16
  17 my $extra_libs = join '', map "  -I$_\n", @extra_libs;
  18
  19 my $command = qq(
  20   $^X
  21   $extra_libs
  22   -mObject::Remote
  23   -mObject::Remote::Connector::STDIO
  24   -mCPS::Future
  25   -mMRO::Compat
  26   -mClass::C3
  27   -mClass::C3::next
  28   -mAlgorithm::C3
  29   -mObject::Remote::ModuleLoader
  30   -mObject::Remote::Node
  31   -mMethod::Generate::BuildAll
  32   -mMethod::Generate::DemolishAll
  33   -mJSON::PP
  34   -e 'print join "\\n", \%INC'
  35 );
  36
  37 $command =~ s/\n/ /g;
  38
  39 chomp(my @inc = qx($command));
  40
  41 my %mods = reverse @inc;
  42
  43 my @non_core = grep +(
  44   not (
  45     /^\Q$Config{privlibexp}/ or /^\Q$Config{archlibexp}/
  46   )
  47 ), keys %mods;
  48
  49 my @core_non_arch = grep +(
  50   /^\Q$Config{privlibexp}/
  51 ), grep !/\Q$Config{archname}/, grep !/\Q$Config{myarchname}/, keys %mods;
  52
  53 my $start = stripspace <<'END_START';
  54   # This chunk of stuff was generated by Object::Remote::FatNode. To find
  55   # the original file's code, look for the end of this BEGIN block or the
  56   # string 'FATPACK'
  57   BEGIN {
  58   my (%fatpacked,%fatpacked_extra);
  59 END_START
  60 my $end = stripspace <<'END_END';
  61   s/^  //mg for values %fatpacked, values %fatpacked_extra;
  62
  63   sub load_from_hash {
  64     if (my $fat = $_[0]->{$_[1]}) {
  65       open my $fh, '<', \$fat;
  66       return $fh;
  67     }
  68     #Uncomment this to find brokenness
  69     #warn "Missing $_[1]";
  70     return
  71   }
  72
  73   unshift @INC, sub { load_from_hash(\%fatpacked, $_[1]) };
  74   push @INC, sub { load_from_hash(\%fatpacked_extra, $_[1]) };
  75
  76   } # END OF FATPACK CODE
  77
  78   use strictures 1;
  79   use Object::Remote::Node;
  80   Object::Remote::Node->run;
  81 END_END
  82
  83 my %files = map +($mods{$_} => scalar do { local (@ARGV, $/) = ($_); <> }),
  84               @non_core, @core_non_arch;
  85
  86 sub generate_fatpack_hash {
  87   my ($hash_name, $orig) = @_;
  88   (my $stub = $orig) =~ s/\.pm$//;
  89   my $name = uc join '_', split '/', $stub;
  90   my $data = $files{$orig} or die $orig; $data =~ s/^/  /mg;
  91   return '$'.$hash_name.'{'.perlstring($orig).qq!} = <<'${name}';\n!
  92   .qq!${data}${name}\n!;
  93 }
  94
  95 my @segments = (
  96   map(generate_fatpack_hash('fatpacked', $_), sort map $mods{$_}, @non_core),
  97   map(generate_fatpack_hash('fatpacked_extra', $_), sort map $mods{$_}, @core_non_arch),
  98 );
  99
 100 our $DATA = join "\n", $start, @segments, $end;
 101
 102 1;