lib/Object/Remote/FatNode.pm

   1 package Object::Remote::FatNode;
   2
   3 use strictures 1;
   4 use Config;
   5 use B qw(perlstring);
   6
   7 my @exclude_mods = qw(XSLoader.pm DynaLoader.pm);
   8
   9 sub stripspace {
  10   my ($text) = @_;
  11   $text =~ /^(\s+)/ && $text =~ s/^$1//mg;
  12   $text;
  13 }
  14
  15 my %maybe_libs = map +($_ => 1), grep defined, (values %Config, '.');
  16
  17 my @extra_libs = grep not(ref($_) or $maybe_libs{$_}), @INC;
  18
  19 my $extra_libs = join '', map "  -I$_\n", @extra_libs;
  20
  21 my $command = qq(
  22   $^X
  23   $extra_libs
  24   -mObject::Remote
  25   -mObject::Remote::Connector::STDIO
  26   -mCPS::Future
  27   -mMRO::Compat
  28   -mClass::C3
  29   -mClass::C3::next
  30   -mAlgorithm::C3
  31   -mObject::Remote::ModuleLoader
  32   -mObject::Remote::Node
  33   -mMethod::Generate::BuildAll
  34   -mMethod::Generate::DemolishAll
  35   -mJSON::PP
  36   -e 'print join "\\n", \%INC'
  37 );
  38
  39 $command =~ s/\n/ /g;
  40
  41 chomp(my @inc = qx($command));
  42
  43 my %exclude = map { $_ => 1 } @exclude_mods;
  44 my %mods = reverse @inc;
  45
  46 foreach(keys(%mods)) {
  47   if ($exclude{ $mods{$_} }) {
  48     delete($mods{$_});
  49   }
  50 }
  51
  52 sub filter_not_core {
  53   not (
  54     /^\Q$Config{privlibexp}/ or /^\Q$Config{archlibexp}/
  55   )
  56 }
  57
  58 my @before_inc = grep { filter_not_core() } keys %mods;
  59 my @after_inc;
  60
  61 my $start = stripspace <<'END_START';
  62   # This chunk of stuff was generated by Object::Remote::FatNode. To find
  63   # the original file's code, look for the end of this BEGIN block or the
  64   # string 'FATPACK'
  65   BEGIN {
  66   my (%fatpacked,%fatpacked_extra);
  67 END_START
  68
  69 $start .= 'my %exclude = map { $_ => 1 } qw(' . join(' ', @exclude_mods) . ");\n";
  70
  71 my $end = stripspace <<'END_END';
  72   s/^  //mg for values %fatpacked, values %fatpacked_extra;
  73
  74   sub load_from_hash {
  75     if (my $fat = $_[0]->{$_[1]}) {
  76       if ($exclude{$_[1]}) {
  77         warn "Will not pre-load '$_[1]'";
  78         return undef;
  79       }
  80
  81       warn "handling $_[1]";
  82       open my $fh, '<', \$fat;
  83       return $fh;
  84     }
  85
  86     #Uncomment this to find brokenness
  87     #warn "Missing $_[1]";
  88     return;
  89   }
  90
  91   unshift @INC, sub { load_from_hash(\%fatpacked, $_[1]) };
  92   push @INC, sub { load_from_hash(\%fatpacked_extra, $_[1]) };
  93
  94   } # END OF FATPACK CODE
  95
  96   use strictures 1;
  97   use Object::Remote::Node;
  98   Object::Remote::Node->run;
  99 END_END
 100
 101 my %files = map +($mods{$_} => scalar do { local (@ARGV, $/) = ($_); <> }),
 102               @before_inc, @after_inc;
 103
 104 sub generate_fatpack_hash {
 105   my ($hash_name, $orig) = @_;
 106   (my $stub = $orig) =~ s/\.pm$//;
 107   my $name = uc join '_', split '/', $stub;
 108   my $data = $files{$orig} or die $orig; $data =~ s/^/  /mg;
 109   return '$'.$hash_name.'{'.perlstring($orig).qq!} = <<'${name}';\n!
 110   .qq!${data}${name}\n!;
 111 }
 112
 113 my @segments = (
 114   map(generate_fatpack_hash('fatpacked', $_), sort map $mods{$_}, @before_inc),
 115   map(generate_fatpack_hash('fatpacked_extra', $_), sort map $mods{$_}, @after_inc),
 116 );
 117
 118 our $DATA = join "\n", $start, @segments, $end;
 119
 120 1;