lib/Object/Remote/Connector/SSH.pm

   1 package Object::Remote::Connector::SSH;
   2
   3 use Object::Remote::ModuleSender;
   4 use Object::Remote::Handle;
   5 use Moo;
   6
   7 with 'Object::Remote::Role::Connector::PerlInterpreter';
   8
   9 has ssh_to => (is => 'ro', required => 1);
  10
  11 has ssh_perl_command => (is => 'lazy');
  12
  13 has ssh_options => (is => 'ro', default => sub { [ '-A' ] });
  14
  15 has ssh_command => (is => 'ro', default => sub { 'ssh' });
  16
  17 #TODO properly integrate if this works
  18 BEGIN { $ENV{TERM} = 'dumb'; }
  19
  20 sub _build_ssh_perl_command {
  21   my ($self) = @_;
  22   return [
  23     do { my $c = $self->ssh_command; ref($c) ? @$c : $c },
  24     @{$self->ssh_options}, $self->ssh_to,
  25     @{$self->perl_command}
  26   ];
  27 }
  28
  29 sub final_perl_command { shift->ssh_perl_command }
  30
  31 no warnings 'once';
  32
  33 push @Object::Remote::Connection::Guess, sub {
  34   for ($_[0]) {
  35     # 0-9 a-z _ - first char, those or . subsequent - hostnamish
  36     if (defined and !ref and /^(?:.*?\@)?[\w\-][\w\-\.]/) {
  37       my $host = shift(@_);
  38       return __PACKAGE__->new(@_, ssh_to => $host);
  39     }
  40   }
  41   return;
  42 };
  43
  44 1;