lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote::Handle;
   6 use Object::Remote;
   7 use IO::Handle;
   8 use Module::Runtime qw(use_module);
   9 use Scalar::Util qw(weaken blessed refaddr);
  10 use JSON::PP qw(encode_json);
  11 use Moo;
  12
  13 our $DEBUG;
  14
  15 has send_to_fh => (
  16   is => 'ro', required => 1,
  17   trigger => sub { $_[1]->autoflush(1) },
  18 );
  19
  20 has receive_from_fh => (
  21   is => 'ro', required => 1,
  22   trigger => sub {
  23     my ($self, $fh) = @_;
  24     weaken($self);
  25     Object::Remote->current_loop
  26                   ->watch_io(
  27                       handle => $fh,
  28                       on_read_ready => sub { $self->_receive_data_from($fh) }
  29                     );
  30   },
  31 );
  32
  33 has on_close => (is => 'rw', default => sub {});
  34
  35 has child_pid => (is => 'ro');
  36
  37 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  38
  39 has local_objects_by_id => (is => 'ro', default => sub { {} });
  40
  41 has remote_objects_by_id => (is => 'ro', default => sub { {} });
  42
  43 has _json => (
  44   is => 'lazy',
  45   handles => {
  46     _deserialize => 'decode',
  47     _encode => 'encode',
  48   },
  49 );
  50
  51 sub _build__json {
  52   weaken(my $self = shift);
  53   my $remotes = $self->remote_objects_by_id;
  54   JSON::PP->new->filter_json_single_key_object(
  55     __remote_object__ => sub {
  56       my $id = shift;
  57       return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  58       (
  59         $remotes->{$id}
  60         or Object::Remote::Handle->new(connection => $self, id => $id)
  61       )->proxy;
  62     }
  63   );
  64 }
  65
  66 BEGIN {
  67   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
  68   eval { require Object::Remote::Connector::Local };
  69   eval { require Object::Remote::Connector::SSH };
  70 }
  71
  72 sub new_from_spec {
  73   my ($class, $spec) = @_;
  74   foreach my $poss (do { our @Guess }) {
  75     if (my $obj = $poss->($spec)) { return $obj }
  76   }
  77   die "Couldn't figure out what to do with ${spec}";
  78 }
  79
  80 sub register_remote {
  81   my ($self, $remote) = @_;
  82   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
  83   return $remote;
  84 }
  85
  86 sub send_free {
  87   my ($self, $id) = @_;
  88   delete $self->remote_objects_by_id->{$id};
  89   $self->_send([ free => $id ]);
  90 }
  91
  92 sub send {
  93   my ($self, $type, @call) = @_;
  94
  95   unshift @call, $type => my $future = CPS::Future->new;
  96
  97   $self->_send(\@call);
  98
  99   return $future;
 100 }
 101
 102 sub send_discard {
 103   my ($self, $type, @call) = @_;
 104
 105   unshift @call, $type => { __remote_object__ => 'NULL' };
 106
 107   $self->_send(\@call);
 108 }
 109
 110 sub _send {
 111   my ($self, $to_send) = @_;
 112
 113   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
 114 }
 115
 116 sub _serialize {
 117   my ($self, $data) = @_;
 118   local our @New_Ids;
 119   return eval {
 120     my $flat = $self->_encode($self->_deobjectify($data));
 121     warn "$$ >>> ${flat}\n" if $DEBUG;
 122     $flat;
 123   } or do {
 124     my $err = $@; # won't get here if the eval doesn't die
 125     # don't keep refs to new things
 126     delete @{$self->local_objects_by_id}{@New_Ids};
 127     die "Error serializing: $err";
 128   };
 129 }
 130
 131 sub _deobjectify {
 132   my ($self, $data) = @_;
 133   if (blessed($data)) {
 134     my $id = refaddr($data);
 135     $self->local_objects_by_id->{$id} ||= do {
 136       push our(@New_Ids), $id;
 137       $data;
 138     };
 139     return +{ __remote_object__ => $id };
 140   } elsif (my $ref = ref($data)) {
 141     if ($ref eq 'HASH') {
 142       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 143     } elsif ($ref eq 'ARRAY') {
 144       return [ map $self->_deobjectify($_), @$data ];
 145     } else {
 146       die "Can't collapse reftype $ref";
 147     }
 148   }
 149   return $data; # plain scalar
 150 }
 151
 152 sub _receive_data_from {
 153   my ($self, $fh) = @_;
 154   my $rb = $self->_receive_data_buffer;
 155   if (sysread($fh, $$rb, 1024, length($$rb)) > 0) {
 156     while ($$rb =~ s/^(.*)\n//) {
 157       $self->_receive($1);
 158     }
 159   } else {
 160     $self->on_close->done();
 161   }
 162 }
 163
 164 sub _receive {
 165   my ($self, $flat) = @_;
 166   warn "$$ <<< $flat\n" if $DEBUG;
 167   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 168     or do { warn "Deserialize failed for ${flat}: $@"; return };
 169   eval { $self->${\"receive_${type}"}(@rest); 1 }
 170     or do { warn "Receive failed for ${flat}: $@"; return };
 171   return;
 172 }
 173
 174 sub receive_free {
 175   my ($self, $id) = @_;
 176   delete $self->local_objects_by_id->{$id}
 177     or warn "Free: no such object $id";
 178   return;
 179 }
 180
 181 sub receive_call {
 182   my ($self, $future, $id, @rest) = @_;
 183   $future->{method} = 'call_discard_free';
 184   my $local = $self->local_objects_by_id->{$id}
 185     or do { $future->fail("No such object $id"); return };
 186   $self->_invoke($future, $local, @rest);
 187 }
 188
 189 sub receive_call_free {
 190   my ($self, $future, $id, @rest) = @_;
 191   $self->receive_call($future, $id, undef, @rest);
 192   $self->receive_free($id);
 193 }
 194
 195 sub receive_class_call {
 196   my ($self, $future, $class, @rest) = @_;
 197   $future->{method} = 'call_discard_free';
 198   eval { use_module($class) }
 199     or do { $future->fail("Error loading ${class}: $@"); return };
 200   $self->_invoke($future, $class, @rest);
 201 }
 202
 203 sub _invoke {
 204   my ($self, $future, $local, $ctx, $method, @args) = @_;
 205   if ($method =~ /^start::/) {
 206     my $f = $local->$method(@args);
 207     $f->on_done(sub { undef($f); $future->done(@_) });
 208     return unless $f;
 209     $f->on_fail(sub { undef($f); $future->fail(@_) });
 210     return;
 211   }
 212   my $do = sub { $local->$method(@args) };
 213   eval {
 214     $future->done(
 215       defined($ctx)
 216         ? ($ctx ? $do->() : scalar($do->()))
 217         : do { $do->(); () }
 218     );
 219     1;
 220   } or do { $future->fail($@); return; };
 221   return;
 222 }
 223
 224 sub DEMOLISH {
 225   my ($self, $gd) = @_;
 226   return if $gd;
 227   Object::Remote->current_loop
 228                 ->unwatch_io(
 229                     handle => $self->receive_from_fh,
 230                     on_read_ready => 1
 231                   );
 232 }
 233
 234 1;