lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use CPS::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote;
   6 use IO::Handle;
   7 use Module::Runtime qw(use_module);
   8 use Scalar::Util qw(weaken blessed refaddr);
   9 use JSON::PP qw(encode_json);
  10 use Moo;
  11
  12 our $DEBUG;
  13
  14 has send_to_fh => (
  15   is => 'ro', required => 1,
  16   trigger => sub { $_[1]->autoflush(1) },
  17 );
  18
  19 has receive_from_fh => (
  20   is => 'ro', required => 1,
  21   trigger => sub {
  22     my ($self, $fh) = @_;
  23     weaken($self);
  24     Object::Remote->current_loop
  25                   ->watch_io(
  26                       handle => $fh,
  27                       on_read_ready => sub { $self->_receive_data_from($fh) }
  28                     );
  29   },
  30 );
  31
  32 has on_close => (is => 'rw', default => sub {});
  33
  34 has child_pid => (is => 'ro');
  35
  36 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  37
  38 has local_objects_by_id => (is => 'ro', default => sub { {} });
  39
  40 has remote_objects_by_id => (is => 'ro', default => sub { {} });
  41
  42 has _json => (
  43   is => 'lazy',
  44   handles => {
  45     _deserialize => 'decode',
  46     _encode => 'encode',
  47   },
  48 );
  49
  50 sub _build__json {
  51   weaken(my $self = shift);
  52   my $remotes = $self->remote_objects_by_id;
  53   JSON::PP->new->filter_json_single_key_object(
  54     __remote_object__ => sub {
  55       my $id = shift;
  56       return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  57       (
  58         $remotes->{$id}
  59         or Object::Remote->new(connection => $self, id => $id)
  60       )->proxy;
  61     }
  62   );
  63 }
  64
  65 sub register_remote {
  66   my ($self, $remote) = @_;
  67   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
  68   return $remote;
  69 }
  70
  71 sub send_free {
  72   my ($self, $id) = @_;
  73   delete $self->remote_objects_by_id->{$id};
  74   $self->_send([ free => $id ]);
  75 }
  76
  77 sub send {
  78   my ($self, $type, @call) = @_;
  79
  80   unshift @call, $type => my $future = CPS::Future->new;
  81
  82   $self->_send(\@call);
  83
  84   return $future;
  85 }
  86
  87 sub send_discard {
  88   my ($self, $type, @call) = @_;
  89
  90   unshift @call, $type => { __remote_object__ => 'NULL' };
  91
  92   $self->_send(\@call);
  93 }
  94
  95 sub _send {
  96   my ($self, $to_send) = @_;
  97
  98   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
  99 }
 100
 101 sub _serialize {
 102   my ($self, $data) = @_;
 103   local our @New_Ids;
 104   return eval {
 105     my $flat = $self->_encode($self->_deobjectify($data));
 106     warn "$$ >>> ${flat}\n" if $DEBUG;
 107     $flat;
 108   } or do {
 109     my $err = $@; # won't get here if the eval doesn't die
 110     # don't keep refs to new things
 111     delete @{$self->local_objects_by_id}{@New_Ids};
 112     die "Error serializing: $err";
 113   };
 114 }
 115
 116 sub _deobjectify {
 117   my ($self, $data) = @_;
 118   if (blessed($data)) {
 119     my $id = refaddr($data);
 120     $self->local_objects_by_id->{$id} ||= do {
 121       push our(@New_Ids), $id;
 122       $data;
 123     };
 124     return +{ __remote_object__ => $id };
 125   } elsif (my $ref = ref($data)) {
 126     if ($ref eq 'HASH') {
 127       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 128     } elsif ($ref eq 'ARRAY') {
 129       return [ map $self->_deobjectify($_), @$data ];
 130     } else {
 131       die "Can't collapse reftype $ref";
 132     }
 133   }
 134   return $data; # plain scalar
 135 }
 136
 137 sub _receive_data_from {
 138   my ($self, $fh) = @_;
 139   my $rb = $self->_receive_data_buffer;
 140   if (sysread($fh, $$rb, 1024, length($$rb)) > 0) {
 141     while ($$rb =~ s/^(.*)\n//) {
 142       $self->_receive($1);
 143     }
 144   } else {
 145     $self->on_close->();
 146   }
 147 }
 148
 149 sub _receive {
 150   my ($self, $flat) = @_;
 151   warn "$$ <<< $flat\n" if $DEBUG;
 152   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 153     or do { warn "Deserialize failed for ${flat}: $@"; return };
 154   eval { $self->${\"receive_${type}"}(@rest); 1 }
 155     or do { warn "Receive failed for ${flat}: $@"; return };
 156   return;
 157 }
 158
 159 sub receive_free {
 160   my ($self, $id) = @_;
 161   delete $self->local_objects_by_id->{$id}
 162     or warn "Free: no such object $id";
 163   return;
 164 }
 165
 166 sub receive_call {
 167   my ($self, $future, $id, @rest) = @_;
 168   $future->{method} = 'call_discard_free';
 169   my $local = $self->local_objects_by_id->{$id}
 170     or do { $future->fail("No such object $id"); return };
 171   $self->_invoke($future, $local, @rest);
 172 }
 173
 174 sub receive_call_free {
 175   my ($self, $future, $id, @rest) = @_;
 176   $self->receive_call($future, $id, @rest);
 177   $self->receive_free($id);
 178 }
 179
 180 sub receive_class_call {
 181   my ($self, $future, $class, @rest) = @_;
 182   $future->{method} = 'call_discard_free';
 183   eval { use_module($class) }
 184     or do { $future->fail("Error loading ${class}: $@"); return };
 185   $self->_invoke($future, $class, @rest);
 186 }
 187
 188 sub _invoke {
 189   my ($self, $future, $local, $method, @args) = @_;
 190   eval { $future->done(scalar $local->$method(@args)); 1 }
 191     or do { $future->fail($@); return; };
 192   return;
 193 }
 194
 195 sub DEMOLISH {
 196   my ($self, $gd) = @_;
 197   return if $gd;
 198   Object::Remote->current_loop
 199                 ->unwatch_io(
 200                     handle => $self->receive_from_fh,
 201                     on_read_ready => 1
 202                   );
 203 }
 204
 205 1;