lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote::Handle;
   6 use Object::Remote::CodeContainer;
   7 use Object::Remote;
   8 use IO::Handle;
   9 use Module::Runtime qw(use_module);
  10 use Scalar::Util qw(weaken blessed refaddr);
  11 use JSON::PP qw(encode_json);
  12 use Moo;
  13
  14 our $DEBUG = !!$ENV{OBJECT_REMOTE_DEBUG};
  15
  16 has send_to_fh => (
  17   is => 'ro', required => 1,
  18   trigger => sub { $_[1]->autoflush(1) },
  19 );
  20
  21 has receive_from_fh => (
  22   is => 'ro', required => 1,
  23   trigger => sub {
  24     my ($self, $fh) = @_;
  25     weaken($self);
  26     Object::Remote->current_loop
  27                   ->watch_io(
  28                       handle => $fh,
  29                       on_read_ready => sub { $self->_receive_data_from($fh) }
  30                     );
  31   },
  32 );
  33
  34 has on_close => (is => 'rw', default => sub { CPS::Future->new });
  35
  36 has child_pid => (is => 'ro');
  37
  38 has ready_future => (is => 'lazy');
  39
  40 sub _build_ready_future { CPS::Future->new }
  41
  42 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  43
  44 has local_objects_by_id => (
  45   is => 'ro', default => sub { {} },
  46   coerce => sub { +{ %{$_[0]} } }, # shallow clone on the way in
  47 );
  48
  49 has remote_objects_by_id => (
  50   is => 'ro', default => sub { {} },
  51   coerce => sub { +{ %{$_[0]} } }, # shallow clone on the way in
  52 );
  53
  54 has outstanding_futures => (is => 'ro', default => sub { {} });
  55
  56 has _json => (
  57   is => 'lazy',
  58   handles => {
  59     _deserialize => 'decode',
  60     _encode => 'encode',
  61   },
  62 );
  63
  64 sub _id_to_remote_object {
  65   my ($self, $id) = @_;
  66   return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  67   (
  68     $self->remote_objects_by_id->{$id}
  69     or Object::Remote::Handle->new(connection => $self, id => $id)
  70   )->proxy;
  71 }
  72
  73 sub _build__json {
  74   weaken(my $self = shift);
  75   JSON::PP->new->filter_json_single_key_object(
  76     __remote_object__ => sub {
  77       $self->_id_to_remote_object(@_);
  78     }
  79   )->filter_json_single_key_object(
  80     __remote_code__ => sub {
  81       my $code_container = $self->_id_to_remote_object(@_);
  82       sub { $code_container->call(@_) };
  83     }
  84   );
  85 }
  86
  87 BEGIN {
  88   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
  89   eval { require Object::Remote::Connector::Local };
  90   eval { require Object::Remote::Connector::LocalSudo };
  91   eval { require Object::Remote::Connector::SSH };
  92   eval { require Object::Remote::Connector::UNIX };
  93 }
  94
  95 sub new_from_spec {
  96   my ($class, $spec) = @_;
  97   return $spec if blessed $spec;
  98   foreach my $poss (do { our @Guess }) {
  99     if (my $obj = $poss->($spec)) { return $obj }
 100   }
 101   die "Couldn't figure out what to do with ${spec}";
 102 }
 103
 104 sub remote_object {
 105   my ($self, @args) = @_;
 106   Object::Remote::Handle->new(
 107     connection => $self, @args
 108   )->proxy;
 109 }
 110
 111 sub connect {
 112   my ($self, $to) = @_;
 113   return await_future($self->send(
 114     class_call => 'Object::Remote', 0, connect => $to
 115   ));
 116 }
 117
 118 sub remote_sub {
 119   my ($self, $sub) = @_;
 120   my ($pkg, $name) = $sub =~ m/^(.*)::([^:]+)$/;
 121   return await_future($self->send(class_call => $pkg, 0, can => $name));
 122 }
 123
 124 sub register_remote {
 125   my ($self, $remote) = @_;
 126   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
 127   return $remote;
 128 }
 129
 130 sub await_ready {
 131   my ($self) = @_;
 132   await_future($self->ready_future);
 133 }
 134
 135 sub send_free {
 136   my ($self, $id) = @_;
 137   delete $self->remote_objects_by_id->{$id};
 138   $self->_send([ free => $id ]);
 139 }
 140
 141 sub send {
 142   my ($self, $type, @call) = @_;
 143
 144   unshift @call, $type => my $future = CPS::Future->new;
 145
 146   my $outstanding = $self->outstanding_futures;
 147   $outstanding->{$future} = $future;
 148   $future->on_ready(sub { delete $outstanding->{$future} });
 149
 150   $self->_send(\@call);
 151
 152   return $future;
 153 }
 154
 155 sub send_discard {
 156   my ($self, $type, @call) = @_;
 157
 158   unshift @call, $type => { __remote_object__ => 'NULL' };
 159
 160   $self->_send(\@call);
 161 }
 162
 163 sub _send {
 164   my ($self, $to_send) = @_;
 165
 166   $self->await_ready;
 167
 168   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
 169 }
 170
 171 sub _serialize {
 172   my ($self, $data) = @_;
 173   local our @New_Ids;
 174   return eval {
 175     my $flat = $self->_encode($self->_deobjectify($data));
 176     warn "$$ >>> ${flat}\n" if $DEBUG;
 177     $flat;
 178   } || do {
 179     my $err = $@; # won't get here if the eval doesn't die
 180     # don't keep refs to new things
 181     delete @{$self->local_objects_by_id}{@New_Ids};
 182     die "Error serializing: $err";
 183   };
 184 }
 185
 186 sub _local_object_to_id {
 187   my ($self, $object) = @_;
 188   my $id = refaddr($object);
 189   $self->local_objects_by_id->{$id} ||= do {
 190     push our(@New_Ids), $id;
 191     $object;
 192   };
 193   return $id;
 194 }
 195
 196 sub _deobjectify {
 197   my ($self, $data) = @_;
 198   if (blessed($data)) {
 199     return +{ __remote_object__ => $self->_local_object_to_id($data) };
 200   } elsif (my $ref = ref($data)) {
 201     if ($ref eq 'HASH') {
 202       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 203     } elsif ($ref eq 'ARRAY') {
 204       return [ map $self->_deobjectify($_), @$data ];
 205     } elsif ($ref eq 'CODE') {
 206       my $id = $self->_local_object_to_id(
 207                  Object::Remote::CodeContainer->new(code => $data)
 208                );
 209       return +{ __remote_code__ => $id };
 210     } else {
 211       die "Can't collapse reftype $ref";
 212     }
 213   }
 214   return $data; # plain scalar
 215 }
 216
 217 sub _receive_data_from {
 218   my ($self, $fh) = @_;
 219   my $rb = $self->_receive_data_buffer;
 220   my $ready = $self->ready_future->is_ready;
 221   my $len = sysread($fh, $$rb, 1024, length($$rb));
 222   my $err = defined($len) ? undef : ": $!";
 223   if (defined($len) and $len > 0) {
 224     while ($$rb =~ s/^(.*)\n//) {
 225       if ($ready) {
 226         $self->_receive($1);
 227       } else {
 228         my $line = $1;
 229         die "New remote container did not send Shere - got ${line}"
 230           unless $line eq "Shere";
 231         $self->ready_future->done;
 232       }
 233     }
 234   } else {
 235     Object::Remote->current_loop
 236                   ->unwatch_io(
 237                       handle => $self->receive_from_fh,
 238                       on_read_ready => 1
 239                     );
 240     my $outstanding = $self->outstanding_futures;
 241     $_->fail("Connection lost${err}") for values %$outstanding;
 242     %$outstanding = ();
 243     $self->on_close->done();
 244   }
 245 }
 246
 247 sub _receive {
 248   my ($self, $flat) = @_;
 249   warn "$$ <<< $flat\n" if $DEBUG;
 250   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 251     or do { warn "Deserialize failed for ${flat}: $@"; return };
 252   eval { $self->${\"receive_${type}"}(@rest); 1 }
 253     or do { warn "Receive failed for ${flat}: $@"; return };
 254   return;
 255 }
 256
 257 sub receive_free {
 258   my ($self, $id) = @_;
 259   delete $self->local_objects_by_id->{$id}
 260     or warn "Free: no such object $id";
 261   return;
 262 }
 263
 264 sub receive_call {
 265   my ($self, $future, $id, @rest) = @_;
 266   $future->{method} = 'call_discard_free';
 267   my $local = $self->local_objects_by_id->{$id}
 268     or do { $future->fail("No such object $id"); return };
 269   $self->_invoke($future, $local, @rest);
 270 }
 271
 272 sub receive_call_free {
 273   my ($self, $future, $id, @rest) = @_;
 274   $self->receive_call($future, $id, undef, @rest);
 275   $self->receive_free($id);
 276 }
 277
 278 sub receive_class_call {
 279   my ($self, $future, $class, @rest) = @_;
 280   $future->{method} = 'call_discard_free';
 281   eval { use_module($class) }
 282     or do { $future->fail("Error loading ${class}: $@"); return };
 283   $self->_invoke($future, $class, @rest);
 284 }
 285
 286 sub _invoke {
 287   my ($self, $future, $local, $ctx, $method, @args) = @_;
 288   if ($method =~ /^start::/) {
 289     my $f = $local->$method(@args);
 290     $f->on_done(sub { undef($f); $future->done(@_) });
 291     return unless $f;
 292     $f->on_fail(sub { undef($f); $future->fail(@_) });
 293     return;
 294   }
 295   my $do = sub { $local->$method(@args) };
 296   eval {
 297     $future->done(
 298       defined($ctx)
 299         ? ($ctx ? $do->() : scalar($do->()))
 300         : do { $do->(); () }
 301     );
 302     1;
 303   } or do { $future->fail($@); return; };
 304   return;
 305 }
 306
 307 sub DEMOLISH {
 308   my ($self, $gd) = @_;
 309   return if $gd;
 310   Object::Remote->current_loop
 311                 ->unwatch_io(
 312                     handle => $self->receive_from_fh,
 313                     on_read_ready => 1
 314                   );
 315 }
 316
 317 1;