lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote::Handle;
   6 use Object::Remote::CodeContainer;
   7 use Object::Remote;
   8 use IO::Handle;
   9 use Module::Runtime qw(use_module);
  10 use Scalar::Util qw(weaken blessed refaddr);
  11 use JSON::PP qw(encode_json);
  12 use Moo;
  13
  14 our $DEBUG = !!$ENV{OBJECT_REMOTE_DEBUG};
  15
  16 has send_to_fh => (
  17   is => 'ro', required => 1,
  18   trigger => sub { $_[1]->autoflush(1) },
  19 );
  20
  21 has receive_from_fh => (
  22   is => 'ro', required => 1,
  23   trigger => sub {
  24     my ($self, $fh) = @_;
  25     weaken($self);
  26     Object::Remote->current_loop
  27                   ->watch_io(
  28                       handle => $fh,
  29                       on_read_ready => sub { $self->_receive_data_from($fh) }
  30                     );
  31   },
  32 );
  33
  34 has on_close => (is => 'rw', default => sub {});
  35
  36 has child_pid => (is => 'ro');
  37
  38 has is_ready => (is => 'rwp', trigger => sub {
  39   my ($self, $value) = @_;
  40   $self->ready_future->done if $value;
  41 });
  42
  43 has ready_future => (is => 'lazy');
  44
  45 sub _build_ready_future { CPS::Future->new }
  46
  47 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  48
  49 has local_objects_by_id => (is => 'ro', default => sub { {} });
  50
  51 has remote_objects_by_id => (is => 'ro', default => sub { {} });
  52
  53 has _json => (
  54   is => 'lazy',
  55   handles => {
  56     _deserialize => 'decode',
  57     _encode => 'encode',
  58   },
  59 );
  60
  61 sub _id_to_remote_object {
  62   my ($self, $id) = @_;
  63   return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  64   (
  65     $self->remote_objects_by_id->{$id}
  66     or Object::Remote::Handle->new(connection => $self, id => $id)
  67   )->proxy;
  68 }
  69
  70 sub _build__json {
  71   weaken(my $self = shift);
  72   JSON::PP->new->filter_json_single_key_object(
  73     __remote_object__ => sub {
  74       $self->_id_to_remote_object(@_);
  75     }
  76   )->filter_json_single_key_object(
  77     __remote_code__ => sub {
  78       my $code_container = $self->_id_to_remote_object(@_);
  79       sub { $code_container->call(@_) };
  80     }
  81   );
  82 }
  83
  84 BEGIN {
  85   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
  86   eval { require Object::Remote::Connector::Local };
  87   eval { require Object::Remote::Connector::LocalSudo };
  88   eval { require Object::Remote::Connector::SSH };
  89 }
  90
  91 sub new_from_spec {
  92   my ($class, $spec) = @_;
  93   foreach my $poss (do { our @Guess }) {
  94     if (my $obj = $poss->($spec)) { return $obj }
  95   }
  96   die "Couldn't figure out what to do with ${spec}";
  97 }
  98
  99 sub register_remote {
 100   my ($self, $remote) = @_;
 101   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
 102   return $remote;
 103 }
 104
 105 sub await_ready {
 106   my ($self) = @_;
 107   return if $self->is_ready;
 108   await_future($self->ready_future);
 109 }
 110
 111 sub send_free {
 112   my ($self, $id) = @_;
 113   delete $self->remote_objects_by_id->{$id};
 114   $self->_send([ free => $id ]);
 115 }
 116
 117 sub send {
 118   my ($self, $type, @call) = @_;
 119
 120   unshift @call, $type => my $future = CPS::Future->new;
 121
 122   $self->_send(\@call);
 123
 124   return $future;
 125 }
 126
 127 sub send_discard {
 128   my ($self, $type, @call) = @_;
 129
 130   unshift @call, $type => { __remote_object__ => 'NULL' };
 131
 132   $self->_send(\@call);
 133 }
 134
 135 sub _send {
 136   my ($self, $to_send) = @_;
 137
 138   $self->await_ready unless $self->is_ready;
 139
 140   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
 141 }
 142
 143 sub _serialize {
 144   my ($self, $data) = @_;
 145   local our @New_Ids;
 146   return eval {
 147     my $flat = $self->_encode($self->_deobjectify($data));
 148     warn "$$ >>> ${flat}\n" if $DEBUG;
 149     $flat;
 150   } || do {
 151     my $err = $@; # won't get here if the eval doesn't die
 152     # don't keep refs to new things
 153     delete @{$self->local_objects_by_id}{@New_Ids};
 154     die "Error serializing: $err";
 155   };
 156 }
 157
 158 sub _local_object_to_id {
 159   my ($self, $object) = @_;
 160   my $id = refaddr($object);
 161   $self->local_objects_by_id->{$id} ||= do {
 162     push our(@New_Ids), $id;
 163     $object;
 164   };
 165   return $id;
 166 }
 167
 168 sub _deobjectify {
 169   my ($self, $data) = @_;
 170   if (blessed($data)) {
 171     return +{ __remote_object__ => $self->_local_object_to_id($data) };
 172   } elsif (my $ref = ref($data)) {
 173     if ($ref eq 'HASH') {
 174       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 175     } elsif ($ref eq 'ARRAY') {
 176       return [ map $self->_deobjectify($_), @$data ];
 177     } elsif ($ref eq 'CODE') {
 178       my $id = $self->_local_object_to_id(
 179                  Object::Remote::CodeContainer->new(code => $data)
 180                );
 181       return +{ __remote_code__ => $id };
 182     } else {
 183       die "Can't collapse reftype $ref";
 184     }
 185   }
 186   return $data; # plain scalar
 187 }
 188
 189 sub _receive_data_from {
 190   my ($self, $fh) = @_;
 191   my $rb = $self->_receive_data_buffer;
 192   my $ready = $self->is_ready;
 193   if (sysread($fh, $$rb, 1024, length($$rb)) > 0) {
 194     while ($$rb =~ s/^(.*)\n//) {
 195       if ($ready) {
 196         $self->_receive($1);
 197       } else {
 198         my $line = $1;
 199         die "New remote container did not send Shere - got ${line}"
 200           unless $line eq "Shere";
 201         $self->_set_is_ready($ready = 1);
 202       }
 203     }
 204   } else {
 205     $self->on_close->done();
 206   }
 207 }
 208
 209 sub _receive {
 210   my ($self, $flat) = @_;
 211   warn "$$ <<< $flat\n" if $DEBUG;
 212   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 213     or do { warn "Deserialize failed for ${flat}: $@"; return };
 214   eval { $self->${\"receive_${type}"}(@rest); 1 }
 215     or do { warn "Receive failed for ${flat}: $@"; return };
 216   return;
 217 }
 218
 219 sub receive_free {
 220   my ($self, $id) = @_;
 221   delete $self->local_objects_by_id->{$id}
 222     or warn "Free: no such object $id";
 223   return;
 224 }
 225
 226 sub receive_call {
 227   my ($self, $future, $id, @rest) = @_;
 228   $future->{method} = 'call_discard_free';
 229   my $local = $self->local_objects_by_id->{$id}
 230     or do { $future->fail("No such object $id"); return };
 231   $self->_invoke($future, $local, @rest);
 232 }
 233
 234 sub receive_call_free {
 235   my ($self, $future, $id, @rest) = @_;
 236   $self->receive_call($future, $id, undef, @rest);
 237   $self->receive_free($id);
 238 }
 239
 240 sub receive_class_call {
 241   my ($self, $future, $class, @rest) = @_;
 242   $future->{method} = 'call_discard_free';
 243   eval { use_module($class) }
 244     or do { $future->fail("Error loading ${class}: $@"); return };
 245   $self->_invoke($future, $class, @rest);
 246 }
 247
 248 sub _invoke {
 249   my ($self, $future, $local, $ctx, $method, @args) = @_;
 250   if ($method =~ /^start::/) {
 251     my $f = $local->$method(@args);
 252     $f->on_done(sub { undef($f); $future->done(@_) });
 253     return unless $f;
 254     $f->on_fail(sub { undef($f); $future->fail(@_) });
 255     return;
 256   }
 257   my $do = sub { $local->$method(@args) };
 258   eval {
 259     $future->done(
 260       defined($ctx)
 261         ? ($ctx ? $do->() : scalar($do->()))
 262         : do { $do->(); () }
 263     );
 264     1;
 265   } or do { $future->fail($@); return; };
 266   return;
 267 }
 268
 269 sub DEMOLISH {
 270   my ($self, $gd) = @_;
 271   return if $gd;
 272   Object::Remote->current_loop
 273                 ->unwatch_io(
 274                     handle => $self->receive_from_fh,
 275                     on_read_ready => 1
 276                   );
 277 }
 278
 279 1;