lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote::Handle;
   6 use Object::Remote;
   7 use IO::Handle;
   8 use Module::Runtime qw(use_module);
   9 use Scalar::Util qw(weaken blessed refaddr);
  10 use JSON::PP qw(encode_json);
  11 use Moo;
  12
  13 our $DEBUG = !!$ENV{OBJECT_REMOTE_DEBUG};
  14
  15 has send_to_fh => (
  16   is => 'ro', required => 1,
  17   trigger => sub { $_[1]->autoflush(1) },
  18 );
  19
  20 has receive_from_fh => (
  21   is => 'ro', required => 1,
  22   trigger => sub {
  23     my ($self, $fh) = @_;
  24     weaken($self);
  25     Object::Remote->current_loop
  26                   ->watch_io(
  27                       handle => $fh,
  28                       on_read_ready => sub { $self->_receive_data_from($fh) }
  29                     );
  30   },
  31 );
  32
  33 has on_close => (is => 'rw', default => sub {});
  34
  35 has child_pid => (is => 'ro');
  36
  37 has is_ready => (is => 'rwp', trigger => sub {
  38   my ($self, $value) = @_;
  39   $self->ready_future->done if $value;
  40 });
  41
  42 has ready_future => (is => 'lazy');
  43
  44 sub _build_ready_future { CPS::Future->new }
  45
  46 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  47
  48 has local_objects_by_id => (is => 'ro', default => sub { {} });
  49
  50 has remote_objects_by_id => (is => 'ro', default => sub { {} });
  51
  52 has _json => (
  53   is => 'lazy',
  54   handles => {
  55     _deserialize => 'decode',
  56     _encode => 'encode',
  57   },
  58 );
  59
  60 sub _build__json {
  61   weaken(my $self = shift);
  62   my $remotes = $self->remote_objects_by_id;
  63   JSON::PP->new->filter_json_single_key_object(
  64     __remote_object__ => sub {
  65       my $id = shift;
  66       return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  67       (
  68         $remotes->{$id}
  69         or Object::Remote::Handle->new(connection => $self, id => $id)
  70       )->proxy;
  71     }
  72   );
  73 }
  74
  75 BEGIN {
  76   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
  77   eval { require Object::Remote::Connector::Local };
  78   eval { require Object::Remote::Connector::LocalSudo };
  79   eval { require Object::Remote::Connector::SSH };
  80 }
  81
  82 sub new_from_spec {
  83   my ($class, $spec) = @_;
  84   foreach my $poss (do { our @Guess }) {
  85     if (my $obj = $poss->($spec)) { return $obj }
  86   }
  87   die "Couldn't figure out what to do with ${spec}";
  88 }
  89
  90 sub register_remote {
  91   my ($self, $remote) = @_;
  92   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
  93   return $remote;
  94 }
  95
  96 sub await_ready {
  97   my ($self) = @_;
  98   return if $self->is_ready;
  99   await_future($self->ready_future);
 100 }
 101
 102 sub send_free {
 103   my ($self, $id) = @_;
 104   delete $self->remote_objects_by_id->{$id};
 105   $self->_send([ free => $id ]);
 106 }
 107
 108 sub send {
 109   my ($self, $type, @call) = @_;
 110
 111   unshift @call, $type => my $future = CPS::Future->new;
 112
 113   $self->_send(\@call);
 114
 115   return $future;
 116 }
 117
 118 sub send_discard {
 119   my ($self, $type, @call) = @_;
 120
 121   unshift @call, $type => { __remote_object__ => 'NULL' };
 122
 123   $self->_send(\@call);
 124 }
 125
 126 sub _send {
 127   my ($self, $to_send) = @_;
 128
 129   $self->await_ready unless $self->is_ready;
 130
 131   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
 132 }
 133
 134 sub _serialize {
 135   my ($self, $data) = @_;
 136   local our @New_Ids;
 137   return eval {
 138     my $flat = $self->_encode($self->_deobjectify($data));
 139     warn "$$ >>> ${flat}\n" if $DEBUG;
 140     $flat;
 141   } || do {
 142     my $err = $@; # won't get here if the eval doesn't die
 143     # don't keep refs to new things
 144     delete @{$self->local_objects_by_id}{@New_Ids};
 145     die "Error serializing: $err";
 146   };
 147 }
 148
 149 sub _local_object_to_id {
 150   my ($self, $object) = @_;
 151   my $id = refaddr($object);
 152   $self->local_objects_by_id->{$id} ||= do {
 153     push our(@New_Ids), $id;
 154     $object;
 155   };
 156   return $id;
 157 }
 158
 159 sub _deobjectify {
 160   my ($self, $data) = @_;
 161   if (blessed($data)) {
 162     return +{ __remote_object__ => $self->_local_object_to_id($data) };
 163   } elsif (my $ref = ref($data)) {
 164     if ($ref eq 'HASH') {
 165       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 166     } elsif ($ref eq 'ARRAY') {
 167       return [ map $self->_deobjectify($_), @$data ];
 168     } else {
 169       die "Can't collapse reftype $ref";
 170     }
 171   }
 172   return $data; # plain scalar
 173 }
 174
 175 sub _receive_data_from {
 176   my ($self, $fh) = @_;
 177   my $rb = $self->_receive_data_buffer;
 178   my $ready = $self->is_ready;
 179   if (sysread($fh, $$rb, 1024, length($$rb)) > 0) {
 180     while ($$rb =~ s/^(.*)\n//) {
 181       if ($ready) {
 182         $self->_receive($1);
 183       } else {
 184         my $line = $1;
 185         die "New remote container did not send Shere - got ${line}"
 186           unless $line eq "Shere";
 187         $self->_set_is_ready($ready = 1);
 188       }
 189     }
 190   } else {
 191     $self->on_close->done();
 192   }
 193 }
 194
 195 sub _receive {
 196   my ($self, $flat) = @_;
 197   warn "$$ <<< $flat\n" if $DEBUG;
 198   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 199     or do { warn "Deserialize failed for ${flat}: $@"; return };
 200   eval { $self->${\"receive_${type}"}(@rest); 1 }
 201     or do { warn "Receive failed for ${flat}: $@"; return };
 202   return;
 203 }
 204
 205 sub receive_free {
 206   my ($self, $id) = @_;
 207   delete $self->local_objects_by_id->{$id}
 208     or warn "Free: no such object $id";
 209   return;
 210 }
 211
 212 sub receive_call {
 213   my ($self, $future, $id, @rest) = @_;
 214   $future->{method} = 'call_discard_free';
 215   my $local = $self->local_objects_by_id->{$id}
 216     or do { $future->fail("No such object $id"); return };
 217   $self->_invoke($future, $local, @rest);
 218 }
 219
 220 sub receive_call_free {
 221   my ($self, $future, $id, @rest) = @_;
 222   $self->receive_call($future, $id, undef, @rest);
 223   $self->receive_free($id);
 224 }
 225
 226 sub receive_class_call {
 227   my ($self, $future, $class, @rest) = @_;
 228   $future->{method} = 'call_discard_free';
 229   eval { use_module($class) }
 230     or do { $future->fail("Error loading ${class}: $@"); return };
 231   $self->_invoke($future, $class, @rest);
 232 }
 233
 234 sub _invoke {
 235   my ($self, $future, $local, $ctx, $method, @args) = @_;
 236   if ($method =~ /^start::/) {
 237     my $f = $local->$method(@args);
 238     $f->on_done(sub { undef($f); $future->done(@_) });
 239     return unless $f;
 240     $f->on_fail(sub { undef($f); $future->fail(@_) });
 241     return;
 242   }
 243   my $do = sub { $local->$method(@args) };
 244   eval {
 245     $future->done(
 246       defined($ctx)
 247         ? ($ctx ? $do->() : scalar($do->()))
 248         : do { $do->(); () }
 249     );
 250     1;
 251   } or do { $future->fail($@); return; };
 252   return;
 253 }
 254
 255 sub DEMOLISH {
 256   my ($self, $gd) = @_;
 257   return if $gd;
 258   Object::Remote->current_loop
 259                 ->unwatch_io(
 260                     handle => $self->receive_from_fh,
 261                     on_read_ready => 1
 262                   );
 263 }
 264
 265 1;