lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use CPS::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote;
   6 use IO::Handle;
   7 use Module::Runtime qw(use_module);
   8 use Scalar::Util qw(weaken blessed refaddr);
   9 use JSON::PP qw(encode_json);
  10 use Moo;
  11
  12 our $DEBUG;
  13
  14 has send_to_fh => (
  15   is => 'ro', required => 1,
  16   trigger => sub { $_[1]->autoflush(1) },
  17 );
  18
  19 has receive_from_fh => (
  20   is => 'ro', required => 1,
  21   trigger => sub {
  22     my ($self, $fh) = @_;
  23     weaken($self);
  24     Object::Remote->current_loop
  25                   ->watch_io(
  26                       handle => $fh,
  27                       on_read_ready => sub { $self->_receive_data_from($fh) }
  28                     );
  29   },
  30 );
  31
  32 has on_close => (is => 'rw', default => sub {});
  33
  34 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  35
  36 has local_objects_by_id => (is => 'ro', default => sub { {} });
  37
  38 has remote_objects_by_id => (is => 'ro', default => sub { {} });
  39
  40 has _json => (
  41   is => 'lazy',
  42   handles => {
  43     _deserialize => 'decode',
  44     _encode => 'encode',
  45   },
  46 );
  47
  48 sub _build__json {
  49   weaken(my $self = shift);
  50   my $remotes = $self->remote_objects_by_id;
  51   JSON::PP->new->filter_json_single_key_object(
  52     __remote_object__ => sub {
  53       my $id = shift;
  54       return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  55       (
  56         $remotes->{$id}
  57         or Object::Remote->new(connection => $self, id => $id)
  58       )->proxy;
  59     }
  60   );
  61 }
  62
  63 sub register_remote {
  64   my ($self, $remote) = @_;
  65   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
  66   return $remote;
  67 }
  68
  69 sub send_free {
  70   my ($self, $id) = @_;
  71   delete $self->remote_objects_by_id->{$id};
  72   $self->_send([ free => $id ]);
  73 }
  74
  75 sub send {
  76   my ($self, $type, @call) = @_;
  77
  78   unshift @call, $type => my $future = CPS::Future->new;
  79
  80   $self->_send(\@call);
  81
  82   return $future;
  83 }
  84
  85 sub send_discard {
  86   my ($self, $type, @call) = @_;
  87
  88   unshift @call, $type => { __remote_object__ => 'NULL' };
  89
  90   $self->_send(\@call);
  91 }
  92
  93 sub _send {
  94   my ($self, $to_send) = @_;
  95
  96   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
  97 }
  98
  99 sub _serialize {
 100   my ($self, $data) = @_;
 101   local our @New_Ids;
 102   return eval {
 103     my $flat = $self->_encode($self->_deobjectify($data));
 104     warn "$$ >>> ${flat}\n" if $DEBUG;
 105     $flat;
 106   } or do {
 107     my $err = $@; # won't get here if the eval doesn't die
 108     # don't keep refs to new things
 109     delete @{$self->local_objects_by_id}{@New_Ids};
 110     die "Error serializing: $err";
 111   };
 112 }
 113
 114 sub _deobjectify {
 115   my ($self, $data) = @_;
 116   if (blessed($data)) {
 117     my $id = refaddr($data);
 118     $self->local_objects_by_id->{$id} ||= do {
 119       push our(@New_Ids), $id;
 120       $data;
 121     };
 122     return +{ __remote_object__ => $id };
 123   } elsif (my $ref = ref($data)) {
 124     if ($ref eq 'HASH') {
 125       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 126     } elsif ($ref eq 'ARRAY') {
 127       return [ map $self->_deobjectify($_), @$data ];
 128     } else {
 129       die "Can't collapse reftype $ref";
 130     }
 131   }
 132   return $data; # plain scalar
 133 }
 134
 135 sub _receive_data_from {
 136   my ($self, $fh) = @_;
 137   my $rb = $self->_receive_data_buffer;
 138   if (sysread($fh, $$rb, 1024, length($$rb)) > 0) {
 139     while ($$rb =~ s/^(.*)\n//) {
 140       $self->_receive($1);
 141     }
 142   } else {
 143     $self->on_close->();
 144   }
 145 }
 146
 147 sub _receive {
 148   my ($self, $flat) = @_;
 149   warn "$$ <<< $flat\n" if $DEBUG;
 150   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 151     or do { warn "Deserialize failed for ${flat}: $@"; return };
 152   eval { $self->${\"receive_${type}"}(@rest); 1 }
 153     or do { warn "Receive failed for ${flat}: $@"; return };
 154   return;
 155 }
 156
 157 sub receive_free {
 158   my ($self, $id) = @_;
 159   delete $self->local_objects_by_id->{$id}
 160     or warn "Free: no such object $id";
 161   return;
 162 }
 163
 164 sub receive_call {
 165   my ($self, $future, $id, @rest) = @_;
 166   $future->{method} = 'call_discard';
 167   my $local = $self->local_objects_by_id->{$id}
 168     or do { $future->fail("No such object $id"); return };
 169   $self->_invoke($future, $local, @rest);
 170 }
 171
 172 sub receive_class_call {
 173   my ($self, $future, $class, @rest) = @_;
 174   $future->{method} = 'call_discard';
 175   eval { use_module($class) }
 176     or do { $future->fail("Error loading ${class}: $@"); return };
 177   $self->_invoke($future, $class, @rest);
 178 }
 179
 180 sub _invoke {
 181   my ($self, $future, $local, $method, @args) = @_;
 182   eval { $future->done(scalar $local->$method(@args)); 1 }
 183     or do { $future->fail($@); return; };
 184   return;
 185 }
 186
 187 sub DEMOLISH {
 188   my ($self, $gd) = @_;
 189   return if $gd;
 190   Object::Remote->current_loop
 191                 ->unwatch_io(
 192                     handle => $self->receive_from_fh,
 193                     on_read_ready => 1
 194                   );
 195 }
 196
 197 1;