lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote::Handle;
   6 use Object::Remote;
   7 use IO::Handle;
   8 use Module::Runtime qw(use_module);
   9 use Scalar::Util qw(weaken blessed refaddr);
  10 use JSON::PP qw(encode_json);
  11 use Moo;
  12
  13 our $DEBUG;
  14
  15 has send_to_fh => (
  16   is => 'ro', required => 1,
  17   trigger => sub { $_[1]->autoflush(1) },
  18 );
  19
  20 has receive_from_fh => (
  21   is => 'ro', required => 1,
  22   trigger => sub {
  23     my ($self, $fh) = @_;
  24     weaken($self);
  25     Object::Remote->current_loop
  26                   ->watch_io(
  27                       handle => $fh,
  28                       on_read_ready => sub { $self->_receive_data_from($fh) }
  29                     );
  30   },
  31 );
  32
  33 has on_close => (is => 'rw', default => sub {});
  34
  35 has child_pid => (is => 'ro');
  36
  37 has is_ready => (is => 'rwp', trigger => sub {
  38   my ($self, $value) = @_;
  39   $self->ready_future->done if $value;
  40 });
  41
  42 has ready_future => (is => 'lazy');
  43
  44 sub _build_ready_future { CPS::Future->new }
  45
  46 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  47
  48 has local_objects_by_id => (is => 'ro', default => sub { {} });
  49
  50 has remote_objects_by_id => (is => 'ro', default => sub { {} });
  51
  52 has _json => (
  53   is => 'lazy',
  54   handles => {
  55     _deserialize => 'decode',
  56     _encode => 'encode',
  57   },
  58 );
  59
  60 sub _build__json {
  61   weaken(my $self = shift);
  62   my $remotes = $self->remote_objects_by_id;
  63   JSON::PP->new->filter_json_single_key_object(
  64     __remote_object__ => sub {
  65       my $id = shift;
  66       return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  67       (
  68         $remotes->{$id}
  69         or Object::Remote::Handle->new(connection => $self, id => $id)
  70       )->proxy;
  71     }
  72   );
  73 }
  74
  75 BEGIN {
  76   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
  77   eval { require Object::Remote::Connector::Local };
  78   eval { require Object::Remote::Connector::SSH };
  79 }
  80
  81 sub new_from_spec {
  82   my ($class, $spec) = @_;
  83   foreach my $poss (do { our @Guess }) {
  84     if (my $obj = $poss->($spec)) { return $obj }
  85   }
  86   die "Couldn't figure out what to do with ${spec}";
  87 }
  88
  89 sub register_remote {
  90   my ($self, $remote) = @_;
  91   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
  92   return $remote;
  93 }
  94
  95 sub await_ready {
  96   my ($self) = @_;
  97   return if $self->is_ready;
  98   await_future($self->ready_future);
  99 }
 100
 101 sub send_free {
 102   my ($self, $id) = @_;
 103   delete $self->remote_objects_by_id->{$id};
 104   $self->_send([ free => $id ]);
 105 }
 106
 107 sub send {
 108   my ($self, $type, @call) = @_;
 109
 110   unshift @call, $type => my $future = CPS::Future->new;
 111
 112   $self->_send(\@call);
 113
 114   return $future;
 115 }
 116
 117 sub send_discard {
 118   my ($self, $type, @call) = @_;
 119
 120   unshift @call, $type => { __remote_object__ => 'NULL' };
 121
 122   $self->_send(\@call);
 123 }
 124
 125 sub _send {
 126   my ($self, $to_send) = @_;
 127
 128   $self->await_ready unless $self->is_ready;
 129
 130   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
 131 }
 132
 133 sub _serialize {
 134   my ($self, $data) = @_;
 135   local our @New_Ids;
 136   return eval {
 137     my $flat = $self->_encode($self->_deobjectify($data));
 138     warn "$$ >>> ${flat}\n" if $DEBUG;
 139     $flat;
 140   } or do {
 141     my $err = $@; # won't get here if the eval doesn't die
 142     # don't keep refs to new things
 143     delete @{$self->local_objects_by_id}{@New_Ids};
 144     die "Error serializing: $err";
 145   };
 146 }
 147
 148 sub _deobjectify {
 149   my ($self, $data) = @_;
 150   if (blessed($data)) {
 151     my $id = refaddr($data);
 152     $self->local_objects_by_id->{$id} ||= do {
 153       push our(@New_Ids), $id;
 154       $data;
 155     };
 156     return +{ __remote_object__ => $id };
 157   } elsif (my $ref = ref($data)) {
 158     if ($ref eq 'HASH') {
 159       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 160     } elsif ($ref eq 'ARRAY') {
 161       return [ map $self->_deobjectify($_), @$data ];
 162     } else {
 163       die "Can't collapse reftype $ref";
 164     }
 165   }
 166   return $data; # plain scalar
 167 }
 168
 169 sub _receive_data_from {
 170   my ($self, $fh) = @_;
 171   my $rb = $self->_receive_data_buffer;
 172   my $ready = $self->is_ready;
 173   if (sysread($fh, $$rb, 1024, length($$rb)) > 0) {
 174     while ($$rb =~ s/^(.*)\n//) {
 175       if ($ready) {
 176         $self->_receive($1);
 177       } else {
 178         my $line = $1;
 179         die "New remote container did not send Shere - got ${line}"
 180           unless $line eq "Shere";
 181         $self->_set_is_ready($ready = 1);
 182       }
 183     }
 184   } else {
 185     $self->on_close->done();
 186   }
 187 }
 188
 189 sub _receive {
 190   my ($self, $flat) = @_;
 191   warn "$$ <<< $flat\n" if $DEBUG;
 192   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 193     or do { warn "Deserialize failed for ${flat}: $@"; return };
 194   eval { $self->${\"receive_${type}"}(@rest); 1 }
 195     or do { warn "Receive failed for ${flat}: $@"; return };
 196   return;
 197 }
 198
 199 sub receive_free {
 200   my ($self, $id) = @_;
 201   delete $self->local_objects_by_id->{$id}
 202     or warn "Free: no such object $id";
 203   return;
 204 }
 205
 206 sub receive_call {
 207   my ($self, $future, $id, @rest) = @_;
 208   $future->{method} = 'call_discard_free';
 209   my $local = $self->local_objects_by_id->{$id}
 210     or do { $future->fail("No such object $id"); return };
 211   $self->_invoke($future, $local, @rest);
 212 }
 213
 214 sub receive_call_free {
 215   my ($self, $future, $id, @rest) = @_;
 216   $self->receive_call($future, $id, undef, @rest);
 217   $self->receive_free($id);
 218 }
 219
 220 sub receive_class_call {
 221   my ($self, $future, $class, @rest) = @_;
 222   $future->{method} = 'call_discard_free';
 223   eval { use_module($class) }
 224     or do { $future->fail("Error loading ${class}: $@"); return };
 225   $self->_invoke($future, $class, @rest);
 226 }
 227
 228 sub _invoke {
 229   my ($self, $future, $local, $ctx, $method, @args) = @_;
 230   if ($method =~ /^start::/) {
 231     my $f = $local->$method(@args);
 232     $f->on_done(sub { undef($f); $future->done(@_) });
 233     return unless $f;
 234     $f->on_fail(sub { undef($f); $future->fail(@_) });
 235     return;
 236   }
 237   my $do = sub { $local->$method(@args) };
 238   eval {
 239     $future->done(
 240       defined($ctx)
 241         ? ($ctx ? $do->() : scalar($do->()))
 242         : do { $do->(); () }
 243     );
 244     1;
 245   } or do { $future->fail($@); return; };
 246   return;
 247 }
 248
 249 sub DEMOLISH {
 250   my ($self, $gd) = @_;
 251   return if $gd;
 252   Object::Remote->current_loop
 253                 ->unwatch_io(
 254                     handle => $self->receive_from_fh,
 255                     on_read_ready => 1
 256                   );
 257 }
 258
 259 1;