lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote::Handle;
   6 use Object::Remote::CodeContainer;
   7 use Object::Remote;
   8 use IO::Handle;
   9 use Module::Runtime qw(use_module);
  10 use Scalar::Util qw(weaken blessed refaddr);
  11 use JSON::PP qw(encode_json);
  12 use Moo;
  13
  14 our $DEBUG = !!$ENV{OBJECT_REMOTE_DEBUG};
  15
  16 has send_to_fh => (
  17   is => 'ro', required => 1,
  18   trigger => sub { $_[1]->autoflush(1) },
  19 );
  20
  21 has receive_from_fh => (
  22   is => 'ro', required => 1,
  23   trigger => sub {
  24     my ($self, $fh) = @_;
  25     weaken($self);
  26     Object::Remote->current_loop
  27                   ->watch_io(
  28                       handle => $fh,
  29                       on_read_ready => sub { $self->_receive_data_from($fh) }
  30                     );
  31   },
  32 );
  33
  34 has on_close => (is => 'rw', default => sub { CPS::Future->new });
  35
  36 has child_pid => (is => 'ro');
  37
  38 has is_ready => (is => 'rwp', trigger => sub {
  39   my ($self, $value) = @_;
  40   $self->ready_future->done if $value;
  41 });
  42
  43 has ready_future => (is => 'lazy');
  44
  45 sub _build_ready_future { CPS::Future->new }
  46
  47 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  48
  49 has local_objects_by_id => (is => 'ro', default => sub { {} });
  50
  51 has remote_objects_by_id => (is => 'ro', default => sub { {} });
  52
  53 has outstanding_futures => (is => 'ro', default => sub { {} });
  54
  55 has _json => (
  56   is => 'lazy',
  57   handles => {
  58     _deserialize => 'decode',
  59     _encode => 'encode',
  60   },
  61 );
  62
  63 sub _id_to_remote_object {
  64   my ($self, $id) = @_;
  65   return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  66   (
  67     $self->remote_objects_by_id->{$id}
  68     or Object::Remote::Handle->new(connection => $self, id => $id)
  69   )->proxy;
  70 }
  71
  72 sub _build__json {
  73   weaken(my $self = shift);
  74   JSON::PP->new->filter_json_single_key_object(
  75     __remote_object__ => sub {
  76       $self->_id_to_remote_object(@_);
  77     }
  78   )->filter_json_single_key_object(
  79     __remote_code__ => sub {
  80       my $code_container = $self->_id_to_remote_object(@_);
  81       sub { $code_container->call(@_) };
  82     }
  83   );
  84 }
  85
  86 BEGIN {
  87   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
  88   eval { require Object::Remote::Connector::Local };
  89   eval { require Object::Remote::Connector::LocalSudo };
  90   eval { require Object::Remote::Connector::SSH };
  91 }
  92
  93 sub new_from_spec {
  94   my ($class, $spec) = @_;
  95   return $spec if blessed $spec;
  96   foreach my $poss (do { our @Guess }) {
  97     if (my $obj = $poss->($spec)) { return $obj }
  98   }
  99   die "Couldn't figure out what to do with ${spec}";
 100 }
 101
 102 sub new_remote {
 103   my ($self, @args) = @_;
 104   Object::Remote::Handle->new(
 105     connection => $self, @args
 106   )->proxy;
 107 }
 108
 109 sub get_remote_sub {
 110   my ($self, $sub) = @_;
 111   my ($pkg, $name) = $sub =~ m/^(.*)::([^:]+)$/;
 112   return await_future($self->send(class_call => $pkg, 0, can => $name));
 113 }
 114
 115 sub register_remote {
 116   my ($self, $remote) = @_;
 117   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
 118   return $remote;
 119 }
 120
 121 sub await_ready {
 122   my ($self) = @_;
 123   return if $self->is_ready;
 124   await_future($self->ready_future);
 125 }
 126
 127 sub send_free {
 128   my ($self, $id) = @_;
 129   delete $self->remote_objects_by_id->{$id};
 130   $self->_send([ free => $id ]);
 131 }
 132
 133 sub send {
 134   my ($self, $type, @call) = @_;
 135
 136   unshift @call, $type => my $future = CPS::Future->new;
 137
 138   my $outstanding = $self->outstanding_futures;
 139   $outstanding->{$future} = $future;
 140   $future->on_ready(sub { delete $outstanding->{$future} });
 141
 142   $self->_send(\@call);
 143
 144   return $future;
 145 }
 146
 147 sub send_discard {
 148   my ($self, $type, @call) = @_;
 149
 150   unshift @call, $type => { __remote_object__ => 'NULL' };
 151
 152   $self->_send(\@call);
 153 }
 154
 155 sub _send {
 156   my ($self, $to_send) = @_;
 157
 158   $self->await_ready unless $self->is_ready;
 159
 160   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
 161 }
 162
 163 sub _serialize {
 164   my ($self, $data) = @_;
 165   local our @New_Ids;
 166   return eval {
 167     my $flat = $self->_encode($self->_deobjectify($data));
 168     warn "$$ >>> ${flat}\n" if $DEBUG;
 169     $flat;
 170   } || do {
 171     my $err = $@; # won't get here if the eval doesn't die
 172     # don't keep refs to new things
 173     delete @{$self->local_objects_by_id}{@New_Ids};
 174     die "Error serializing: $err";
 175   };
 176 }
 177
 178 sub _local_object_to_id {
 179   my ($self, $object) = @_;
 180   my $id = refaddr($object);
 181   $self->local_objects_by_id->{$id} ||= do {
 182     push our(@New_Ids), $id;
 183     $object;
 184   };
 185   return $id;
 186 }
 187
 188 sub _deobjectify {
 189   my ($self, $data) = @_;
 190   if (blessed($data)) {
 191     return +{ __remote_object__ => $self->_local_object_to_id($data) };
 192   } elsif (my $ref = ref($data)) {
 193     if ($ref eq 'HASH') {
 194       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 195     } elsif ($ref eq 'ARRAY') {
 196       return [ map $self->_deobjectify($_), @$data ];
 197     } elsif ($ref eq 'CODE') {
 198       my $id = $self->_local_object_to_id(
 199                  Object::Remote::CodeContainer->new(code => $data)
 200                );
 201       return +{ __remote_code__ => $id };
 202     } else {
 203       die "Can't collapse reftype $ref";
 204     }
 205   }
 206   return $data; # plain scalar
 207 }
 208
 209 sub _receive_data_from {
 210   my ($self, $fh) = @_;
 211   my $rb = $self->_receive_data_buffer;
 212   my $ready = $self->is_ready;
 213   if (sysread($fh, $$rb, 1024, length($$rb)) > 0) {
 214     while ($$rb =~ s/^(.*)\n//) {
 215       if ($ready) {
 216         $self->_receive($1);
 217       } else {
 218         my $line = $1;
 219         die "New remote container did not send Shere - got ${line}"
 220           unless $line eq "Shere";
 221         $self->_set_is_ready($ready = 1);
 222       }
 223     }
 224   } else {
 225     Object::Remote->current_loop
 226                   ->unwatch_io(
 227                       handle => $self->receive_from_fh,
 228                       on_read_ready => 1
 229                     );
 230     my $outstanding = $self->outstanding_futures;
 231     $_->fail("Connection lost") for values %$outstanding;
 232     %$outstanding = ();
 233     $self->on_close->done();
 234   }
 235 }
 236
 237 sub _receive {
 238   my ($self, $flat) = @_;
 239   warn "$$ <<< $flat\n" if $DEBUG;
 240   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 241     or do { warn "Deserialize failed for ${flat}: $@"; return };
 242   eval { $self->${\"receive_${type}"}(@rest); 1 }
 243     or do { warn "Receive failed for ${flat}: $@"; return };
 244   return;
 245 }
 246
 247 sub receive_free {
 248   my ($self, $id) = @_;
 249   delete $self->local_objects_by_id->{$id}
 250     or warn "Free: no such object $id";
 251   return;
 252 }
 253
 254 sub receive_call {
 255   my ($self, $future, $id, @rest) = @_;
 256   $future->{method} = 'call_discard_free';
 257   my $local = $self->local_objects_by_id->{$id}
 258     or do { $future->fail("No such object $id"); return };
 259   $self->_invoke($future, $local, @rest);
 260 }
 261
 262 sub receive_call_free {
 263   my ($self, $future, $id, @rest) = @_;
 264   $self->receive_call($future, $id, undef, @rest);
 265   $self->receive_free($id);
 266 }
 267
 268 sub receive_class_call {
 269   my ($self, $future, $class, @rest) = @_;
 270   $future->{method} = 'call_discard_free';
 271   eval { use_module($class) }
 272     or do { $future->fail("Error loading ${class}: $@"); return };
 273   $self->_invoke($future, $class, @rest);
 274 }
 275
 276 sub _invoke {
 277   my ($self, $future, $local, $ctx, $method, @args) = @_;
 278   if ($method =~ /^start::/) {
 279     my $f = $local->$method(@args);
 280     $f->on_done(sub { undef($f); $future->done(@_) });
 281     return unless $f;
 282     $f->on_fail(sub { undef($f); $future->fail(@_) });
 283     return;
 284   }
 285   my $do = sub { $local->$method(@args) };
 286   eval {
 287     $future->done(
 288       defined($ctx)
 289         ? ($ctx ? $do->() : scalar($do->()))
 290         : do { $do->(); () }
 291     );
 292     1;
 293   } or do { $future->fail($@); return; };
 294   return;
 295 }
 296
 297 sub DEMOLISH {
 298   my ($self, $gd) = @_;
 299   return if $gd;
 300   Object::Remote->current_loop
 301                 ->unwatch_io(
 302                     handle => $self->receive_from_fh,
 303                     on_read_ready => 1
 304                   );
 305 }
 306
 307 1;