lib/Object/Remote/Connection.pm

   1 package Object::Remote::Connection;
   2
   3 use Object::Remote::Future;
   4 use Object::Remote::Null;
   5 use Object::Remote::Handle;
   6 use Object::Remote::CodeContainer;
   7 use Object::Remote;
   8 use IO::Handle;
   9 use Module::Runtime qw(use_module);
  10 use Scalar::Util qw(weaken blessed refaddr);
  11 use JSON::PP qw(encode_json);
  12 use Moo;
  13
  14 our $DEBUG = !!$ENV{OBJECT_REMOTE_DEBUG};
  15
  16 has send_to_fh => (
  17   is => 'ro', required => 1,
  18   trigger => sub { $_[1]->autoflush(1) },
  19 );
  20
  21 has receive_from_fh => (
  22   is => 'ro', required => 1,
  23   trigger => sub {
  24     my ($self, $fh) = @_;
  25     weaken($self);
  26     Object::Remote->current_loop
  27                   ->watch_io(
  28                       handle => $fh,
  29                       on_read_ready => sub { $self->_receive_data_from($fh) }
  30                     );
  31   },
  32 );
  33
  34 has on_close => (is => 'rw', default => sub { CPS::Future->new });
  35
  36 has child_pid => (is => 'ro');
  37
  38 has ready_future => (is => 'lazy');
  39
  40 sub _build_ready_future { CPS::Future->new }
  41
  42 has _receive_data_buffer => (is => 'ro', default => sub { my $x = ''; \$x });
  43
  44 has local_objects_by_id => (is => 'ro', default => sub { {} });
  45
  46 has remote_objects_by_id => (is => 'ro', default => sub { {} });
  47
  48 has outstanding_futures => (is => 'ro', default => sub { {} });
  49
  50 has _json => (
  51   is => 'lazy',
  52   handles => {
  53     _deserialize => 'decode',
  54     _encode => 'encode',
  55   },
  56 );
  57
  58 sub _id_to_remote_object {
  59   my ($self, $id) = @_;
  60   return bless({}, 'Object::Remote::Null') if $id eq 'NULL';
  61   (
  62     $self->remote_objects_by_id->{$id}
  63     or Object::Remote::Handle->new(connection => $self, id => $id)
  64   )->proxy;
  65 }
  66
  67 sub _build__json {
  68   weaken(my $self = shift);
  69   JSON::PP->new->filter_json_single_key_object(
  70     __remote_object__ => sub {
  71       $self->_id_to_remote_object(@_);
  72     }
  73   )->filter_json_single_key_object(
  74     __remote_code__ => sub {
  75       my $code_container = $self->_id_to_remote_object(@_);
  76       sub { $code_container->call(@_) };
  77     }
  78   );
  79 }
  80
  81 BEGIN {
  82   unshift our @Guess, sub { blessed($_[0]) ? $_[0] : undef };
  83   eval { require Object::Remote::Connector::Local };
  84   eval { require Object::Remote::Connector::LocalSudo };
  85   eval { require Object::Remote::Connector::SSH };
  86   eval { require Object::Remote::Connector::UNIX };
  87 }
  88
  89 sub new_from_spec {
  90   my ($class, $spec) = @_;
  91   return $spec if blessed $spec;
  92   foreach my $poss (do { our @Guess }) {
  93     if (my $obj = $poss->($spec)) { return $obj }
  94   }
  95   die "Couldn't figure out what to do with ${spec}";
  96 }
  97
  98 sub new_remote {
  99   my ($self, @args) = @_;
 100   Object::Remote::Handle->new(
 101     connection => $self, @args
 102   )->proxy;
 103 }
 104
 105 sub connect {
 106   my ($self, $to) = @_;
 107   return await_future($self->send(
 108     class_call => 'Object::Remote', 0, connect => $to
 109   ));
 110 }
 111
 112 sub get_remote_sub {
 113   my ($self, $sub) = @_;
 114   my ($pkg, $name) = $sub =~ m/^(.*)::([^:]+)$/;
 115   return await_future($self->send(class_call => $pkg, 0, can => $name));
 116 }
 117
 118 sub register_remote {
 119   my ($self, $remote) = @_;
 120   weaken($self->remote_objects_by_id->{$remote->id} = $remote);
 121   return $remote;
 122 }
 123
 124 sub await_ready {
 125   my ($self) = @_;
 126   await_future($self->ready_future);
 127 }
 128
 129 sub send_free {
 130   my ($self, $id) = @_;
 131   delete $self->remote_objects_by_id->{$id};
 132   $self->_send([ free => $id ]);
 133 }
 134
 135 sub send {
 136   my ($self, $type, @call) = @_;
 137
 138   unshift @call, $type => my $future = CPS::Future->new;
 139
 140   my $outstanding = $self->outstanding_futures;
 141   $outstanding->{$future} = $future;
 142   $future->on_ready(sub { delete $outstanding->{$future} });
 143
 144   $self->_send(\@call);
 145
 146   return $future;
 147 }
 148
 149 sub send_discard {
 150   my ($self, $type, @call) = @_;
 151
 152   unshift @call, $type => { __remote_object__ => 'NULL' };
 153
 154   $self->_send(\@call);
 155 }
 156
 157 sub _send {
 158   my ($self, $to_send) = @_;
 159
 160   $self->await_ready;
 161
 162   print { $self->send_to_fh } $self->_serialize($to_send)."\n";
 163 }
 164
 165 sub _serialize {
 166   my ($self, $data) = @_;
 167   local our @New_Ids;
 168   return eval {
 169     my $flat = $self->_encode($self->_deobjectify($data));
 170     warn "$$ >>> ${flat}\n" if $DEBUG;
 171     $flat;
 172   } || do {
 173     my $err = $@; # won't get here if the eval doesn't die
 174     # don't keep refs to new things
 175     delete @{$self->local_objects_by_id}{@New_Ids};
 176     die "Error serializing: $err";
 177   };
 178 }
 179
 180 sub _local_object_to_id {
 181   my ($self, $object) = @_;
 182   my $id = refaddr($object);
 183   $self->local_objects_by_id->{$id} ||= do {
 184     push our(@New_Ids), $id;
 185     $object;
 186   };
 187   return $id;
 188 }
 189
 190 sub _deobjectify {
 191   my ($self, $data) = @_;
 192   if (blessed($data)) {
 193     return +{ __remote_object__ => $self->_local_object_to_id($data) };
 194   } elsif (my $ref = ref($data)) {
 195     if ($ref eq 'HASH') {
 196       return +{ map +($_ => $self->_deobjectify($data->{$_})), keys %$data };
 197     } elsif ($ref eq 'ARRAY') {
 198       return [ map $self->_deobjectify($_), @$data ];
 199     } elsif ($ref eq 'CODE') {
 200       my $id = $self->_local_object_to_id(
 201                  Object::Remote::CodeContainer->new(code => $data)
 202                );
 203       return +{ __remote_code__ => $id };
 204     } else {
 205       die "Can't collapse reftype $ref";
 206     }
 207   }
 208   return $data; # plain scalar
 209 }
 210
 211 sub _receive_data_from {
 212   my ($self, $fh) = @_;
 213   my $rb = $self->_receive_data_buffer;
 214   my $ready = $self->ready_future->is_ready;
 215   my $len = sysread($fh, $$rb, 1024, length($$rb));
 216   my $err = defined($len) ? undef : ": $!";
 217   if (defined($len) and $len > 0) {
 218     while ($$rb =~ s/^(.*)\n//) {
 219       if ($ready) {
 220         $self->_receive($1);
 221       } else {
 222         my $line = $1;
 223         die "New remote container did not send Shere - got ${line}"
 224           unless $line eq "Shere";
 225         $self->ready_future->done;
 226       }
 227     }
 228   } else {
 229     Object::Remote->current_loop
 230                   ->unwatch_io(
 231                       handle => $self->receive_from_fh,
 232                       on_read_ready => 1
 233                     );
 234     my $outstanding = $self->outstanding_futures;
 235     $_->fail("Connection lost${err}") for values %$outstanding;
 236     %$outstanding = ();
 237     $self->on_close->done();
 238   }
 239 }
 240
 241 sub _receive {
 242   my ($self, $flat) = @_;
 243   warn "$$ <<< $flat\n" if $DEBUG;
 244   my ($type, @rest) = eval { @{$self->_deserialize($flat)} }
 245     or do { warn "Deserialize failed for ${flat}: $@"; return };
 246   eval { $self->${\"receive_${type}"}(@rest); 1 }
 247     or do { warn "Receive failed for ${flat}: $@"; return };
 248   return;
 249 }
 250
 251 sub receive_free {
 252   my ($self, $id) = @_;
 253   delete $self->local_objects_by_id->{$id}
 254     or warn "Free: no such object $id";
 255   return;
 256 }
 257
 258 sub receive_call {
 259   my ($self, $future, $id, @rest) = @_;
 260   $future->{method} = 'call_discard_free';
 261   my $local = $self->local_objects_by_id->{$id}
 262     or do { $future->fail("No such object $id"); return };
 263   $self->_invoke($future, $local, @rest);
 264 }
 265
 266 sub receive_call_free {
 267   my ($self, $future, $id, @rest) = @_;
 268   $self->receive_call($future, $id, undef, @rest);
 269   $self->receive_free($id);
 270 }
 271
 272 sub receive_class_call {
 273   my ($self, $future, $class, @rest) = @_;
 274   $future->{method} = 'call_discard_free';
 275   eval { use_module($class) }
 276     or do { $future->fail("Error loading ${class}: $@"); return };
 277   $self->_invoke($future, $class, @rest);
 278 }
 279
 280 sub _invoke {
 281   my ($self, $future, $local, $ctx, $method, @args) = @_;
 282   if ($method =~ /^start::/) {
 283     my $f = $local->$method(@args);
 284     $f->on_done(sub { undef($f); $future->done(@_) });
 285     return unless $f;
 286     $f->on_fail(sub { undef($f); $future->fail(@_) });
 287     return;
 288   }
 289   my $do = sub { $local->$method(@args) };
 290   eval {
 291     $future->done(
 292       defined($ctx)
 293         ? ($ctx ? $do->() : scalar($do->()))
 294         : do { $do->(); () }
 295     );
 296     1;
 297   } or do { $future->fail($@); return; };
 298   return;
 299 }
 300
 301 sub DEMOLISH {
 302   my ($self, $gd) = @_;
 303   return if $gd;
 304   Object::Remote->current_loop
 305                 ->unwatch_io(
 306                     handle => $self->receive_from_fh,
 307                     on_read_ready => 1
 308                   );
 309 }
 310
 311 1;