lib/DX/Step/ResolveProposition.pm

   1 package DX::Step::ResolveProposition;
   2
   3 use Types::Standard qw(ArrayRef);
   4 use DX::Utils qw(deparse);
   5 use DX::Class;
   6
   7 with 'DX::Role::Step';
   8
   9 has actions => (is => 'ro', isa => ArrayRef[Action], required => 1);
  10
  11 has depends_on => (is => 'ro', isa => DependencyGroupList, required => 1);
  12
  13 has resolves => (is => 'ro', isa => Proposition);
  14
  15 has alternative_step => (is => 'ro', isa => Step);
  16
  17 sub but_first {
  18   my ($self, @actions) = @_;
  19   $self->but(actions => [ @actions, @{$self->actions} ]);
  20 }
  21
  22 sub but_with_dependencies_on {
  23   my ($self, @deps) = @_;
  24   $self->but(depends_on => [ @{$self->depends_on}, @deps ]);
  25 }
  26
  27 sub apply_to {
  28   my ($self, $ss) = @_;
  29   my $old_hyp = $ss->current_hypothesis;
  30   trace 'step.apply.old_hyp '.$self => $old_hyp;
  31   trace 'step.apply.actions '.$self => $self->actions;
  32   my $new_ss = $self->_apply_to_ss($ss);
  33   return $ss->but(next_step => DX::Step::Backtrack->new) unless $new_ss;
  34   my $new_hyp = $new_ss->current_hypothesis;
  35   trace 'step.apply.new_hyp '.$self => $new_hyp;
  36   my $ns = do {
  37     if (my $prop = $ss->next_proposition($new_hyp)) {
  38       DX::Step::ConsiderProposition->new(
  39         proposition => $prop
  40       )
  41     } else {
  42       $ss->on_solution_step
  43     }
  44   };
  45   my $alt_step = $self->alternative_step;
  46   return (
  47     $ss->but(
  48       current_hypothesis => $new_hyp,
  49       next_step => $ns,
  50       ($alt_step
  51         ? (alternatives => [ [ $old_hyp, $alt_step ], @{$ss->alternatives} ])
  52         : ()
  53       ),
  54     ),
  55   );
  56 }
  57
  58 sub _apply_to_ss {
  59   my ($self, $old_ss) = @_;
  60   my $old_hyp = $old_ss->current_hypothesis;
  61   (my $hyp, my @recheck) = $old_hyp->with_resolution(
  62     $self->resolves, $self->depends_on, $self->actions
  63   );
  64   return undef unless $hyp;
  65   return $self->_recheck_for(
  66     $old_ss->but(current_hypothesis => $hyp),
  67     @recheck
  68   );
  69 }
  70
  71 sub _recheck_for {
  72   my ($self, $old_ss, @recheck) = @_;
  73   return $old_ss unless @recheck;
  74   my $ss  = $old_ss;
  75   foreach my $prop (@recheck) {
  76     return undef unless $ss = $self->_recheck_one($ss, $prop);
  77   }
  78   return $ss;
  79 }
  80
  81 sub _recheck_one {
  82   my ($self, $old_ss, $prop) = @_;
  83
  84   my $old_hyp = $old_ss->current_hypothesis;
  85
  86   my $ap = DX::ActionPolicy::LockScope->new(
  87     lock_to_depth => $old_hyp->scope->depth,
  88     next_policy => $old_hyp->action_policy,
  89   );
  90
  91   # we should probably be doing something about pruning the scope
  92   # but that's completely pointless until we have rules
  93
  94   my $hyp = ref($old_hyp)->new(
  95     scope => $old_hyp->scope,
  96     resolved_propositions => DX::ResolvedPropositionSet->new_empty,
  97     actions => [],
  98     action_applications => [],
  99     action_policy => $ap,
 100   );
 101
 102   my $pseq = DX::PropositionSequence->new(
 103     members => [ $prop ],
 104     external_names => {},
 105     internal_names => {},
 106   );
 107
 108   trace 'step.recheck.hyp' => $hyp;
 109
 110   my $ss = DX::SearchState->new(
 111     current_hypothesis => $hyp,
 112     alternatives => [],
 113     propositions => $pseq,
 114     next_step => DX::Step::ConsiderProposition->new(
 115                    proposition => $prop,
 116                  ),
 117     is_solution_state => 0,
 118     on_exhaustion_step => undef,
 119     on_solution_step => DX::Step::MarkAsSolution->new,
 120   );
 121
 122   my $sp = DX::SearchProcess->new(
 123     current_search_state => $ss,
 124   );
 125
 126   my $sol_sp = $sp->find_solution;
 127
 128   unless ($sol_sp) {
 129     trace 'step.recheck.fail' => 'argh';
 130     return undef;
 131   }
 132
 133   my $sol_rps = $sol_sp->current_hypothesis->resolved_propositions;
 134
 135   my $rps = $old_hyp->resolved_propositions;
 136
 137   $rps = $rps->with_updated_dependencies_for(
 138     $prop, $sol_rps->dependencies_for($prop)
 139   );
 140
 141   trace 'step.recheck.done' => 'yay';
 142
 143   return $old_ss->but(
 144     current_hypothesis => $old_hyp->but(resolved_propositions => $rps),
 145   );
 146 }
 147
 148 1;