rewrite deparse system

[scpubgit/DX.git] / lib / DX / Value / Dict.pm

package DX::Value::Dict;

use DX::Utils qw(string);
use DX::Class;

with 'DX::Role::StructuredValue';

has '+action_builder' => (
  handles => [ qw(
    can_set_value action_for_set_value
    can_add_member action_for_add_member action_for_remove_member
  ) ]
);

has members => (is => 'ro', required => 1);

sub for_deparse {
  [ dict => $_[0]->members ]
}

sub index_list { sort keys %{$_[0]->members} }

sub get_member_at {
  my ($self, $at) = @_;
  $self->members->{ref($at) ? $at->string_value : $at};
}

sub with_member_at {
  my ($self, $at, $value) = @_;
  $self->but(
    members => {
      %{$self->members},
      (ref($at) ? $at->string_value : $at) => $value
    }
  );
}

sub without_member_at {
  my ($self, $at) = @_;
  my %members = %{$self->members};
  delete $members{$at};
  $self->but(members => \%members);
}

sub to_data {
  my ($self) = @_;
  my $m = $self->members;
  +{ map +($_ => $m->{$_}->to_data), $self->index_list };
}

1;