add is_solution_state flag on SearchState

[scpubgit/DX.git] / lib / DX / SearchState.pm

package DX::SearchState;

use Types::Standard qw(Maybe);
use DX::Step::Backtrack;
use DX::Step::InvokeNextPredicate;
use DX::Class;

has current_hypothesis => (is => 'ro', isa => Hypothesis, required => 1);

has next_step => (is => 'ro', isa => Maybe[Step]);

has propositions => (is => 'ro', isa => PropositionSequence, required => 1);

has alternatives => (is => 'ro', isa => AlternativeList, required => 1);

has is_solution_state => (is => 'ro', required => 1);

sub next_proposition {
  my ($self, $hyp) = @_;
  $hyp ||= $self->current_hypothesis;
  $self->propositions->members->[
    $hyp->resolved_propositions->resolved_count
  ];
}

sub new_for {
  my ($class, $hyp, $props) = @_;
  $class->new(
    current_hypothesis => $hyp,
    alternatives => [],
    next_step => DX::Step::InvokeNextPredicate->new(
      proposition => $props->members->[0],
    ),
    propositions => $props,
    is_solution_state => 0,
  );
}

sub with_one_step {
  my ($self) = @_;
  return undef unless my $step = $self->next_step;
  return $step->apply_to($self);
}

sub force_backtrack {
  my ($self) = @_;
  my ($first_alt, @rest_alt) = @{$self->alternatives};
  return undef unless $first_alt;
  trace 'search.backtrack.forced' => $first_alt->[0];
  return $self->but(
    next_step => DX::Step::Backtrack->new,
  )->with_one_step;
}

1;