have with_actions return the recheck list

[scpubgit/DX.git] / lib / DX / Hypothesis.pm

package DX::Hypothesis;

use DX::ActionPolicy::LockScope;
use Types::Standard qw(ArrayRef);
use DX::Utils qw(deparse);
use DX::Class;

has scope => (is => 'ro', isa => Scope, required => 1);

has resolved_propositions => (
  is => 'ro', isa => ResolvedPropositionSet, required => 1
);

has actions => (
  is => 'ro', isa => ArrayRef[Action], required => 1
);

has action_applications => (
  is => 'ro', isa => ArrayRef[Action], required => 1
);

has action_policy => (is => 'ro', isa => ActionPolicy, required => 1);

sub with_actions {
  my ($self, @actions) = @_;
  my $hyp = $self;
  my @events;
  foreach my $act (@actions) {
    return undef unless $self->action_policy->allows($act);
    ($hyp, my @these_events) = $act->dry_run($hyp);
    return undef unless $hyp;
    push @events, @these_events;
  }
  my ($still_resolved, @recheck) = $hyp->resolved_propositions
                                       ->but_expire_for(@events);
  return (
    $hyp->but(resolved_propositions => $still_resolved),
    @recheck
  );
}

sub but_recheck_for {
  my ($self, @recheck) = @_;

  my $ap = DX::ActionPolicy::LockScope->new(
    lock_to_depth => $self->scope->depth,
    next_policy => $self->action_policy,
  );

  # we should probably be doing something about pruning the scope
  # but that's completely pointless until we have rules

  my $hyp = ref($self)->new(
    scope => $self->scope,
    resolved_propositions => DX::ResolvedPropositionSet->new_empty,
    actions => [],
    action_applications => [],
    action_policy => $ap,
  );

  my $pseq = DX::PropositionSequence->new(
    members => \@recheck,
    external_names => {},
    internal_names => {},
  );

  trace 'step.recheck.hyp' => $hyp;

  my $ss = DX::SearchProcess->new_for($hyp, $pseq);

  my $sol_ss = $ss->find_solution;

  unless ($sol_ss) {
    trace 'step.recheck.fail' => 'argh';
    return undef;
  }

  my $sol_rps = $sol_ss->current_hypothesis->resolved_propositions;

  my $rps = $self->resolved_propositions;

  $rps = $rps->with_updated_dependencies_for(
    $_, $sol_rps->dependencies_for($_)
  ) for @recheck;

  trace 'step.recheck.done' => 'yay';

  return $self->but(resolved_propositions => $rps);
}

sub with_resolution {
  my ($self, $prop, $depends, $actions) = @_;
  (my $hyp, my @recheck) = $self->with_actions(@$actions);
  return undef unless $hyp;
  if (@recheck) {
    $hyp = $hyp->but_recheck_for(@recheck);
    return undef unless $hyp;
  }
  $hyp->but(
    resolved_propositions => $self->resolved_propositions
                                  ->with_resolution_for(
                                      $prop,
                                      $depends,
                                    ),
  );
}

1;