lib/DX/State.pm

   1 package DX::State;
   2
   3 use Return::MultiLevel qw(with_return);
   4 use DX::Op::Backtrack;
   5 use Scalar::Util qw(blessed);
   6 use Moo;
   7
   8 has next_op => (is => 'ro', required => 1);
   9
  10 has return_stack => (is => 'ro', required => 1);
  11
  12 has by_id => (is => 'ro', required => 1);
  13
  14 has scope => (is => 'ro', required => 1);
  15
  16 has last_choice => (is => 'ro', required => 1);
  17
  18 has id_gen => (is => 'ro', default => sub { {} });
  19
  20 has rule_set => (is => 'ro');
  21
  22 has facts => (is => 'ro');
  23
  24 sub scope_var {
  25   my ($self, $name) = @_;
  26   $self->by_id->{$self->scope->{$name}};
  27 }
  28
  29 sub allocate_var {
  30   my ($self, $name, $var, $id_gen) = @_;
  31   my $id = join('_', $name, ++($id_gen->{$name}||='000'));
  32   DX::Var->new(id => $id, %$var);
  33 }
  34
  35 sub expand_vars {
  36   my ($self, %vars) = @_;
  37   my %by_id = %{$self->by_id};
  38   my %id_gen = %{$self->id_gen};
  39   foreach my $name (keys %vars) {
  40     unless (blessed($vars{$name})) {
  41       my $var = $vars{$name} = $self->allocate_var(
  42         $name, $vars{$name}, \%id_gen
  43       );
  44       $by_id{$var->id} = $var;
  45     }
  46   }
  47   $self->but(
  48     by_id => \%by_id, id_gen => \%id_gen,
  49   ), %vars;
  50 }
  51
  52 sub assign_vars {
  53   my ($self, %vars) = @_;
  54   my ($state, %expanded) = $self->expand_vars(%vars);
  55   $state->but(
  56     scope => { %{$self->scope}, map +($_ => $expanded{$_}->id), keys %expanded }
  57   );
  58 }
  59
  60 sub bind_value {
  61   my ($self, $var, $value) = @_;
  62   my $bound = $var->with_value($value);
  63   $self->but(
  64     by_id => { %{$self->by_id}, $var->id => $bound },
  65   );
  66 }
  67
  68 sub bind_stream_then {
  69   my ($self, $var, $stream, $then) = @_;
  70   my $bound = $var->with_stream($stream);
  71   $self->but(
  72     by_id => { %{$self->by_id}, $var->id => $bound },
  73     next_op => $then
  74   )->mark_choice($bound);
  75 }
  76
  77 sub mark_choice {
  78   my ($self, $var) = @_;
  79   $self->but(last_choice => [ $self, $var ]);
  80 }
  81
  82 sub backtrack {
  83   my ($self) = @_;
  84   my ($state, $var) = ($self);
  85   while (($state, $var) = @{$state->last_choice}) {
  86     $var->bound_value; $var->clear_bound_value;
  87     return $state->mark_choice($var) unless $var->bound_stream->is_exhausted;
  88   }
  89   $self->return_from_run(undef);
  90 }
  91
  92 sub then {
  93   my ($self, $then) = @_;
  94   $self->but(next_op => $then);
  95 }
  96
  97 sub return_from_run {
  98   my (undef, $return) = @_;
  99   (our $Run_Return)->($return);
 100 }
 101
 102 sub return_from_op {
 103   my (undef, $return) = @_;
 104   if (our $Op_Return) {
 105     $Op_Return->($return);
 106   }
 107 }
 108
 109 sub run {
 110   my ($state) = @_;
 111   with_return {
 112     my ($return) = @_;
 113     local our $Run_Return = $return;
 114     while (my $op = $state->next_op) {
 115       my $backtrack = with_return {
 116         my ($return) = @_;
 117         local our $Op_Return = $return;
 118         $state = $op->run($state);
 119         return;
 120       };
 121       if ($backtrack) { $state = $state->backtrack }
 122     }
 123     return $state;
 124   }
 125 }
 126
 127 sub push_backtrack {
 128   $_[0]->then(DX::Op::Backtrack->new);
 129 }
 130
 131 sub but {
 132   my ($self, @but) = @_;
 133   $self->new(%$self, @but);
 134 }
 135
 136 sub pop_return_stack {
 137   my ($self) = @_;
 138   my @stack = @{$self->return_stack};
 139   my $top = pop @stack;
 140   $self->but(return_stack => \@stack, next_op => $top->[0]);
 141 }
 142
 143 sub push_return_then {
 144   my ($self, $return, $then) = @_;
 145   $self->but(
 146     return_stack => [ @{$self->return_stack}, [ $return, $self ] ],
 147     next_op => $then
 148   );
 149 }
 150
 151 1;