lib/DX/RuleSet.pm

   1 package DX::RuleSet;
   2
   3 use Moo;
   4 use DX::Op::SetupScope;
   5 use DX::Op::CallRule;
   6 use DX::Op::MemberOf;
   7 use DX::Op::ApplyConstraint;
   8 use DX::Op::Return;
   9 use DX::Op::Cut;
  10 use DX::Op::Backtrack;
  11 use DX::Op::Observe;
  12 use DX::Op::Not;
  13 use DX::Op::ProposeAction;
  14 use DX::Op::Materialize;
  15 use DX::Op::Prop;
  16 use DX::Op::Exists;
  17 use DX::Op::Predicate;
  18 use List::Util qw(reduce);
  19
  20 has rules => (is => 'ro', default => sub { {} });
  21
  22 sub add_predicate {
  23   my ($self, $name, $vars, @cases) = @_;
  24   my $full_name = join('/', $name, scalar @$vars);
  25   push @{$self->rules->{$full_name}}, DX::Op::Predicate->new(
  26     arg_names => $vars, arg_cases => \@cases
  27   );
  28 }
  29
  30 sub add_rule {
  31   my ($self, $name, $vars, @body) = @_;
  32   my $full_name = join('/', $name, scalar @$vars);
  33   push @{$self->rules->{$full_name}}, $self->_make_rule($vars, @body);
  34   return $self;
  35 }
  36
  37 sub _make_rule {
  38   my ($self, $vars, @body) = @_;
  39   my $head = $self->expand_and_link(DX::Op::Return->new, @body);
  40   DX::Op::SetupScope->new(arg_names => $vars, next => $head);
  41 }
  42
  43 sub expand_and_link {
  44   my ($self, $last, @body) = @_;
  45   return reduce { $b->but(next => $a) }
  46            $last,
  47            reverse map $self->expand($_), @body;
  48 }
  49
  50 sub expand {
  51   my ($self, $thing) = @_;
  52   if (ref($thing) eq 'ARRAY') {
  53     my ($type, @rest) = @$thing;
  54     if ($self->can(my $expand_meth = "_expand_op_${type}")) {
  55       return $self->$expand_meth(@rest);
  56     }
  57     return $self->_expand_call(@$thing);
  58   }
  59   return $thing;
  60 }
  61
  62 sub _expand_call {
  63   my ($self, $name, @args) = @_;
  64   DX::Op::CallRule->new(rule_name => $name, rule_args => \@args);
  65 }
  66
  67 sub _expand_op_cut { return DX::Op::Cut->new }
  68
  69 sub _expand_op_fail { return DX::Op::Backtrack->new }
  70
  71 sub _expand_op_not {
  72   my ($self, @contents) = @_;
  73   my $cut = DX::Op::Cut->new(next => DX::Op::Backtrack->new);
  74   DX::Op::Not->new(
  75     body => $self->expand_and_link($cut, @contents)
  76   );
  77 }
  78
  79 sub _expand_op_member_of {
  80   my ($self, $member_var, $coll_var) = @_;
  81   DX::Op::MemberOf->new(
  82     member_var => $member_var,
  83     coll_var => $coll_var,
  84   );
  85 }
  86
  87 sub _expand_op_constrain {
  88   my ($self, $vars, $constraint) = @_;
  89   DX::Op::ApplyConstraint->new(
  90     vars => $vars,
  91     constraint => $constraint
  92   );
  93 }
  94
  95 sub _expand_op_observe {
  96   my ($self, $vars, $builder) = @_;
  97   DX::Op::Observe->new(
  98     vars => $vars,
  99     builder => $builder,
 100   );
 101 }
 102
 103 sub _expand_op_act {
 104   my ($self, $vars, $builder) = @_;
 105   DX::Op::ProposeAction->new(
 106     vars => $vars,
 107     builder => $builder,
 108   );
 109 }
 110
 111 sub _expand_op_materialize {
 112   my ($self, $var_name) = @_;
 113   DX::Op::Materialize->new(var_name => $var_name);
 114 }
 115
 116 sub _expand_op_prop {
 117   my ($self, @args) = @_;
 118   my %new; @new{qw(of name value)} = @args;
 119   DX::Op::Prop->new(%new);
 120 }
 121
 122 sub _expand_op_exists {
 123   my ($self, $vars, @body) = @_;
 124   DX::Op::Exists->new(
 125     vars => $vars,
 126     body => $self->expand_and_link(DX::Op::Return->new, @body)
 127   );
 128 }
 129
 130 1;