lib/DX/RuleSet.pm

   1 package DX::RuleSet;
   2
   3 use Moo;
   4 use DX::Op::CallRule;
   5 use DX::Op::MemberOf;
   6 use DX::Op::ApplyConstraint;
   7 use DX::Op::Return;
   8 use DX::Op::Cut;
   9 use DX::Op::Backtrack;
  10 use DX::Op::Observe;
  11 use DX::Op::Not;
  12 use DX::Op::ProposeAction;
  13 use DX::Op::Materialize;
  14 use DX::Op::Prop;
  15 use DX::Op::Exists;
  16 use List::Util qw(reduce);
  17
  18 has rules => (is => 'ro', default => sub { {} });
  19
  20 sub add_rule {
  21   my ($self, $name, $vars, @body) = @_;
  22   my $full_name = join('/', $name, scalar @$vars);
  23   push @{$self->rules->{$full_name}}, $self->_make_rule($vars, @body);
  24   return $self;
  25 }
  26
  27 sub _make_rule {
  28   my ($self, $vars, @body) = @_;
  29   my $head = $self->expand_and_link(DX::Op::Return->new, @body);
  30   [ $vars, $head ];
  31 }
  32
  33 sub expand_and_link {
  34   my ($self, $last, @body) = @_;
  35   return reduce { $b->but(next => $a) }
  36            $last,
  37            reverse map $self->expand($_), @body;
  38 }
  39
  40 sub expand {
  41   my ($self, $thing) = @_;
  42   if (ref($thing) eq 'ARRAY') {
  43     my ($type, @rest) = @$thing;
  44     if ($self->can(my $expand_meth = "_expand_op_${type}")) {
  45       return $self->$expand_meth(@rest);
  46     }
  47     return $self->_expand_call(@$thing);
  48   }
  49   return $thing;
  50 }
  51
  52 sub _expand_call {
  53   my ($self, $name, @args) = @_;
  54   DX::Op::CallRule->new(rule_name => $name, rule_args => \@args);
  55 }
  56
  57 sub _expand_op_cut { return DX::Op::Cut->new }
  58
  59 sub _expand_op_fail { return DX::Op::Backtrack->new }
  60
  61 sub _expand_op_not {
  62   my ($self, @contents) = @_;
  63   my $cut = DX::Op::Cut->new(next => DX::Op::Backtrack->new);
  64   DX::Op::Not->new(
  65     body => $self->expand_and_link($cut, @contents)
  66   );
  67 }
  68
  69 sub _expand_op_member_of {
  70   my ($self, $member_var, $coll_var) = @_;
  71   DX::Op::MemberOf->new(
  72     member_var => $member_var,
  73     coll_var => $coll_var,
  74   );
  75 }
  76
  77 sub _expand_op_constrain {
  78   my ($self, $vars, $constraint) = @_;
  79   DX::Op::ApplyConstraint->new(
  80     vars => $vars,
  81     constraint => $constraint
  82   );
  83 }
  84
  85 sub _expand_op_observe {
  86   my ($self, $vars, $builder) = @_;
  87   DX::Op::Observe->new(
  88     vars => $vars,
  89     builder => $builder,
  90   );
  91 }
  92
  93 sub _expand_op_act {
  94   my ($self, $vars, $builder) = @_;
  95   DX::Op::ProposeAction->new(
  96     vars => $vars,
  97     builder => $builder,
  98   );
  99 }
 100
 101 sub _expand_op_materialize {
 102   my ($self, $var_name) = @_;
 103   DX::Op::Materialize->new(var_name => $var_name);
 104 }
 105
 106 sub _expand_op_prop {
 107   my ($self, @args) = @_;
 108   my %new; @new{qw(of name value)} = @args;
 109   DX::Op::Prop->new(%new);
 110 }
 111
 112 sub _expand_op_exists {
 113   my ($self, $vars, @body) = @_;
 114   DX::Op::Exists->new(
 115     vars => $vars,
 116     body => $self->expand_and_link(DX::Op::Return->new, @body)
 117   );
 118 }
 119
 120 1;