lib/DX/RuleSet.pm

   1 package DX::RuleSet;
   2
   3 use Moo;
   4 use DX::Op::SetupScope;
   5 use DX::Op::CallRule;
   6 use DX::Op::MemberOf;
   7 use DX::Op::ApplyConstraint;
   8 use DX::Op::Return;
   9 use DX::Op::Cut;
  10 use DX::Op::Backtrack;
  11 use DX::Op::Observe;
  12 use DX::Op::Not;
  13 use DX::Op::ProposeAction;
  14 use DX::Op::ModifyAction;
  15 use DX::Op::Materialize;
  16 use DX::Op::Prop;
  17 use DX::Op::Exists;
  18 use DX::Op::Predicate;
  19 use DX::Op::HasAction;
  20 use DX::Op::FindAll;
  21 use List::Util qw(reduce);
  22
  23 has rules => (is => 'ro', default => sub { {} });
  24
  25 sub add_predicate {
  26   my ($self, $name, $vars, @cases) = @_;
  27   my $full_name = join('/', $name, scalar @$vars);
  28   push @{$self->rules->{$full_name}}, DX::Op::Predicate->new(
  29     arg_names => $vars, arg_cases => \@cases
  30   );
  31 }
  32
  33 sub add_rule {
  34   my ($self, $name, $vars, @body) = @_;
  35   my $full_name = join('/', $name, scalar @$vars);
  36   push @{$self->rules->{$full_name}}, $self->_make_rule($vars, @body);
  37   return $self;
  38 }
  39
  40 sub _make_rule {
  41   my ($self, $vars, @body) = @_;
  42   my $head = $self->expand_and_link(DX::Op::Return->new, @body);
  43   DX::Op::SetupScope->new(arg_names => $vars, next => $head);
  44 }
  45
  46 sub expand_and_link {
  47   my ($self, $last, @body) = @_;
  48   return reduce { $b->but(next => $a) }
  49            $last,
  50            reverse map $self->expand($_), @body;
  51 }
  52
  53 sub expand {
  54   my ($self, $thing) = @_;
  55   if (ref($thing) eq 'ARRAY') {
  56     my ($type, @rest) = @$thing;
  57     if ($self->can(my $expand_meth = "_expand_op_${type}")) {
  58       return $self->$expand_meth(@rest);
  59     }
  60     return $self->_expand_call(@$thing);
  61   }
  62   return $thing;
  63 }
  64
  65 sub _expand_call {
  66   my ($self, $name, @args) = @_;
  67   DX::Op::CallRule->new(rule_name => $name, rule_args => \@args);
  68 }
  69
  70 sub _expand_op_cut { return DX::Op::Cut->new }
  71
  72 sub _expand_op_fail { return DX::Op::Backtrack->new }
  73
  74 sub _expand_op_not {
  75   my ($self, @contents) = @_;
  76   my $cut = DX::Op::Cut->new(next => DX::Op::Backtrack->new);
  77   DX::Op::Not->new(
  78     body => $self->expand_and_link($cut, @contents)
  79   );
  80 }
  81
  82 sub _expand_op_findall {
  83   my ($self, $coll_name, $var_name, @contents) = @_;
  84   my $findall = DX::Op::FindAll->new(
  85     coll_name => $coll_name,
  86     var_name => $var_name,
  87     body => $self->expand_and_link(DX::Op::Return->new, @contents),
  88   );
  89 }
  90
  91 sub _expand_op_member_of {
  92   my ($self, $member_var, $coll_var) = @_;
  93   DX::Op::MemberOf->new(
  94     member_var => $member_var,
  95     coll_var => $coll_var,
  96   );
  97 }
  98
  99 sub _expand_op_constrain {
 100   my ($self, $vars, $constraint) = @_;
 101   DX::Op::ApplyConstraint->new(
 102     vars => $vars,
 103     constraint => $constraint
 104   );
 105 }
 106
 107 sub _expand_op_observe {
 108   my ($self, $vars, $builder) = @_;
 109   DX::Op::Observe->new(
 110     vars => $vars,
 111     builder => $builder,
 112   );
 113 }
 114
 115 sub _expand_op_act {
 116   my ($self, $vars, $builder) = @_;
 117   DX::Op::ProposeAction->new(
 118     vars => $vars,
 119     builder => $builder,
 120   );
 121 }
 122
 123 sub _expand_op_react {
 124   my ($self, $vars, $builder) = @_;
 125   DX::Op::ModifyAction->new(
 126     vars => $vars,
 127     builder => $builder,
 128   );
 129 }
 130
 131 sub _expand_op_materialize {
 132   my ($self, $var_name) = @_;
 133   DX::Op::Materialize->new(var_name => $var_name);
 134 }
 135
 136 sub _expand_op_prop {
 137   my ($self, @args) = @_;
 138   my %new; @new{qw(of name value)} = @args;
 139   DX::Op::Prop->new(%new);
 140 }
 141
 142 sub _expand_op_exists {
 143   my ($self, $vars, @body) = @_;
 144   DX::Op::Exists->new(
 145     vars => $vars,
 146     body => $self->expand_and_link(DX::Op::Return->new, @body)
 147   );
 148 }
 149
 150 sub _expand_op_has_action {
 151   my ($self, @args) = @_;
 152   DX::Op::HasAction->new(arg_spec => \@args);
 153 }
 154
 155 1;