lib/DX/RuleSet.pm

   1 package DX::RuleSet;
   2
   3 use Moo;
   4 use DX::Op::SetupScope;
   5 use DX::Op::CallRule;
   6 use DX::Op::MemberOf;
   7 use DX::Op::ApplyConstraint;
   8 use DX::Op::Return;
   9 use DX::Op::Cut;
  10 use DX::Op::Backtrack;
  11 use DX::Op::Observe;
  12 use DX::Op::Not;
  13 use DX::Op::ProposeAction;
  14 use DX::Op::ModifyAction;
  15 use DX::Op::Materialize;
  16 use DX::Op::Prop;
  17 use DX::Op::Exists;
  18 use DX::Op::Predicate;
  19 use DX::Op::HasAction;
  20 use List::Util qw(reduce);
  21
  22 has rules => (is => 'ro', default => sub { {} });
  23
  24 sub add_predicate {
  25   my ($self, $name, $vars, @cases) = @_;
  26   my $full_name = join('/', $name, scalar @$vars);
  27   push @{$self->rules->{$full_name}}, DX::Op::Predicate->new(
  28     arg_names => $vars, arg_cases => \@cases
  29   );
  30 }
  31
  32 sub add_rule {
  33   my ($self, $name, $vars, @body) = @_;
  34   my $full_name = join('/', $name, scalar @$vars);
  35   push @{$self->rules->{$full_name}}, $self->_make_rule($vars, @body);
  36   return $self;
  37 }
  38
  39 sub _make_rule {
  40   my ($self, $vars, @body) = @_;
  41   my $head = $self->expand_and_link(DX::Op::Return->new, @body);
  42   DX::Op::SetupScope->new(arg_names => $vars, next => $head);
  43 }
  44
  45 sub expand_and_link {
  46   my ($self, $last, @body) = @_;
  47   return reduce { $b->but(next => $a) }
  48            $last,
  49            reverse map $self->expand($_), @body;
  50 }
  51
  52 sub expand {
  53   my ($self, $thing) = @_;
  54   if (ref($thing) eq 'ARRAY') {
  55     my ($type, @rest) = @$thing;
  56     if ($self->can(my $expand_meth = "_expand_op_${type}")) {
  57       return $self->$expand_meth(@rest);
  58     }
  59     return $self->_expand_call(@$thing);
  60   }
  61   return $thing;
  62 }
  63
  64 sub _expand_call {
  65   my ($self, $name, @args) = @_;
  66   DX::Op::CallRule->new(rule_name => $name, rule_args => \@args);
  67 }
  68
  69 sub _expand_op_cut { return DX::Op::Cut->new }
  70
  71 sub _expand_op_fail { return DX::Op::Backtrack->new }
  72
  73 sub _expand_op_not {
  74   my ($self, @contents) = @_;
  75   my $cut = DX::Op::Cut->new(next => DX::Op::Backtrack->new);
  76   DX::Op::Not->new(
  77     body => $self->expand_and_link($cut, @contents)
  78   );
  79 }
  80
  81 sub _expand_op_member_of {
  82   my ($self, $member_var, $coll_var) = @_;
  83   DX::Op::MemberOf->new(
  84     member_var => $member_var,
  85     coll_var => $coll_var,
  86   );
  87 }
  88
  89 sub _expand_op_constrain {
  90   my ($self, $vars, $constraint) = @_;
  91   DX::Op::ApplyConstraint->new(
  92     vars => $vars,
  93     constraint => $constraint
  94   );
  95 }
  96
  97 sub _expand_op_observe {
  98   my ($self, $vars, $builder) = @_;
  99   DX::Op::Observe->new(
 100     vars => $vars,
 101     builder => $builder,
 102   );
 103 }
 104
 105 sub _expand_op_act {
 106   my ($self, $vars, $builder) = @_;
 107   DX::Op::ProposeAction->new(
 108     vars => $vars,
 109     builder => $builder,
 110   );
 111 }
 112
 113 sub _expand_op_react {
 114   my ($self, $vars, $builder) = @_;
 115   DX::Op::ModifyAction->new(
 116     vars => $vars,
 117     builder => $builder,
 118   );
 119 }
 120
 121 sub _expand_op_materialize {
 122   my ($self, $var_name) = @_;
 123   DX::Op::Materialize->new(var_name => $var_name);
 124 }
 125
 126 sub _expand_op_prop {
 127   my ($self, @args) = @_;
 128   my %new; @new{qw(of name value)} = @args;
 129   DX::Op::Prop->new(%new);
 130 }
 131
 132 sub _expand_op_exists {
 133   my ($self, $vars, @body) = @_;
 134   DX::Op::Exists->new(
 135     vars => $vars,
 136     body => $self->expand_and_link(DX::Op::Return->new, @body)
 137   );
 138 }
 139
 140 sub _expand_op_has_action {
 141   my ($self, @args) = @_;
 142   DX::Op::HasAction->new(arg_spec => \@args);
 143 }
 144
 145 1;