lib/DX/RuleSet.pm

   1 package DX::RuleSet;
   2
   3 use Moo;
   4 use DX::Op::SetupScope;
   5 use DX::Op::CallRule;
   6 use DX::Op::MemberOf;
   7 use DX::Op::ApplyConstraint;
   8 use DX::Op::Return;
   9 use DX::Op::Cut;
  10 use DX::Op::Backtrack;
  11 use DX::Op::Observe;
  12 use DX::Op::Not;
  13 use DX::Op::ProposeAction;
  14 use DX::Op::Materialize;
  15 use DX::Op::Prop;
  16 use DX::Op::Exists;
  17 use List::Util qw(reduce);
  18
  19 has rules => (is => 'ro', default => sub { {} });
  20
  21 sub add_rule {
  22   my ($self, $name, $vars, @body) = @_;
  23   my $full_name = join('/', $name, scalar @$vars);
  24   push @{$self->rules->{$full_name}}, $self->_make_rule($vars, @body);
  25   return $self;
  26 }
  27
  28 sub _make_rule {
  29   my ($self, $vars, @body) = @_;
  30   my $head = $self->expand_and_link(DX::Op::Return->new, @body);
  31   DX::Op::SetupScope->new(arg_names => $vars, next => $head);
  32 }
  33
  34 sub expand_and_link {
  35   my ($self, $last, @body) = @_;
  36   return reduce { $b->but(next => $a) }
  37            $last,
  38            reverse map $self->expand($_), @body;
  39 }
  40
  41 sub expand {
  42   my ($self, $thing) = @_;
  43   if (ref($thing) eq 'ARRAY') {
  44     my ($type, @rest) = @$thing;
  45     if ($self->can(my $expand_meth = "_expand_op_${type}")) {
  46       return $self->$expand_meth(@rest);
  47     }
  48     return $self->_expand_call(@$thing);
  49   }
  50   return $thing;
  51 }
  52
  53 sub _expand_call {
  54   my ($self, $name, @args) = @_;
  55   DX::Op::CallRule->new(rule_name => $name, rule_args => \@args);
  56 }
  57
  58 sub _expand_op_cut { return DX::Op::Cut->new }
  59
  60 sub _expand_op_fail { return DX::Op::Backtrack->new }
  61
  62 sub _expand_op_not {
  63   my ($self, @contents) = @_;
  64   my $cut = DX::Op::Cut->new(next => DX::Op::Backtrack->new);
  65   DX::Op::Not->new(
  66     body => $self->expand_and_link($cut, @contents)
  67   );
  68 }
  69
  70 sub _expand_op_member_of {
  71   my ($self, $member_var, $coll_var) = @_;
  72   DX::Op::MemberOf->new(
  73     member_var => $member_var,
  74     coll_var => $coll_var,
  75   );
  76 }
  77
  78 sub _expand_op_constrain {
  79   my ($self, $vars, $constraint) = @_;
  80   DX::Op::ApplyConstraint->new(
  81     vars => $vars,
  82     constraint => $constraint
  83   );
  84 }
  85
  86 sub _expand_op_observe {
  87   my ($self, $vars, $builder) = @_;
  88   DX::Op::Observe->new(
  89     vars => $vars,
  90     builder => $builder,
  91   );
  92 }
  93
  94 sub _expand_op_act {
  95   my ($self, $vars, $builder) = @_;
  96   DX::Op::ProposeAction->new(
  97     vars => $vars,
  98     builder => $builder,
  99   );
 100 }
 101
 102 sub _expand_op_materialize {
 103   my ($self, $var_name) = @_;
 104   DX::Op::Materialize->new(var_name => $var_name);
 105 }
 106
 107 sub _expand_op_prop {
 108   my ($self, @args) = @_;
 109   my %new; @new{qw(of name value)} = @args;
 110   DX::Op::Prop->new(%new);
 111 }
 112
 113 sub _expand_op_exists {
 114   my ($self, $vars, @body) = @_;
 115   DX::Op::Exists->new(
 116     vars => $vars,
 117     body => $self->expand_and_link(DX::Op::Return->new, @body)
 118   );
 119 }
 120
 121 1;