eliminate variable name requirement from query()

[scpubgit/DKit.git] / t / findall.t

use strictures 1;
use Test::More;
use DX::Solver;
use DX::OrderedSet;

my $solver = DX::Solver->new;

{ package My::Server;
  use Moo;
  has name => (is => 'ro', required => 1);

  package My::ShellInstalled;
  use Moo;
  has server => (is => 'ro', required => 1);
  has shell => (is => 'ro', required => 1);
}

$solver->facts->{server} = DX::OrderedSet->new(
  values => [ map My::Server->new(name => $_), qw(one two three four five) ]
);
$solver->facts->{shell_installed} = DX::OrderedSet->new(
  values => [
    (map My::ShellInstalled->new(server => $_, shell => 'bash'),
       qw(one three four)),
    (map My::ShellInstalled->new(server => $_, shell => 'csh'),
       qw(two three five)),
  ],
);

$solver->add_rule(has_shell => [ 'Srv', 'Shell' ],
  [ member_of => 'SI', \'shell_installed' ],
  [ prop => 'SI' => \'server' => 'Name' ],
  [ prop => 'Srv' => \'name' => 'Name' ],
  [ prop => 'SI' => \'shell' => 'Shell' ]
);

my @r = $solver->query(
  [ findall => X => S =>
    [ member_of => 'S', \'server' ],
    [ has_shell => 'S', \'bash' ],
  ]
)->results;

is_deeply(
  [ map $_->name, $r[0]->value_for('X')->all ],
  [ qw(one three four) ]
);

@r = $solver->query(
  [ foreach => S => [ [ member_of => 'S', \'server' ] ],
    [ [ has_shell => 'S' => \'bash' ] ] ]
)->results;

ok(!@r, 'No results for only bash');

$solver->add_rule(has_any_shell => [ 'S' ] => [ has_shell => 'S' => \'bash' ]);
$solver->add_rule(has_any_shell => [ 'S' ] => [ has_shell => 'S' => \'csh' ]);

@r = $solver->query(
  [ foreach => S => [ [ member_of => 'S', \'server' ] ],
    [ [ has_any_shell => 'S' ] ] ]
)->results;

# only three matches both legs of has_any_shell

is(scalar(@r), 2, 'Two solutions for any shell');

done_testing;