enable SSI

[scpubgit/App-SCS.git] / lib / App / SCS / Plugin / Server.pm

package App::SCS::Plugin::Server;

use Module::Runtime qw(use_module);
use Moo;
no warnings::illegalproto;

with 'App::SCS::Role::Plugin';

has _static_handler => (is => 'lazy');

sub _build__static_handler {
  my ($self) = @_;
  use_module('Plack::App::File')->new(
    root => $self->app->share_dir->catdir('static')
  );
}

sub page_dispatchers {
  my ($self) = @_;
  sub (/**.*) {
    my $path = $_[1];
    return unless $path =~ s/(?=\/|^)-//;
    App::SCS::Web::redispatch_to("/static/${path}");
  },
  sub (/static/...) { $self->_static_handler },
  sub (/favicon + .ico) { $self->_static_handler },
}

sub run_command_server {
  my ($self, $env) = @_;
  my @args = @{$env->{argv}};
  my $r = use_module('Plack::Runner')->new(
    server => 'Starman',
    app => use_module('Plack::Middleware::SSI')->wrap(
      $self->app->web->to_psgi_app
    )
  );
  $r->parse_options(@args);
  $r->set_options(argv => \@args);
  $r->run;
}

1;