lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 BEGIN {
   7   *_PERL_LT_5_8_4 = ($] < 5.008004) ? sub(){1} : sub(){0};
   8 }
   9
  10 our $VERSION = '1.005006';
  11 $VERSION = eval $VERSION;
  12
  13 sub VERSION {
  14   no warnings;
  15   local $@;
  16   if (defined $_[1] && eval { $_[0]->UNIVERSAL::VERSION($_[1]); 1}) {
  17     $^H |= 0x20000
  18       unless _PERL_LT_5_8_4;
  19     $^H{strictures_enable} = int $_[1];
  20   }
  21   goto &UNIVERSAL::VERSION;
  22 }
  23
  24 our %extra_load_states;
  25
  26 our $Smells_Like_VCS;
  27
  28 sub import {
  29   my $class = shift;
  30   my %opts = ref $_[0] ? %{$_[0]} : @_;
  31   if (!exists $opts{version}) {
  32     $opts{version}
  33       = exists $^H{strictures_enable} ? delete $^H{strictures_enable}
  34       : int $VERSION;
  35   }
  36   $opts{file} = (caller)[1];
  37   $class->_enable(\%opts);
  38 }
  39
  40 sub _enable {
  41   my ($class, $opts) = @_;
  42   my $version = $opts->{version};
  43   $version = 'undef'
  44     if !defined $version;
  45   my $method = "_enable_$version";
  46   if (!$class->can($method)) {
  47     die "Major version specified as $version - not supported!";
  48   }
  49   $class->$method($opts);
  50 }
  51
  52 sub _enable_1 {
  53   my ($class, $opts) = @_;
  54   strict->import;
  55   warnings->import(FATAL => 'all');
  56
  57   if (_want_extra($opts->{file})) {
  58     _load_extras(qw(indirect multidimensional bareword::filehandles));
  59     indirect->unimport(':fatal')
  60       if $extra_load_states{indirect};
  61     multidimensional->unimport
  62       if $extra_load_states{multidimensional};
  63     bareword::filehandles->unimport
  64       if $extra_load_states{'bareword::filehandles'};
  65   }
  66 }
  67
  68 sub _want_extra {
  69   my $file = shift;
  70   if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  71     if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  72       die 'PERL_STRICTURES_EXTRA checks are not available on perls older'
  73         . "than 5.8.4: please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  74     }
  75     return $ENV{PERL_STRICTURES_EXTRA};
  76   }
  77   return (
  78     !_PERL_LT_5_8_4
  79     and $file =~ /^(?:t|xt|lib|blib)[\\\/]/
  80     and defined $Smells_Like_VCS ? $Smells_Like_VCS
  81       : ( $Smells_Like_VCS = !!(
  82         -e '.git' || -e '.svn' || -e '.hg'
  83         || (-e '../../dist.ini'
  84           && (-e '../../.git' || -e '../../.svn' || -e '../../.hg' ))
  85       ))
  86   );
  87 }
  88
  89 sub _load_extras {
  90   my @extras = @_;
  91   my @failed;
  92   foreach my $mod (@extras) {
  93     next
  94       if exists $extra_load_states{$mod};
  95
  96     $extra_load_states{$mod} = eval "require $mod; 1;" or do {
  97       push @failed, $mod;
  98
  99       #work around 5.8 require bug
 100       (my $file = $mod) =~ s|::|/|g;
 101       delete $INC{"${file}.pm"};
 102     };
 103   }
 104
 105   if (@failed) {
 106     my $failed = join ' ', @failed;
 107     my $extras = join ' ', @extras;
 108     print STDERR <<EOE;
 109 strictures.pm extra testing active but couldn't load all modules. Missing were:
 110
 111   $failed
 112
 113 Extra testing is auto-enabled in checkouts only, so if you're the author
 114 of a strictures-using module you need to run:
 115
 116   cpan $extras
 117
 118 but these modules are not required by your users.
 119 EOE
 120   }
 121 }
 122
 123 1;
 124
 125 __END__
 126 =head1 NAME
 127
 128 strictures - turn on strict and make all warnings fatal
 129
 130 =head1 SYNOPSIS
 131
 132   use strictures 1;
 133
 134 is equivalent to
 135
 136   use strict;
 137   use warnings FATAL => 'all';
 138
 139 except when called from a file which matches:
 140
 141   (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
 142
 143 and when either C<.git>, C<.svn>, or C<.hg> is present in the current directory
 144 (with the intention of only forcing extra tests on the author side) -- or when
 145 C<.git>, C<.svn>, or C<.hg> is present two directories up along with
 146 C<dist.ini> (which would indicate we are in a C<dzil test> operation, via
 147 L<Dist::Zilla>) -- or when the C<PERL_STRICTURES_EXTRA> environment variable is
 148 set, in which case
 149
 150   use strictures 1;
 151
 152 is equivalent to
 153
 154   use strict;
 155   use warnings FATAL => 'all';
 156   no indirect 'fatal';
 157   no multidimensional;
 158   no bareword::filehandles;
 159
 160 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with
 161 only a minor version increase, but any changes to the effect of C<use
 162 strictures> in normal mode will involve a major version bump.
 163
 164 If any of the extra testing modules are not present, L<strictures> will
 165 complain loudly, once, via C<warn()>, and then shut up. But you really
 166 should consider installing them, they're all great anti-footgun tools.
 167
 168 =head1 DESCRIPTION
 169
 170 I've been writing the equivalent of this module at the top of my code for
 171 about a year now. I figured it was time to make it shorter.
 172
 173 Things like the importer in C<use Moose> don't help me because they turn
 174 warnings on but don't make them fatal -- which from my point of view is
 175 useless because I want an exception to tell me my code isn't warnings-clean.
 176
 177 Any time I see a warning from my code, that indicates a mistake.
 178
 179 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 180 and then unknown (and probably undesired) subsequent behaviour.
 181
 182 I also want to ensure that obvious coding mistakes, like indirect object
 183 syntax (and not so obvious mistakes that cause things to accidentally compile
 184 as such) get caught, but not at the cost of an XS dependency and not at the
 185 cost of blowing things up on another machine.
 186
 187 Therefore, L<strictures> turns on additional checking, but only when it thinks
 188 it's running in a test file in a VCS checkout -- although if this causes
 189 undesired behaviour this can be overridden by setting the
 190 C<PERL_STRICTURES_EXTRA> environment variable.
 191
 192 If additional useful author side checks come to mind, I'll add them to the
 193 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version
 194 increase (e.g. 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the
 195 mechanism of this code will result in a sub-version increase (e.g. 1.000000 to
 196 1.000001 (1.0.1)).
 197
 198 If the behaviour of C<use strictures> in normal mode changes in any way, that
 199 will constitute a major version increase -- and the code already checks
 200 when its version is tested to ensure that
 201
 202   use strictures 1;
 203
 204 will continue to only introduce the current set of strictures even if 2.0 is
 205 installed.
 206
 207 =head1 METHODS
 208
 209 =head2 import
 210
 211 This method does the setup work described above in L</DESCRIPTION>
 212
 213 =head2 VERSION
 214
 215 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 216 with a version number on it and does the version check.
 217
 218 =head1 EXTRA TESTING RATIONALE
 219
 220 Every so often, somebody complains that they're deploying via C<git pull>
 221 and that they don't want L<strictures> to enable itself in this case -- and that
 222 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 223 disable extra testing would be welcome but the discussion never seems to get
 224 that far).
 225
 226 In order to allow us to skip a couple of stages and get straight to a
 227 productive conversation, here's my current rationale for turning the
 228 extra testing on via a heuristic:
 229
 230 The extra testing is all stuff that only ever blows up at compile time;
 231 this is intentional. So the oft-raised concern that it's different code being
 232 tested is only sort of the case -- none of the modules involved affect the
 233 final optree to my knowledge, so the author gets some additional compile
 234 time crashes which he/she then fixes, and the rest of the testing is
 235 completely valid for all environments.
 236
 237 The point of the extra testing -- especially C<no indirect> -- is to catch
 238 mistakes that newbie users won't even realise are mistakes without
 239 help. For example,
 240
 241   foo { ... };
 242
 243 where foo is an & prototyped sub that you forgot to import -- this is
 244 pernicious to track down since all I<seems> fine until it gets called
 245 and you get a crash. Worse still, you can fail to have imported it due
 246 to a circular require, at which point you have a load order dependent
 247 bug which I've seen before now I<only> show up in production due to tiny
 248 differences between the production and the development environment. I wrote
 249 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 250 this particular problem before L<strictures> itself existed.
 251
 252 As such, in my experience so far L<strictures>' extra testing has
 253 I<avoided> production versus development differences, not caused them.
 254
 255 Additionally, L<strictures>' policy is very much "try and provide as much
 256 protection as possible for newbies -- who won't think about whether there's
 257 an option to turn on or not" -- so having only the environment variable
 258 is not sufficient to achieve that (I get to explain that you need to add
 259 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 260 completely skip steps because they don't understand that that step
 261 is important).
 262
 263 I make no claims that the heuristic is perfect -- it's already been evolved
 264 significantly over time, especially for 1.004 where we changed things to
 265 ensure it only fires on files in your checkout (rather than L<strictures>-using
 266 modules you happened to have installed, which was just silly). However, I
 267 hope the above clarifies why a heuristic approach is not only necessary but
 268 desirable from a point of view of providing new users with as much safety as
 269 possible, and will allow any future discussion on the subject to focus on "how
 270 do we minimise annoyance to people deploying from checkouts intentionally".
 271
 272 =head1 SEE ALSO
 273
 274 =over 4
 275
 276 =item *
 277
 278 L<indirect>
 279
 280 =item *
 281
 282 L<multidimensional>
 283
 284 =item *
 285
 286 L<bareword::filehandles>
 287
 288 =back
 289
 290 =head1 COMMUNITY AND SUPPORT
 291
 292 =head2 IRC channel
 293
 294 irc.perl.org #toolchain
 295
 296 (or bug 'mst' in query on there or freenode)
 297
 298 =head2 Git repository
 299
 300 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 301
 302   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 303
 304 The web interface to the repository is at:
 305
 306   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 307
 308 =head1 AUTHOR
 309
 310 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 311
 312 =head1 CONTRIBUTORS
 313
 314 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 315
 316 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 317
 318 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 319
 320 =head1 COPYRIGHT
 321
 322 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 323 as listed above.
 324
 325 =head1 LICENSE
 326
 327 This library is free software and may be distributed under the same terms
 328 as perl itself.
 329
 330 =cut