lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 BEGIN {
   7   *_PERL_LT_5_8_4 = ($] < 5.008004) ? sub(){1} : sub(){0};
   8 }
   9
  10 our $VERSION = '1.005006';
  11 $VERSION = eval $VERSION;
  12
  13 sub VERSION {
  14   my ($class, $version) = @_;
  15   for ($version) {
  16     last unless defined && !ref && int != 1;
  17     die "Major version specified as $_ - this is strictures version 1";
  18   }
  19   # passing undef here may either warn or die depending on the version of perl.
  20   # we can't match the caller's warning state in this case, so just disable the
  21   # warning.
  22   no warnings 'uninitialized';
  23   shift->SUPER::VERSION(@_);
  24 }
  25
  26 our $extra_load_states;
  27
  28 our $Smells_Like_VCS;
  29
  30 sub import {
  31   strict->import;
  32   warnings->import(FATAL => 'all');
  33
  34   my $extra_tests = do {
  35     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  36       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  37         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  38           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  39       }
  40       $ENV{PERL_STRICTURES_EXTRA};
  41     } elsif (! _PERL_LT_5_8_4) {
  42       (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
  43         and defined $Smells_Like_VCS ? $Smells_Like_VCS
  44           : ( $Smells_Like_VCS = !!(
  45             -e '.git' || -e '.svn' || -e '.hg'
  46             || (-e '../../dist.ini'
  47               && (-e '../../.git' || -e '../../.svn' || -e '../../.hg' ))
  48           ))
  49     }
  50   };
  51   if ($extra_tests) {
  52     $extra_load_states ||= do {
  53
  54       my (%rv, @failed);
  55       foreach my $mod (qw(indirect multidimensional bareword::filehandles)) {
  56         eval "require $mod; \$rv{'$mod'} = 1;" or do {
  57           push @failed, $mod;
  58
  59           # courtesy of the 5.8 require bug
  60           # (we do a copy because 5.16.2 at least uses the same read-only
  61           # scalars for the qw() list and it doesn't seem worth a $^V check)
  62
  63           (my $file = $mod) =~ s|::|/|g;
  64           delete $INC{"${file}.pm"};
  65         };
  66       }
  67
  68       if (@failed) {
  69         my $failed = join ' ', @failed;
  70         print STDERR <<EOE;
  71 strictures.pm extra testing active but couldn't load all modules. Missing were:
  72
  73   $failed
  74
  75 Extra testing is auto-enabled in checkouts only, so if you're the author
  76 of a strictures-using module you need to run:
  77
  78   cpan indirect multidimensional bareword::filehandles
  79
  80 but these modules are not required by your users.
  81 EOE
  82       }
  83
  84       \%rv;
  85     };
  86
  87     indirect->unimport(':fatal') if $extra_load_states->{indirect};
  88     multidimensional->unimport if $extra_load_states->{multidimensional};
  89     bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  90   }
  91 }
  92
  93 1;
  94
  95 __END__
  96 =head1 NAME
  97
  98 strictures - turn on strict and make all warnings fatal
  99
 100 =head1 SYNOPSIS
 101
 102   use strictures 1;
 103
 104 is equivalent to
 105
 106   use strict;
 107   use warnings FATAL => 'all';
 108
 109 except when called from a file which matches:
 110
 111   (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
 112
 113 and when either C<.git>, C<.svn>, or C<.hg> is present in the current directory
 114 (with the intention of only forcing extra tests on the author side) -- or when
 115 C<.git>, C<.svn>, or C<.hg> is present two directories up along with
 116 C<dist.ini> (which would indicate we are in a C<dzil test> operation, via
 117 L<Dist::Zilla>) -- or when the C<PERL_STRICTURES_EXTRA> environment variable is
 118 set, in which case
 119
 120   use strictures 1;
 121
 122 is equivalent to
 123
 124   use strict;
 125   use warnings FATAL => 'all';
 126   no indirect 'fatal';
 127   no multidimensional;
 128   no bareword::filehandles;
 129
 130 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with
 131 only a minor version increase, but any changes to the effect of C<use
 132 strictures> in normal mode will involve a major version bump.
 133
 134 If any of the extra testing modules are not present, L<strictures> will
 135 complain loudly, once, via C<warn()>, and then shut up. But you really
 136 should consider installing them, they're all great anti-footgun tools.
 137
 138 =head1 DESCRIPTION
 139
 140 I've been writing the equivalent of this module at the top of my code for
 141 about a year now. I figured it was time to make it shorter.
 142
 143 Things like the importer in C<use Moose> don't help me because they turn
 144 warnings on but don't make them fatal -- which from my point of view is
 145 useless because I want an exception to tell me my code isn't warnings-clean.
 146
 147 Any time I see a warning from my code, that indicates a mistake.
 148
 149 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 150 and then unknown (and probably undesired) subsequent behaviour.
 151
 152 I also want to ensure that obvious coding mistakes, like indirect object
 153 syntax (and not so obvious mistakes that cause things to accidentally compile
 154 as such) get caught, but not at the cost of an XS dependency and not at the
 155 cost of blowing things up on another machine.
 156
 157 Therefore, L<strictures> turns on additional checking, but only when it thinks
 158 it's running in a test file in a VCS checkout -- although if this causes
 159 undesired behaviour this can be overridden by setting the
 160 C<PERL_STRICTURES_EXTRA> environment variable.
 161
 162 If additional useful author side checks come to mind, I'll add them to the
 163 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version
 164 increase (e.g. 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the
 165 mechanism of this code will result in a sub-version increase (e.g. 1.000000 to
 166 1.000001 (1.0.1)).
 167
 168 If the behaviour of C<use strictures> in normal mode changes in any way, that
 169 will constitute a major version increase -- and the code already checks
 170 when its version is tested to ensure that
 171
 172   use strictures 1;
 173
 174 will continue to only introduce the current set of strictures even if 2.0 is
 175 installed.
 176
 177 =head1 METHODS
 178
 179 =head2 import
 180
 181 This method does the setup work described above in L</DESCRIPTION>
 182
 183 =head2 VERSION
 184
 185 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 186 with a version number on it and does the version check.
 187
 188 =head1 EXTRA TESTING RATIONALE
 189
 190 Every so often, somebody complains that they're deploying via C<git pull>
 191 and that they don't want L<strictures> to enable itself in this case -- and that
 192 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 193 disable extra testing would be welcome but the discussion never seems to get
 194 that far).
 195
 196 In order to allow us to skip a couple of stages and get straight to a
 197 productive conversation, here's my current rationale for turning the
 198 extra testing on via a heuristic:
 199
 200 The extra testing is all stuff that only ever blows up at compile time;
 201 this is intentional. So the oft-raised concern that it's different code being
 202 tested is only sort of the case -- none of the modules involved affect the
 203 final optree to my knowledge, so the author gets some additional compile
 204 time crashes which he/she then fixes, and the rest of the testing is
 205 completely valid for all environments.
 206
 207 The point of the extra testing -- especially C<no indirect> -- is to catch
 208 mistakes that newbie users won't even realise are mistakes without
 209 help. For example,
 210
 211   foo { ... };
 212
 213 where foo is an & prototyped sub that you forgot to import -- this is
 214 pernicious to track down since all I<seems> fine until it gets called
 215 and you get a crash. Worse still, you can fail to have imported it due
 216 to a circular require, at which point you have a load order dependent
 217 bug which I've seen before now I<only> show up in production due to tiny
 218 differences between the production and the development environment. I wrote
 219 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 220 this particular problem before L<strictures> itself existed.
 221
 222 As such, in my experience so far L<strictures>' extra testing has
 223 I<avoided> production versus development differences, not caused them.
 224
 225 Additionally, L<strictures>' policy is very much "try and provide as much
 226 protection as possible for newbies -- who won't think about whether there's
 227 an option to turn on or not" -- so having only the environment variable
 228 is not sufficient to achieve that (I get to explain that you need to add
 229 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 230 completely skip steps because they don't understand that that step
 231 is important).
 232
 233 I make no claims that the heuristic is perfect -- it's already been evolved
 234 significantly over time, especially for 1.004 where we changed things to
 235 ensure it only fires on files in your checkout (rather than L<strictures>-using
 236 modules you happened to have installed, which was just silly). However, I
 237 hope the above clarifies why a heuristic approach is not only necessary but
 238 desirable from a point of view of providing new users with as much safety as
 239 possible, and will allow any future discussion on the subject to focus on "how
 240 do we minimise annoyance to people deploying from checkouts intentionally".
 241
 242 =head1 SEE ALSO
 243
 244 =over 4
 245
 246 =item *
 247
 248 L<indirect>
 249
 250 =item *
 251
 252 L<multidimensional>
 253
 254 =item *
 255
 256 L<bareword::filehandles>
 257
 258 =back
 259
 260 =head1 COMMUNITY AND SUPPORT
 261
 262 =head2 IRC channel
 263
 264 irc.perl.org #toolchain
 265
 266 (or bug 'mst' in query on there or freenode)
 267
 268 =head2 Git repository
 269
 270 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 271
 272   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 273
 274 The web interface to the repository is at:
 275
 276   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 277
 278 =head1 AUTHOR
 279
 280 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 281
 282 =head1 CONTRIBUTORS
 283
 284 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 285
 286 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 287
 288 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 289
 290 =head1 COPYRIGHT
 291
 292 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 293 as listed above.
 294
 295 =head1 LICENSE
 296
 297 This library is free software and may be distributed under the same terms
 298 as perl itself.
 299
 300 =cut