lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 BEGIN {
   7   *_PERL_LT_5_8_4 = ($] < 5.008004) ? sub(){1} : sub(){0};
   8 }
   9
  10 our $VERSION = '1.005005';
  11
  12 sub VERSION {
  13   my ($class, $version) = @_;
  14   for ($version) {
  15     last unless defined && !ref && int != 1;
  16     die "Major version specified as $_ - this is strictures version 1";
  17   }
  18   # passing undef here may either warn or die depending on the version of perl.
  19   # we can't match the caller's warning state in this case, so just disable the
  20   # warning.
  21   no warnings 'uninitialized';
  22   shift->SUPER::VERSION(@_);
  23 }
  24
  25 our $extra_load_states;
  26
  27 our $Smells_Like_VCS;
  28
  29 sub import {
  30   strict->import;
  31   warnings->import(FATAL => 'all');
  32
  33   my $extra_tests = do {
  34     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  35       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  36         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  37           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  38       }
  39       $ENV{PERL_STRICTURES_EXTRA};
  40     } elsif (! _PERL_LT_5_8_4) {
  41       (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
  42         and defined $Smells_Like_VCS ? $Smells_Like_VCS
  43           : ( $Smells_Like_VCS = !!(
  44             -e '.git' || -e '.svn' || -e '.hg'
  45             || (-e '../../dist.ini'
  46               && (-e '../../.git' || -e '../../.svn' || -e '../../.hg' ))
  47           ))
  48     }
  49   };
  50   if ($extra_tests) {
  51     $extra_load_states ||= do {
  52
  53       my (%rv, @failed);
  54       foreach my $mod (qw(indirect multidimensional bareword::filehandles)) {
  55         eval "require $mod; \$rv{'$mod'} = 1;" or do {
  56           push @failed, $mod;
  57
  58           # courtesy of the 5.8 require bug
  59           # (we do a copy because 5.16.2 at least uses the same read-only
  60           # scalars for the qw() list and it doesn't seem worth a $^V check)
  61
  62           (my $file = $mod) =~ s|::|/|g;
  63           delete $INC{"${file}.pm"};
  64         };
  65       }
  66
  67       if (@failed) {
  68         my $failed = join ' ', @failed;
  69         print STDERR <<EOE;
  70 strictures.pm extra testing active but couldn't load all modules. Missing were:
  71
  72   $failed
  73
  74 Extra testing is auto-enabled in checkouts only, so if you're the author
  75 of a strictures-using module you need to run:
  76
  77   cpan indirect multidimensional bareword::filehandles
  78
  79 but these modules are not required by your users.
  80 EOE
  81       }
  82
  83       \%rv;
  84     };
  85
  86     indirect->unimport(':fatal') if $extra_load_states->{indirect};
  87     multidimensional->unimport if $extra_load_states->{multidimensional};
  88     bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  89   }
  90 }
  91
  92 1;
  93
  94 __END__
  95 =head1 NAME
  96
  97 strictures - turn on strict and make all warnings fatal
  98
  99 =head1 SYNOPSIS
 100
 101   use strictures 1;
 102
 103 is equivalent to
 104
 105   use strict;
 106   use warnings FATAL => 'all';
 107
 108 except when called from a file which matches:
 109
 110   (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
 111
 112 and when either C<.git>, C<.svn>, or C<.hg> is present in the current directory (with
 113 the intention of only forcing extra tests on the author side) -- or when C<.git>,
 114 C<.svn>, or C<.hg> is present two directories up along with C<dist.ini> (which would
 115 indicate we are in a C<dzil test> operation, via L<Dist::Zilla>) --
 116 or when the C<PERL_STRICTURES_EXTRA> environment variable is set, in which case
 117
 118   use strictures 1;
 119
 120 is equivalent to
 121
 122   use strict;
 123   use warnings FATAL => 'all';
 124   no indirect 'fatal';
 125   no multidimensional;
 126   no bareword::filehandles;
 127
 128 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with only a minor
 129 version increase, but any changes to the effect of C<use strictures> in
 130 normal mode will involve a major version bump.
 131
 132 If any of the extra testing modules are not present, L<strictures> will
 133 complain loudly, once, via C<warn()>, and then shut up. But you really
 134 should consider installing them, they're all great anti-footgun tools.
 135
 136 =head1 DESCRIPTION
 137
 138 I've been writing the equivalent of this module at the top of my code for
 139 about a year now. I figured it was time to make it shorter.
 140
 141 Things like the importer in C<use Moose> don't help me because they turn
 142 warnings on but don't make them fatal -- which from my point of view is
 143 useless because I want an exception to tell me my code isn't warnings-clean.
 144
 145 Any time I see a warning from my code, that indicates a mistake.
 146
 147 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 148 and then unknown (and probably undesired) subsequent behaviour.
 149
 150 I also want to ensure that obvious coding mistakes, like indirect object
 151 syntax (and not so obvious mistakes that cause things to accidentally compile
 152 as such) get caught, but not at the cost of an XS dependency and not at the
 153 cost of blowing things up on another machine.
 154
 155 Therefore, L<strictures> turns on additional checking, but only when it thinks
 156 it's running in a test file in a VCS checkout -- although if this causes
 157 undesired behaviour this can be overridden by setting the
 158 C<PERL_STRICTURES_EXTRA> environment variable.
 159
 160 If additional useful author side checks come to mind, I'll add them to the
 161 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version increase (e.g.
 162 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 163 this code will result in a sub-version increase (e.g. 1.000000 to 1.000001
 164 (1.0.1)).
 165
 166 If the behaviour of C<use strictures> in normal mode changes in any way, that
 167 will constitute a major version increase -- and the code already checks
 168 when its version is tested to ensure that
 169
 170   use strictures 1;
 171
 172 will continue to only introduce the current set of strictures even if 2.0 is
 173 installed.
 174
 175 =head1 METHODS
 176
 177 =head2 import
 178
 179 This method does the setup work described above in L</DESCRIPTION>
 180
 181 =head2 VERSION
 182
 183 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 184 with a version number on it and does the version check.
 185
 186 =head1 EXTRA TESTING RATIONALE
 187
 188 Every so often, somebody complains that they're deploying via C<git pull>
 189 and that they don't want L<strictures> to enable itself in this case -- and that
 190 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 191 disable extra testing would be welcome but the discussion never seems to get
 192 that far).
 193
 194 In order to allow us to skip a couple of stages and get straight to a
 195 productive conversation, here's my current rationale for turning the
 196 extra testing on via a heuristic:
 197
 198 The extra testing is all stuff that only ever blows up at compile time;
 199 this is intentional. So the oft-raised concern that it's different code being
 200 tested is only sort of the case -- none of the modules involved affect the
 201 final optree to my knowledge, so the author gets some additional compile
 202 time crashes which he/she then fixes, and the rest of the testing is
 203 completely valid for all environments.
 204
 205 The point of the extra testing -- especially C<no indirect> -- is to catch
 206 mistakes that newbie users won't even realise are mistakes without
 207 help. For example,
 208
 209   foo { ... };
 210
 211 where foo is an & prototyped sub that you forgot to import -- this is
 212 pernicious to track down since all I<seems> fine until it gets called
 213 and you get a crash. Worse still, you can fail to have imported it due
 214 to a circular require, at which point you have a load order dependent
 215 bug which I've seen before now I<only> show up in production due to tiny
 216 differences between the production and the development environment. I wrote
 217 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 218 this particular problem before L<strictures> itself existed.
 219
 220 As such, in my experience so far L<strictures>' extra testing has
 221 I<avoided> production versus development differences, not caused them.
 222
 223 Additionally, L<strictures>' policy is very much "try and provide as much
 224 protection as possible for newbies -- who won't think about whether there's
 225 an option to turn on or not" -- so having only the environment variable
 226 is not sufficient to achieve that (I get to explain that you need to add
 227 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 228 completely skip steps because they don't understand that that step
 229 is important).
 230
 231 I make no claims that the heuristic is perfect -- it's already been evolved
 232 significantly over time, especially for 1.004 where we changed things to
 233 ensure it only fires on files in your checkout (rather than L<strictures>-using
 234 modules you happened to have installed, which was just silly). However, I
 235 hope the above clarifies why a heuristic approach is not only necessary but
 236 desirable from a point of view of providing new users with as much safety as possible,
 237 and will allow any future discussion on the subject to focus on "how do we
 238 minimise annoyance to people deploying from checkouts intentionally".
 239
 240 =head1 SEE ALSO
 241
 242 =over 4
 243
 244 =item *
 245
 246 L<indirect>
 247
 248 =item *
 249
 250 L<multidimensional>
 251
 252 =item *
 253
 254 L<bareword::filehandles>
 255
 256 =back
 257
 258 =head1 COMMUNITY AND SUPPORT
 259
 260 =head2 IRC channel
 261
 262 irc.perl.org #toolchain
 263
 264 (or bug 'mst' in query on there or freenode)
 265
 266 =head2 Git repository
 267
 268 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 269
 270   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 271
 272 The web interface to the repository is at:
 273
 274   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 275
 276 =head1 AUTHOR
 277
 278 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 279
 280 =head1 CONTRIBUTORS
 281
 282 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 283
 284 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 285
 286 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 287
 288 =head1 COPYRIGHT
 289
 290 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 291 as listed above.
 292
 293 =head1 LICENSE
 294
 295 This library is free software and may be distributed under the same terms
 296 as perl itself.
 297
 298 =cut