lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 our $VERSION = '1.001000'; # 1.1.0
   7
   8 sub VERSION {
   9   for ($_[1]) {
  10     last unless defined && !ref && int != 1;
  11     die "Major version specified as $_ - this is strictures version 1";
  12   }
  13   shift->SUPER::VERSION(@_);
  14 }
  15
  16 sub import {
  17   strict->import;
  18   warnings->import(FATAL => 'all');
  19   my $do_indirect = do {
  20     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  21       $ENV{PERL_STRICTURES_EXTRA}
  22     } else {
  23       !!($0 =~ /^x?t\/.*(?:load|compile|coverage|use_ok).*\.t$/
  24          and (-e '.git' or -e '.svn'))
  25     }
  26   };
  27   if ($do_indirect) {
  28     if (eval { require indirect; 1 }) {
  29       indirect->unimport(':fatal');
  30     } else {
  31       die "strictures.pm extra testing active but couldn't load indirect.pm: $@";
  32     }
  33   }
  34 }
  35
  36 1;
  37
  38 __END__
  39 =head1 NAME
  40
  41 strictures - turn on strict and make all warnings fatal
  42
  43 =head1 SYNOPSIS
  44
  45   use strictures 1;
  46
  47 is equivalent to
  48
  49   use strict;
  50   use warnings FATAL => 'all';
  51
  52 except when called from a file where $0 matches:
  53
  54   /^x?t\/.*(?:load|compile|coverage|use_ok).*\.t$/
  55
  56 and when either '.git' or '.svn' is present in the current directory (with
  57 the intention of only forcing extra tests on the author side) - or when the
  58 PERL_STRICTURES_EXTRA environment variable is set, in which case
  59
  60   use strictures 1;
  61
  62 is equivalent to
  63
  64   use strict;
  65   use warnings FATAL => 'all';
  66   no indirect 'fatal';
  67
  68 Note that _EXTRA may at some point add even more tests, with only a minor
  69 version increase, but any changes to the effect of 'use strictures' in
  70 normal mode will involve a major version bump.
  71
  72 Be aware: THIS MEANS INDIRECT IS REQUIRED FOR AUTHORS OF STRICTURES USING
  73 CODE - but not by end users thereof.
  74
  75 =head1 DESCRIPTION
  76
  77 I've been writing the equivalent of this module at the top of my code for
  78 about a year now. I figured it was time to make it shorter.
  79
  80 Things like the importer in 'use Moose' don't help me because they turn
  81 warnings on but don't make them fatal - which from my point of view is
  82 useless because I want an exception to tell me my code isn't warnings clean.
  83
  84 Any time I see a warning from my code, that indicates a mistake.
  85
  86 Any time my code encounters a mistake, I want a crash - not spew to STDERR
  87 and then unknown (and probably undesired) subsequent behaviour.
  88
  89 I also want to ensure that obvious coding mistakes, like indirect object
  90 syntax (and not so obvious mistakes that cause things to accidentally compile
  91 as such) get caught, but not at the cost of an XS dependency and not at the
  92 cost of blowing things up on another machine.
  93
  94 Therefore, strictures turns on indirect checking only when it thinks it's
  95 running in a compilation (or pod coverage) test - though if this causes
  96 undesired behaviour this can be overriden by setting the
  97 PERL_STRICTURES_EXTRA environment variable.
  98
  99 If additional useful author side checks come to mind, I'll add them to the
 100 _EXTRA code path only - this will result in a minor version increase (i.e.
 101 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 102 this code will result in a subversion increas (i.e. 1.000000 to 1.000001
 103 (1.0.1)).
 104
 105 If the behaviour of 'use strictures' in normal mode changes in any way, that
 106 will constitute a major version increase - and the code already checks
 107 when its version is tested to ensure that
 108
 109   use strictures 1;
 110
 111 will continue to only introduce the current set of strictures even if 2.0 is
 112 installed.
 113
 114 =head1 METHODS
 115
 116 =head2 import
 117
 118 This method does the setup work described above in L</DESCRIPTION>
 119
 120 =head2 VERSION
 121
 122 This method traps the strictures->VERSION(1) call produced by a use line
 123 with a version number on it and does the version check.
 124
 125 =head1 COMMUNITY AND SUPPORT
 126
 127 =head2 IRC channel
 128
 129 irc.perl.org #toolchain
 130
 131 (or bug 'mst' in query on there or freenode)
 132
 133 =head2 Git repository
 134
 135 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 136
 137   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 138
 139 =head1 AUTHOR
 140
 141 Matt S. Trout <mst@shadowcat.co.uk>
 142
 143 =head1 CONTRIBUTORS
 144
 145 None required yet. Maybe this module is perfect (hahahahaha ...).
 146
 147 =head1 COPYRIGHT
 148
 149 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 150 as listed above.
 151
 152 =head1 LICENSE
 153
 154 This library is free software and may be distributed under the same terms
 155 as perl itself.
 156
 157 =cut