lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 use constant _PERL_LT_5_8_4 => ($] < 5.008004) ? 1 : 0;
   7
   8 our $VERSION = '1.004004'; # 1.4.4
   9
  10 sub VERSION {
  11   for ($_[1]) {
  12     last unless defined && !ref && int != 1;
  13     die "Major version specified as $_ - this is strictures version 1";
  14   }
  15   # disable this since Foo->VERSION(undef) correctly returns the version
  16   # and that can happen either if our caller passes undef explicitly or
  17   # because the for above autovivified $_[1] - I could make it stop but
  18   # it's pointless since we don't want to blow up if the caller does
  19   # something valid either.
  20   no warnings 'uninitialized';
  21   shift->SUPER::VERSION(@_);
  22 }
  23
  24 our $extra_load_states;
  25
  26 our $Smells_Like_VCS = (-e '.git' || -e '.svn'
  27   || (-e '../../dist.ini' && (-e '../../.git' || -e '../../.svn')));
  28
  29 sub import {
  30   strict->import;
  31   warnings->import(FATAL => 'all');
  32
  33   my $extra_tests = do {
  34     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  35       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  36         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  37           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  38       }
  39       $ENV{PERL_STRICTURES_EXTRA};
  40     } elsif (! _PERL_LT_5_8_4) {
  41       !!((caller)[1] =~ /^(?:t|xt|lib|blib)/
  42          and $Smells_Like_VCS)
  43     }
  44   };
  45   if ($extra_tests) {
  46     $extra_load_states ||= do {
  47
  48       my (%rv, @failed);
  49       foreach my $mod (qw(indirect multidimensional bareword::filehandles)) {
  50         eval "require $mod; \$rv{'$mod'} = 1;" or do {
  51           push @failed, $mod;
  52
  53           # courtesy of the 5.8 require bug
  54           # (we do a copy because 5.16.2 at least uses the same read-only
  55           # scalars for the qw() list and it doesn't seem worth a $^V check)
  56
  57           (my $file = $mod) =~ s|::|/|g;
  58           delete $INC{"${file}.pm"};
  59         };
  60       }
  61
  62       if (@failed) {
  63         my $failed = join ' ', @failed;
  64         print STDERR <<EOE;
  65 strictures.pm extra testing active but couldn't load all modules. Missing were:
  66
  67   $failed
  68
  69 Extra testing is auto-enabled in checkouts only, so if you're the author
  70 of a strictures-using module you need to run:
  71
  72   cpan indirect multidimensional bareword::filehandles
  73
  74 but these modules are not required by your users.
  75 EOE
  76       }
  77
  78       \%rv;
  79     };
  80
  81     indirect->unimport(':fatal') if $extra_load_states->{indirect};
  82     multidimensional->unimport if $extra_load_states->{multidimensional};
  83     bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  84   }
  85 }
  86
  87 1;
  88
  89 __END__
  90 =head1 NAME
  91
  92 strictures - turn on strict and make all warnings fatal
  93
  94 =head1 SYNOPSIS
  95
  96   use strictures 1;
  97
  98 is equivalent to
  99
 100   use strict;
 101   use warnings FATAL => 'all';
 102
 103 except when called from a file which matches:
 104
 105   (caller)[1] =~ /^(?:t|xt|lib|blib)/
 106
 107 and when either C<.git> or C<.svn> is present in the current directory (with
 108 the intention of only forcing extra tests on the author side) -- or when C<.git>
 109 or C<.svn> is present two directories up along with C<dist.ini> (which would
 110 indicate we are in a C<dzil test> operation, via L<Dist::Zilla>) --
 111 or when the C<PERL_STRICTURES_EXTRA> environment variable is set, in which case
 112
 113   use strictures 1;
 114
 115 is equivalent to
 116
 117   use strict;
 118   use warnings FATAL => 'all';
 119   no indirect 'fatal';
 120   no multidimensional;
 121   no bareword::filehandles;
 122
 123 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with only a minor
 124 version increase, but any changes to the effect of C<use strictures> in
 125 normal mode will involve a major version bump.
 126
 127 If any of the extra testing modules are not present, L<strictures> will
 128 complain loudly, once, via C<warn()>, and then shut up. But you really
 129 should consider installing them, they're all great anti-footgun tools.
 130
 131 =head1 DESCRIPTION
 132
 133 I've been writing the equivalent of this module at the top of my code for
 134 about a year now. I figured it was time to make it shorter.
 135
 136 Things like the importer in C<use Moose> don't help me because they turn
 137 warnings on but don't make them fatal -- which from my point of view is
 138 useless because I want an exception to tell me my code isn't warnings-clean.
 139
 140 Any time I see a warning from my code, that indicates a mistake.
 141
 142 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 143 and then unknown (and probably undesired) subsequent behaviour.
 144
 145 I also want to ensure that obvious coding mistakes, like indirect object
 146 syntax (and not so obvious mistakes that cause things to accidentally compile
 147 as such) get caught, but not at the cost of an XS dependency and not at the
 148 cost of blowing things up on another machine.
 149
 150 Therefore, L<strictures> turns on additional checking, but only when it thinks
 151 it's running in a test file in a VCS checkout -- although if this causes
 152 undesired behaviour this can be overridden by setting the
 153 C<PERL_STRICTURES_EXTRA> environment variable.
 154
 155 If additional useful author side checks come to mind, I'll add them to the
 156 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version increase (e.g.
 157 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 158 this code will result in a sub-version increase (e.g. 1.000000 to 1.000001
 159 (1.0.1)).
 160
 161 If the behaviour of C<use strictures> in normal mode changes in any way, that
 162 will constitute a major version increase -- and the code already checks
 163 when its version is tested to ensure that
 164
 165   use strictures 1;
 166
 167 will continue to only introduce the current set of strictures even if 2.0 is
 168 installed.
 169
 170 =head1 METHODS
 171
 172 =head2 import
 173
 174 This method does the setup work described above in L</DESCRIPTION>
 175
 176 =head2 VERSION
 177
 178 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 179 with a version number on it and does the version check.
 180
 181 =head1 EXTRA TESTING RATIONALE
 182
 183 Every so often, somebody complains that they're deploying via C<git pull>
 184 and that they don't want L<strictures> to enable itself in this case -- and that
 185 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 186 disable extra testing would be welcome but the discussion never seems to get
 187 that far).
 188
 189 In order to allow us to skip a couple of stages and get straight to a
 190 productive conversation, here's my current rationale for turning the
 191 extra testing on via a heuristic:
 192
 193 The extra testing is all stuff that only ever blows up at compile time;
 194 this is intentional. So the oft-raised concern that it's different code being
 195 tested is only sort of the case -- none of the modules involved affect the
 196 final optree to my knowledge, so the author gets some additional compile
 197 time crashes which he/she then fixes, and the rest of the testing is
 198 completely valid for all environments.
 199
 200 The point of the extra testing -- especially C<no indirect> -- is to catch
 201 mistakes that newbie users won't even realise are mistakes without
 202 help. For example,
 203
 204   foo { ... };
 205
 206 where foo is an & prototyped sub that you forgot to import -- this is
 207 pernicious to track down since all I<seems> fine until it gets called
 208 and you get a crash. Worse still, you can fail to have imported it due
 209 to a circular require, at which point you have a load order dependent
 210 bug which I've seen before now I<only> show up in production due to tiny
 211 differences between the production and the development environment. I wrote
 212 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 213 this particular problem before L<strictures> itself existed.
 214
 215 As such, in my experience so far L<strictures>' extra testing has
 216 I<avoided> production versus development differences, not caused them.
 217
 218 Additionally, L<strictures>' policy is very much "try and provide as much
 219 protection as possible for newbies -- who won't think about whether there's
 220 an option to turn on or not" -- so having only the environment variable
 221 is not sufficient to achieve that (I get to explain that you need to add
 222 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 223 completely skip steps because they don't understand that that step
 224 is important).
 225
 226 I make no claims that the heuristic is perfect -- it's already been evolved
 227 significantly over time, especially for 1.004 where we changed things to
 228 ensure it only fires on files in your checkout (rather than L<strictures>-using
 229 modules you happened to have installed, which was just silly). However, I
 230 hope the above clarifies why a heuristic approach is not only necessary but
 231 desirable from a point of view of providing new users with as much safety as possible,
 232 and will allow any future discussion on the subject to focus on "how do we
 233 minimise annoyance to people deploying from checkouts intentionally".
 234
 235 =head1 COMMUNITY AND SUPPORT
 236
 237 =head2 IRC channel
 238
 239 irc.perl.org #toolchain
 240
 241 (or bug 'mst' in query on there or freenode)
 242
 243 =head2 Git repository
 244
 245 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 246
 247   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 248
 249 The web interface to the repository is at:
 250
 251   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 252
 253 =head1 AUTHOR
 254
 255 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 256
 257 =head1 CONTRIBUTORS
 258
 259 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 260
 261 =head1 COPYRIGHT
 262
 263 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 264 as listed above.
 265
 266 =head1 LICENSE
 267
 268 This library is free software and may be distributed under the same terms
 269 as perl itself.
 270
 271 =cut