lib/namespace/clean.pm

   1 package namespace::clean;
   2
   3 =head1 NAME
   4
   5 namespace::clean - Keep imports and functions out of your namespace
   6
   7 =cut
   8
   9 use warnings;
  10 use strict;
  11
  12 use vars              qw( $VERSION $STORAGE_VAR );
  13 use Symbol            qw( qualify_to_ref );
  14 use Filter::EOF;
  15
  16 =head1 VERSION
  17
  18 0.06
  19
  20 =cut
  21
  22 $VERSION     = 0.06;
  23 $STORAGE_VAR = '__NAMESPACE_CLEAN_STORAGE';
  24
  25 =head1 SYNOPSIS
  26
  27   package Foo;
  28   use warnings;
  29   use strict;
  30
  31   use Carp qw(croak);   # 'croak' will be removed
  32
  33   sub bar { 23 }        # 'bar' will be removed
  34
  35   # remove all previously defined functions
  36   use namespace::clean;
  37
  38   sub baz { bar() }     # 'baz' still defined, 'bar' still bound
  39
  40   # begin to collection function names from here again
  41   no namespace::clean;
  42
  43   sub quux { baz() }    # 'quux' will be removed
  44
  45   # remove all functions defined after the 'no' unimport
  46   use namespace::clean;
  47
  48   # Will print: 'No', 'No', 'Yes' and 'No'
  49   print +(__PACKAGE__->can('croak') ? 'Yes' : 'No'), "\n";
  50   print +(__PACKAGE__->can('bar')   ? 'Yes' : 'No'), "\n";
  51   print +(__PACKAGE__->can('baz')   ? 'Yes' : 'No'), "\n";
  52   print +(__PACKAGE__->can('quux')  ? 'Yes' : 'No'), "\n";
  53
  54   1;
  55
  56 =head1 DESCRIPTION
  57
  58 When you define a function, or import one, into a Perl package, it will
  59 naturally also be available as a method. This does not per se cause
  60 problems, but it can complicate subclassing and, for example, plugin
  61 classes that are included via multiple inheritance by loading them as
  62 base classes.
  63
  64 The C<namespace::clean> pragma will remove all previously declared or
  65 imported symbols at the end of the current package's compile cycle.
  66 Functions called in the package itself will still be bound by their
  67 name, but they won't show up as methods on your class or instances.
  68
  69 By unimporting via C<no> you can tell C<namespace::clean> to start
  70 collecting functions for the next C<use namespace::clean;> specification.
  71
  72 You can use the C<-except> flag to tell C<namespace::clean> that you
  73 don't want it to remove a certain function or method. A common use would
  74 be a module exporting an C<import> method along with some functions:
  75
  76   use ModuleExportingImport;
  77   use namespace::clean -except => [qw( import )];
  78
  79 If you just want to C<-except> a single sub, you can pass it directly.
  80 For more than one value you have to use an array reference.
  81
  82 =head1 METHODS
  83
  84 You shouldn't need to call any of these. Just C<use> the package at the
  85 appropriate place.
  86
  87 =cut
  88
  89 =head2 import
  90
  91 Makes a snapshot of the current defined functions and registers a
  92 L<Filter::EOF> cleanup routine to remove those symbols at the end
  93 of the compile-time.
  94
  95 =cut
  96
  97 sub import {
  98     my ($pragma, %args) = @_;
  99
 100     # calling class, all current functions and our storage
 101     my $cleanee   = caller;
 102     my $functions = $pragma->get_functions($cleanee);
 103     my $store     = $pragma->get_class_store($cleanee);
 104
 105     # except parameter can be array ref or single value
 106     my %except = map {( $_ => 1 )} (
 107         $args{ -except }
 108         ? ( ref $args{ -except } eq 'ARRAY' ? @{ $args{ -except } } : $args{ -except } )
 109         : ()
 110     );
 111
 112     # register symbols for removal, if they have a CODE entry
 113     for my $f (keys %$functions) {
 114         next if     $except{ $f };
 115         next unless    $functions->{ $f }
 116                 and *{ $functions->{ $f } }{CODE};
 117         $store->{remove}{ $f } = 1;
 118     }
 119
 120     # register EOF handler on first call to import
 121     unless ($store->{handler_is_installed}) {
 122         Filter::EOF->on_eof_call(sub {
 123           SYMBOL:
 124             for my $f (keys %{ $store->{remove} }) {
 125
 126                 # ignore already removed symbols
 127                 next SYMBOL if $store->{exclude}{ $f };
 128                 no strict 'refs';
 129
 130                 # keep original value to restore non-code slots
 131                 {   no warnings 'uninitialized';    # fix possible unimports
 132                     local *__tmp = *{ ${ "${cleanee}::" }{ $f } };
 133                     delete ${ "${cleanee}::" }{ $f };
 134                 }
 135
 136               SLOT:
 137                 # restore non-code slots to symbol
 138                 for my $t (qw( SCALAR ARRAY HASH IO FORMAT )) {
 139                     next SLOT unless defined *__tmp{ $t };
 140                     *{ "${cleanee}::$f" } = *__tmp{ $t };
 141                 }
 142             }
 143         });
 144         $store->{handler_is_installed} = 1;
 145     }
 146
 147     return 1;
 148 }
 149
 150 =head2 unimport
 151
 152 This method will be called when you do a
 153
 154   no namespace::clean;
 155
 156 It will start a new section of code that defines functions to clean up.
 157
 158 =cut
 159
 160 sub unimport {
 161     my ($pragma) = @_;
 162
 163     # the calling class, the current functions and our storage
 164     my $cleanee   = caller;
 165     my $functions = $pragma->get_functions($cleanee);
 166     my $store     = $pragma->get_class_store($cleanee);
 167
 168     # register all unknown previous functions as excluded
 169     for my $f (keys %$functions) {
 170         next if $store->{remove}{ $f }
 171              or $store->{exclude}{ $f };
 172         $store->{exclude}{ $f } = 1;
 173     }
 174
 175     return 1;
 176 }
 177
 178 =head2 get_class_store
 179
 180 This returns a reference to a hash in a passed package containing
 181 information about function names included and excluded from removal.
 182
 183 =cut
 184
 185 sub get_class_store {
 186     my ($pragma, $class) = @_;
 187     no strict 'refs';
 188     return \%{ "${class}::${STORAGE_VAR}" };
 189 }
 190
 191 =head2 get_functions
 192
 193 Takes a class as argument and returns all currently defined functions
 194 in it as a hash reference with the function name as key and a typeglob
 195 reference to the symbol as value.
 196
 197 =cut
 198
 199 sub get_functions {
 200     my ($pragma, $class) = @_;
 201
 202     return {
 203         map  { @$_ }                                        # key => value
 204         grep { *{ $_->[1] }{CODE} }                         # only functions
 205         map  { [$_, qualify_to_ref( $_, $class )] }         # get globref
 206         grep { $_ !~ /::$/ }                                # no packages
 207         do   { no strict 'refs'; keys %{ "${class}::" } }   # symbol entries
 208     };
 209 }
 210
 211 =head1 IMPLEMENTATION DETAILS
 212
 213 This module works through the effect that a
 214
 215   delete $SomePackage::{foo};
 216
 217 will remove the C<foo> symbol from C<$SomePackage> for run time lookups
 218 (e.g., method calls) but will leave the entry alive to be called by
 219 already resolved names in the package itself. C<namespace::clean> will
 220 restore and therefor in effect keep all glob slots that aren't C<CODE>.
 221
 222 A test file has been added to the perl core to ensure that this behaviour
 223 will be stable in future releases.
 224
 225 Just for completeness sake, if you want to remove the symbol completely,
 226 use C<undef> instead.
 227
 228 =head1 SEE ALSO
 229
 230 L<Filter::EOF>
 231
 232 =head1 AUTHOR AND COPYRIGHT
 233
 234 Robert 'phaylon' Sedlacek C<E<lt>rs@474.atE<gt>>, with many thanks to
 235 Matt S Trout for the inspiration on the whole idea.
 236
 237 =head1 LICENSE
 238
 239 This program is free software; you can redistribute it and/or modify
 240 it under the same terms as perl itself.
 241
 242 =cut
 243
 244 1;