t/taint-mode.t

   1 #
   2 # t/taint-mode.t: checks that local::lib sets up @INC correctly when
   3 # included in a script that has taint mode on, and is executing in an
   4 # environment in which local::lib has already been loaded.
   5 #
   6
   7 use strict;
   8 use warnings;
   9 use Test::More tests => 1;
  10 use File::Temp 'tempfile';
  11 use Cwd;
  12
  13 use lib 't/lib'; use TempDir;
  14
  15 my $dir1 = mk_temp_dir('test_local_lib-XXXXX');
  16
  17 # Set up local::lib environment using our temp dir
  18 require local::lib;
  19 local::lib->import($dir1);
  20
  21 # Create a script that has taint mode turned on, and tries to use a
  22 # local lib to the same temp dir.
  23 my ($fh, $filename) = tempfile('test_local_lib-XXXXX', DIR => Cwd::abs_path('t'), UNLINK => 1);
  24
  25 # escape backlslashes for embedding into generated script
  26 $dir1 =~ s/\\/\\\\/g;
  27
  28 print $fh <<EOM;
  29 #!/usr/bin/perl -T
  30 use strict; use warnings;
  31 use local::lib '$dir1';
  32 warn "using lib dir $dir1\\n";
  33 my \$quoted_dir = quotemeta('$dir1');
  34 if (grep { m{^\$quoted_dir} } \@INC) {
  35   exit 0;
  36 }
  37 warn '\@INC is: ', join("\\n", \@INC), "\\n";
  38 exit 1
  39 EOM
  40 close $fh;
  41
  42 my $exit_val = system($^X, '-Ilib', '-T', $filename);
  43
  44 is($exit_val >> 8, 0, 'test script exited with 0, local::lib dir found in @INC');