lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '2.000004'; # 2.0.4
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16   push @args, @ARGV
  17     if $0 eq '-';
  18
  19   my @steps;
  20   my %opts;
  21   my $shelltype;
  22
  23   while (@args) {
  24     my $arg = shift @args;
  25     # check for lethal dash first to stop processing before causing problems
  26     # the fancy dash is U+2212 or \xE2\x88\x92
  27     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  28       die <<'DEATH';
  29 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  30 These are *not* the traditional -- dashes that software recognizes. You
  31 probably got these by copy-pasting from the perldoc for this module as
  32 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  33 terminal, but can happen elsewhere too. Please try again after replacing the
  34 dashes with normal minus signs.
  35 DEATH
  36     }
  37     elsif ($arg eq '--self-contained') {
  38       die <<'DEATH';
  39 FATAL: The local::lib --self-contained flag has never worked reliably and the
  40 original author, Mark Stosberg, was unable or unwilling to maintain it. As
  41 such, this flag has been removed from the local::lib codebase in order to
  42 prevent misunderstandings and potentially broken builds. The local::lib authors
  43 recommend that you look at the lib::core::only module shipped with this
  44 distribution in order to create a more robust environment that is equivalent to
  45 what --self-contained provided (although quite possibly not what you originally
  46 thought it provided due to the poor quality of the documentation, for which we
  47 apologise).
  48 DEATH
  49     }
  50     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  51       my $path = defined $1 ? $1 : shift @args;
  52       push @steps, ['deactivate', $path];
  53     }
  54     elsif ( $arg eq '--deactivate-all' ) {
  55       push @steps, ['deactivate_all'];
  56     }
  57     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  58       $shelltype = defined $1 ? $1 : shift @args;
  59     }
  60     elsif ( $arg eq '--no-create' ) {
  61       $opts{no_create} = 1;
  62     }
  63     elsif ( $arg =~ /^--/ ) {
  64       die "Unknown import argument: $arg";
  65     }
  66     else {
  67       push @steps, ['activate', $arg];
  68     }
  69   }
  70   if (!@steps) {
  71     push @steps, ['activate', undef];
  72   }
  73
  74   my $self = $class->new(%opts);
  75
  76   for (@steps) {
  77     my ($method, @args) = @$_;
  78     $self = $self->$method(@args);
  79   }
  80
  81   if ($0 eq '-') {
  82     print $self->environment_vars_string($shelltype);
  83     exit 0;
  84   }
  85   else {
  86     $self->setup_local_lib;
  87   }
  88 }
  89
  90 sub new {
  91   my $class = shift;
  92   bless {@_}, $class;
  93 }
  94
  95 sub clone {
  96   my $self = shift;
  97   bless {%$self, @_}, ref $self;
  98 }
  99
 100 sub inc { $_[0]->{inc}     ||= \@INC }
 101 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
 102 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
 103 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
 104 sub extra { $_[0]->{extra} ||= {} }
 105 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
 106 sub no_create { $_[0]->{no_create} }
 107
 108 my $_archname = $Config{archname};
 109 my $_version  = $Config{version};
 110 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
 111 my $_path_sep = $Config{path_sep};
 112
 113 sub _as_list {
 114   my $list = shift;
 115   grep length, map {
 116     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 117       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 118                         : ()
 119     )
 120   } ref $list ? @$list : $list;
 121 }
 122 sub _remove_from {
 123   my ($list, @remove) = @_;
 124   return @$list
 125     if !@remove;
 126   my %remove = map { $_ => 1 } @remove;
 127   grep !$remove{$_}, _as_list($list);
 128 }
 129
 130 my @_lib_subdirs = (
 131   [$_version, $_archname],
 132   [$_version],
 133   [$_archname],
 134   (@_inc_version_list ? \@_inc_version_list : ()),
 135   [],
 136 );
 137
 138 sub install_base_bin_path {
 139   my ($class, $path) = @_;
 140   return File::Spec->catdir($path, 'bin');
 141 }
 142 sub install_base_perl_path {
 143   my ($class, $path) = @_;
 144   return File::Spec->catdir($path, 'lib', 'perl5');
 145 }
 146 sub install_base_arch_path {
 147   my ($class, $path) = @_;
 148   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 149 }
 150
 151 sub lib_paths_for {
 152   my ($class, $path) = @_;
 153   my $base = $class->install_base_perl_path($path);
 154   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 155 }
 156
 157 sub _mm_escape_path {
 158   my $path = shift;
 159   $path =~ s/\\/\\\\\\\\/g;
 160   if ($path =~ s/ /\\ /g) {
 161     $path = qq{"\\"$path\\""};
 162   }
 163   return $path;
 164 }
 165
 166 sub _mb_escape_path {
 167   my $path = shift;
 168   $path =~ s/\\/\\\\/g;
 169   return qq{"$path"};
 170 }
 171
 172 sub installer_options_for {
 173   my ($class, $path) = @_;
 174   return (
 175     PERL_MM_OPT =>
 176       defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 177     PERL_MB_OPT =>
 178       defined $path ? "--install_base "._mb_escape_path($path) : undef,
 179   );
 180 }
 181
 182 sub active_paths {
 183   my ($self) = @_;
 184   $self = ref $self ? $self : $self->new;
 185
 186   return grep {
 187     # screen out entries that aren't actually reflected in @INC
 188     my $active_ll = $self->install_base_perl_path($_);
 189     grep { $_ eq $active_ll } @{$self->inc};
 190   } _as_list($self->roots);
 191 }
 192
 193
 194 sub deactivate {
 195   my ($self, $path) = @_;
 196   $self = $self->new unless ref $self;
 197   $path = $self->resolve_path($path);
 198   $path = $self->normalize_path($path);
 199
 200   my @active_lls = $self->active_paths;
 201
 202   if (!grep { $_ eq $path } @active_lls) {
 203     warn "Tried to deactivate inactive local::lib '$path'\n";
 204     return $self;
 205   }
 206
 207   my %args = (
 208     bins  => [ _remove_from($self->bins,
 209       $self->install_base_bin_path($path)) ],
 210     libs  => [ _remove_from($self->libs,
 211       $self->install_base_perl_path($path)) ],
 212     inc   => [ _remove_from($self->inc,
 213       $self->lib_paths_for($path)) ],
 214     roots => [ _remove_from($self->roots, $path) ],
 215   );
 216
 217   $args{extra} = { $self->installer_options_for($args{roots}[0]) };
 218
 219   $self->clone(%args);
 220 }
 221
 222 sub deactivate_all {
 223   my ($self) = @_;
 224   $self = $self->new unless ref $self;
 225
 226   my @active_lls = $self->active_paths;
 227
 228   my %args;
 229   if (@active_lls) {
 230     %args = (
 231       bins => [ _remove_from($self->bins,
 232         map $self->install_base_bin_path($_), @active_lls) ],
 233       libs => [ _remove_from($self->libs,
 234         map $self->install_base_perl_path($_), @active_lls) ],
 235       inc => [ _remove_from($self->inc,
 236         map $self->lib_paths_for($_), @active_lls) ],
 237       roots => [ _remove_from($self->roots, @active_lls) ],
 238     );
 239   }
 240
 241   $args{extra} = { $self->installer_options_for(undef) };
 242
 243   $self->clone(%args);
 244 }
 245
 246 sub activate {
 247   my ($self, $path) = @_;
 248   $self = $self->new unless ref $self;
 249   $path = $self->resolve_path($path);
 250   $self->ensure_dir_structure_for($path)
 251     unless $self->no_create;
 252
 253   $path = $self->normalize_path($path);
 254
 255   my @active_lls = $self->active_paths;
 256
 257   if (grep { $_ eq $path } @active_lls[1 .. $#active_lls]) {
 258     $self = $self->deactivate($path);
 259   }
 260
 261   my %args;
 262   if (!@active_lls || $active_lls[0] ne $path) {
 263     %args = (
 264       bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 265       libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 266       inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 267       roots => [ $path, @{$self->roots} ],
 268     );
 269   }
 270
 271   $args{extra} = { $self->installer_options_for($path) };
 272
 273   $self->clone(%args);
 274 }
 275
 276 sub normalize_path {
 277   my ($self, $path) = @_;
 278   $path = ( Win32::GetShortPathName($path) || $path )
 279     if $^O eq 'MSWin32';
 280   return $path;
 281 }
 282
 283 sub build_environment_vars_for {
 284   my $self = $_[0]->new->activate($_[1]);
 285   $self->build_environment_vars;
 286 }
 287 sub build_environment_vars {
 288   my $self = shift;
 289   (
 290     PATH                => join($_path_sep, _as_list($self->bins)),
 291     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 292     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 293     %{$self->extra},
 294   );
 295 }
 296
 297 sub setup_local_lib_for {
 298   my $self = $_[0]->new->activate($_[1]);
 299   $self->setup_local_lib;
 300 }
 301
 302 sub setup_local_lib {
 303   my $self = shift;
 304   $self->setup_env_hash;
 305   @INC = @{$self->inc};
 306 }
 307
 308 sub setup_env_hash_for {
 309   my $self = $_[0]->new->activate($_[1]);
 310   $self->setup_env_hash;
 311 }
 312 sub setup_env_hash {
 313   my $self = shift;
 314   my %env = $self->build_environment_vars;
 315   for my $key (keys %env) {
 316     if (defined $env{$key}) {
 317       $ENV{$key} = $env{$key};
 318     }
 319     else {
 320       delete $ENV{$key};
 321     }
 322   }
 323 }
 324
 325 sub print_environment_vars_for {
 326   print $_[0]->environment_vars_string_for(@_[1..$#_]);
 327 }
 328
 329 sub environment_vars_string_for {
 330   my $self = $_[0]->new->activate($_[1]);
 331   $self->environment_vars_string;
 332 }
 333 sub environment_vars_string {
 334   my ($self, $shelltype) = @_;
 335
 336   $shelltype ||= $self->guess_shelltype;
 337
 338   my $build_method = "build_${shelltype}_env_declaration";
 339
 340   my @envs = (
 341     PATH                => $self->bins,
 342     PERL5LIB            => $self->libs,
 343     PERL_LOCAL_LIB_ROOT => $self->roots,
 344     %{$self->extra},
 345   );
 346   my $out = '';
 347   while (@envs) {
 348     my ($name, $value) = (shift(@envs), shift(@envs));
 349     if (
 350         ref $value
 351         && @$value == 1
 352         && ref $value->[0]
 353         && ref $value->[0] eq 'SCALAR'
 354         && ${$value->[0]} eq $name) {
 355       next;
 356     }
 357     if (
 358         !ref $value
 359         and defined $value
 360           ? (defined $ENV{$name} && $value eq $ENV{$name})
 361           : !defined $ENV{$name}
 362     ) {
 363       next;
 364     }
 365     $out .= $self->$build_method($name, $value);
 366   }
 367   my $wrap_method = 'wrap_' . $self->shelltype . '_output';
 368   if ($self->can($wrap_method)) {
 369     return $self->$wrap_method($out);
 370   }
 371   return $out;
 372 }
 373
 374 sub build_bourne_env_declaration {
 375   my ($class, $name, $args) = @_;
 376   my $value = $class->_interpolate($args, '$%s', '"', '\\%s');
 377
 378   if (!defined $value) {
 379     return qq{unset $name;\n};
 380   }
 381
 382   $value =~ s/(^|\G|$_path_sep)\$$name$_path_sep/$1\$$name\${$name+$_path_sep}/g;
 383   $value =~ s/$_path_sep\$$name$/\${$name+$_path_sep}\$$name/;
 384
 385   qq{${name}="$value";\nexport ${name};\n}
 386 }
 387
 388 sub build_csh_env_declaration {
 389   my ($class, $name, $args) = @_;
 390   my ($value, @vars) = $class->_interpolate($args, '$%s', '"', '"\\%s"');
 391   if (!defined $value) {
 392     return qq{unsetenv $name;\n};
 393   }
 394
 395   my $out = '';
 396   for my $var (@vars) {
 397     $out .= qq{if ! \$?$name setenv $name '';\n};
 398   }
 399
 400   my $value_without = $value;
 401   if ($value_without =~ s/(?:^|$_path_sep)\$$name(?:$_path_sep|$)//g) {
 402     $out .= qq{if "\$$name" != '' setenv $name "$value";\n};
 403     $out .= qq{if "\$$name" == '' };
 404   }
 405   $out .= qq{setenv $name "$value_without";\n};
 406   return $out;
 407 }
 408
 409 sub build_cmd_env_declaration {
 410   my ($class, $name, $args) = @_;
 411   my $value = $class->_interpolate($args, '%%%s%%', qr([()!^"<>&|]), '^%s');
 412   if (!$value) {
 413     return qq{\@set $name=\n};
 414   }
 415
 416   my $out = '';
 417   my $value_without = $value;
 418   if ($value_without =~ s/(?:^|$_path_sep)%$name%(?:$_path_sep|$)//g) {
 419     $out .= qq{\@if not "%$name%"=="" set $name=$value\n};
 420     $out .= qq{\@if "%$name%"=="" };
 421   }
 422   $out .= qq{\@set $name=$value_without\n};
 423   return $out;
 424 }
 425
 426 sub build_powershell_env_declaration {
 427   my ($class, $name, $args) = @_;
 428   my $value = $class->_interpolate($args, '$env:%s', '"', '`%s');
 429
 430   if (!$value) {
 431     return qq{Remove-Item -ErrorAction 0 Env:\\$name;\n};
 432   }
 433
 434   my $maybe_path_sep = qq{\$(if("\$env:$name"-eq""){""}else{"$_path_sep"})};
 435   $value =~ s/(^|\G|$_path_sep)\$env:$name$_path_sep/$1\$env:$name"+$maybe_path_sep+"/g;
 436   $value =~ s/$_path_sep\$env:$name$/"+$maybe_path_sep+\$env:$name+"/;
 437
 438   qq{\$env:$name = \$("$value");\n};
 439 }
 440 sub wrap_powershell_output {
 441   my ($class, $out) = @_;
 442   return $out || " \n";
 443 }
 444
 445 sub _interpolate {
 446   my ($class, $args, $var_pat, $escape, $escape_pat) = @_;
 447   return
 448     unless defined $args;
 449   my @args = ref $args ? @$args : $args;
 450   return
 451     unless @args;
 452   my @vars = map { $$_ } grep { ref $_ eq 'SCALAR' } @args;
 453   my $string = join $_path_sep, map {
 454     ref $_ eq 'SCALAR' ? sprintf($var_pat, $$_) : do {
 455       s/($escape)/sprintf($escape_pat, $1)/ge; $_;
 456     };
 457   } @args;
 458   return wantarray ? ($string, \@vars) : $string;
 459 }
 460
 461 sub pipeline;
 462
 463 sub pipeline {
 464   my @methods = @_;
 465   my $last = pop(@methods);
 466   if (@methods) {
 467     \sub {
 468       my ($obj, @args) = @_;
 469       $obj->${pipeline @methods}(
 470         $obj->$last(@args)
 471       );
 472     };
 473   } else {
 474     \sub {
 475       shift->$last(@_);
 476     };
 477   }
 478 }
 479
 480 sub resolve_path {
 481   my ($class, $path) = @_;
 482
 483   $path = $class->${pipeline qw(
 484     resolve_relative_path
 485     resolve_home_path
 486     resolve_empty_path
 487   )}($path);
 488
 489   $path;
 490 }
 491
 492 sub resolve_empty_path {
 493   my ($class, $path) = @_;
 494   if (defined $path) {
 495     $path;
 496   } else {
 497     '~/perl5';
 498   }
 499 }
 500
 501 sub resolve_home_path {
 502   my ($class, $path) = @_;
 503   return $path unless ($path =~ /^~/);
 504   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 505   my $homedir = do {
 506     if (!defined $user && defined $ENV{HOME}) {
 507       $ENV{HOME}
 508     }
 509     else {
 510       require File::Glob;
 511       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 512     }
 513   };
 514   unless (defined $homedir) {
 515     require Carp;
 516     Carp::croak(
 517       "Couldn't resolve homedir for "
 518       .(defined $user ? $user : 'current user')
 519     );
 520   }
 521   $path =~ s/^~[^\/]*/$homedir/;
 522   $path;
 523 }
 524
 525 sub resolve_relative_path {
 526   my ($class, $path) = @_;
 527   $path = File::Spec->rel2abs($path);
 528 }
 529
 530 sub ensure_dir_structure_for {
 531   my ($class, $path) = @_;
 532   unless (-d $path) {
 533     warn "Attempting to create directory ${path}\n";
 534   }
 535   require File::Basename;
 536   my @dirs;
 537   while(!-d $path) {
 538     push @dirs, $path;
 539     $path = File::Basename::dirname($path);
 540   }
 541   mkdir $_ for reverse @dirs;
 542   return;
 543 }
 544
 545 sub guess_shelltype {
 546   my $shellbin
 547     = defined $ENV{SHELL}
 548       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 549     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 550       ? 'bash'
 551     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 552       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 553     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 554       ? 'powershell.exe'
 555     : 'sh';
 556
 557   for ($shellbin) {
 558     return
 559         /csh$/                   ? 'csh'
 560       : /command(?:\.com)?$/i    ? 'cmd'
 561       : /cmd(?:\.exe)?$/i        ? 'cmd'
 562       : /4nt(?:\.exe)?$/i        ? 'cmd'
 563       : /powershell(?:\.exe)?$/i ? 'powershell'
 564                                  : 'bourne';
 565   }
 566 }
 567
 568 1;
 569 __END__
 570
 571 =encoding utf8
 572
 573 =head1 NAME
 574
 575 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 576
 577 =head1 SYNOPSIS
 578
 579 In code -
 580
 581   use local::lib; # sets up a local lib at ~/perl5
 582
 583   use local::lib '~/foo'; # same, but ~/foo
 584
 585   # Or...
 586   use FindBin;
 587   use local::lib "$FindBin::Bin/../support";  # app-local support library
 588
 589 From the shell -
 590
 591   # Install LWP and its missing dependencies to the '~/perl5' directory
 592   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 593
 594   # Just print out useful shell commands
 595   $ perl -Mlocal::lib
 596   export PERL_MB_OPT='--install_base /home/username/perl5'
 597   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 598   export PERL5LIB="/home/username/perl5/lib/perl5"
 599   export PATH="/home/username/perl5/bin:$PATH"
 600
 601 From a .bashrc file -
 602
 603   [ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)"
 604
 605 =head2 The bootstrapping technique
 606
 607 A typical way to install local::lib is using what is known as the
 608 "bootstrapping" technique.  You would do this if your system administrator
 609 hasn't already installed local::lib.  In this case, you'll need to install
 610 local::lib in your home directory.
 611
 612 Even if you do have administrative privileges, you will still want to set up your
 613 environment variables, as discussed in step 4. Without this, you would still
 614 install the modules into the system CPAN installation and also your Perl scripts
 615 will not use the lib/ path you bootstrapped with local::lib.
 616
 617 By default local::lib installs itself and the CPAN modules into ~/perl5.
 618
 619 Windows users must also see L</Differences when using this module under Win32>.
 620
 621 =over 4
 622
 623 =item 1.
 624
 625 Download and unpack the local::lib tarball from CPAN (search for "Download"
 626 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 627 or administrator.  Unpack the file in your home directory or in any other
 628 convenient location.
 629
 630 =item 2.
 631
 632 Run this:
 633
 634   perl Makefile.PL --bootstrap
 635
 636 If the system asks you whether it should automatically configure as much
 637 as possible, you would typically answer yes.
 638
 639 In order to install local::lib into a directory other than the default, you need
 640 to specify the name of the directory when you call bootstrap, as follows:
 641
 642   perl Makefile.PL --bootstrap=~/foo
 643
 644 =item 3.
 645
 646 Run this: (local::lib assumes you have make installed on your system)
 647
 648   make test && make install
 649
 650 =item 4.
 651
 652 Now we need to setup the appropriate environment variables, so that Perl
 653 starts using our newly generated lib/ directory. If you are using bash or
 654 any other Bourne shells, you can add this to your shell startup script this
 655 way:
 656
 657   echo '[ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)"' >>~/.bashrc
 658
 659 If you are using C shell, you can do this as follows:
 660
 661   /bin/csh
 662   echo $SHELL
 663   /bin/csh
 664   echo 'eval `perl -I$HOME/perl5/lib/perl5 -Mlocal::lib`' >> ~/.cshrc
 665
 666 If you passed to bootstrap a directory other than default, you also need to
 667 give that as import parameter to the call of the local::lib module like this
 668 way:
 669
 670   echo '[ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)"' >>~/.bashrc
 671
 672 After writing your shell configuration file, be sure to re-read it to get the
 673 changed settings into your current shell's environment. Bourne shells use
 674 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 675
 676 =back
 677
 678 If you're on a slower machine, or are operating under draconian disk space
 679 limitations, you can disable the automatic generation of manpages from POD when
 680 installing modules by using the C<--no-manpages> argument when bootstrapping:
 681
 682   perl Makefile.PL --bootstrap --no-manpages
 683
 684 To avoid doing several bootstrap for several Perl module environments on the
 685 same account, for example if you use it for several different deployed
 686 applications independently, you can use one bootstrapped local::lib
 687 installation to install modules in different directories directly this way:
 688
 689   cd ~/mydir1
 690   perl -Mlocal::lib=./
 691   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 692   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 693   perl -MCPAN -e install ...    ### whatever modules you want
 694   cd ../mydir2
 695   ... REPEAT ...
 696
 697 When used in a C<.bashrc> file, it is recommended that you protect against
 698 re-activating a directory in a sub-shell.  This can be done by checking the
 699 C<$SHLVL> variable as shown in synopsis.  Without this, sub-shells created by
 700 the user or other programs will override changes made to the parent shell's
 701 environment.
 702
 703 If you are working with several C<local::lib> environments, you may want to
 704 remove some of them from the current environment without disturbing the others.
 705 You can deactivate one environment like this (using bourne sh):
 706
 707   eval $(perl -Mlocal::lib=--deactivate,~/path)
 708
 709 which will generate and run the commands needed to remove C<~/path> from your
 710 various search paths. Whichever environment was B<activated most recently> will
 711 remain the target for module installations. That is, if you activate
 712 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 713 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 714 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 715 installed in C<~/pathB> because pathB was activated later.
 716
 717 You can also ask C<local::lib> to clean itself completely out of the current
 718 shell's environment with the C<--deactivate-all> option.
 719 For multiple environments for multiple apps you may need to include a modified
 720 version of the C<< use FindBin >> instructions in the "In code" sample above.
 721 If you did something like the above, you have a set of Perl modules at C<<
 722 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 723 you need to tell it where to find the modules you installed for it at C<<
 724 ~/mydir1/lib >>.
 725
 726 In C<< ~/mydir1/scripts/myscript.pl >>:
 727
 728   use strict;
 729   use warnings;
 730   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 731   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 732
 733 Put this before any BEGIN { ... } blocks that require the modules you installed.
 734
 735 =head2 Differences when using this module under Win32
 736
 737 To set up the proper environment variables for your current session of
 738 C<CMD.exe>, you can use this:
 739
 740   C:\>perl -Mlocal::lib
 741   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 742   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 743   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 744   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 745
 746   ### To set the environment for this shell alone
 747   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 748   ### instead of $(perl -Mlocal::lib=./)
 749
 750 If you want the environment entries to persist, you'll need to add them to the
 751 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 752
 753 The "~" is translated to the user's profile directory (the directory named for
 754 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 755 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 756 directory is translated to a short name (which means the directory must exist)
 757 and the subdirectories are created.
 758
 759 =head3 PowerShell
 760
 761 local::lib also supports PowerShell, and can be used with the
 762 C<Invoke-Expression> cmdlet.
 763
 764   Invoke-Expression "$(perl -Mlocal::lib)"
 765
 766 =head1 RATIONALE
 767
 768 The version of a Perl package on your machine is not always the version you
 769 need.  Obviously, the best thing to do would be to update to the version you
 770 need.  However, you might be in a situation where you're prevented from doing
 771 this.  Perhaps you don't have system administrator privileges; or perhaps you
 772 are using a package management system such as Debian, and nobody has yet gotten
 773 around to packaging up the version you need.
 774
 775 local::lib solves this problem by allowing you to create your own directory of
 776 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 777 be within your own home directory).  The existing system Perl installation is
 778 not affected; you simply invoke Perl with special options so that Perl uses the
 779 packages in your own local package directory rather than the system packages.
 780 local::lib arranges things so that your locally installed version of the Perl
 781 packages takes precedence over the system installation.
 782
 783 If you are using a package management system (such as Debian), you don't need to
 784 worry about Debian and CPAN stepping on each other's toes.  Your local version
 785 of the packages will be written to an entirely separate directory from those
 786 installed by Debian.
 787
 788 =head1 DESCRIPTION
 789
 790 This module provides a quick, convenient way of bootstrapping a user-local Perl
 791 module library located within the user's home directory. It also constructs and
 792 prints out for the user the list of environment variables using the syntax
 793 appropriate for the user's current shell (as specified by the C<SHELL>
 794 environment variable), suitable for directly adding to one's shell
 795 configuration file.
 796
 797 More generally, local::lib allows for the bootstrapping and usage of a
 798 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 799 easier to ship an application with an app-specific copy of a Perl module, or
 800 collection of modules. Useful in cases like when an upstream maintainer hasn't
 801 applied a patch to a module of theirs that you need for your application.
 802
 803 On import, local::lib sets the following environment variables to appropriate
 804 values:
 805
 806 =over 4
 807
 808 =item PERL_MB_OPT
 809
 810 =item PERL_MM_OPT
 811
 812 =item PERL5LIB
 813
 814 =item PATH
 815
 816 =item PERL_LOCAL_LIB_ROOT
 817
 818 =back
 819
 820 When possible, these will be appended to instead of overwritten entirely.
 821
 822 These values are then available for reference by any code after import.
 823
 824 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 825
 826 See L<lib::core::only> for one way to do this - but note that
 827 there are a number of caveats, and the best approach is always to perform a
 828 build against a clean perl (i.e. site and vendor as close to empty as possible).
 829
 830 =head1 IMPORT OPTIONS
 831
 832 Options are values that can be passed to the C<local::lib> import besides the
 833 directory to use. They are specified as C<use local::lib '--option'[, path];>
 834 or C<perl -Mlocal::lib=--option[,path]>.
 835
 836 =head2 --deactivate
 837
 838 Remove the chosen path (or the default path) from the module search paths if it
 839 was added by C<local::lib>, instead of adding it.
 840
 841 =head2 --deactivate-all
 842
 843 Remove all directories that were added to search paths by C<local::lib> from the
 844 search paths.
 845
 846 =head2 --shelltype
 847
 848 Specify the shell type to use for output.  By default, the shell will be
 849 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 850 C<cmd>, or C<powershell>.
 851
 852 =head2 --no-create
 853
 854 Prevents C<local::lib> from creating directories when activating dirs.  This is
 855 likely to cause issues on Win32 systems.
 856
 857 =head1 CLASS METHODS
 858
 859 =head2 ensure_dir_structure_for
 860
 861 =over 4
 862
 863 =item Arguments: $path
 864
 865 =item Return value: None
 866
 867 =back
 868
 869 Attempts to create the given path, and all required parent directories. Throws
 870 an exception on failure.
 871
 872 =head2 print_environment_vars_for
 873
 874 =over 4
 875
 876 =item Arguments: $path
 877
 878 =item Return value: None
 879
 880 =back
 881
 882 Prints to standard output the variables listed above, properly set to use the
 883 given path as the base directory.
 884
 885 =head2 build_environment_vars_for
 886
 887 =over 4
 888
 889 =item Arguments: $path
 890
 891 =item Return value: %environment_vars
 892
 893 =back
 894
 895 Returns a hash with the variables listed above, properly set to use the
 896 given path as the base directory.
 897
 898 =head2 setup_env_hash_for
 899
 900 =over 4
 901
 902 =item Arguments: $path
 903
 904 =item Return value: None
 905
 906 =back
 907
 908 Constructs the C<%ENV> keys for the given path, by calling
 909 L</build_environment_vars_for>.
 910
 911 =head2 active_paths
 912
 913 =over 4
 914
 915 =item Arguments: None
 916
 917 =item Return value: @paths
 918
 919 =back
 920
 921 Returns a list of active C<local::lib> paths, according to the
 922 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 923 what is really in C<@INC>.
 924
 925 =head2 install_base_perl_path
 926
 927 =over 4
 928
 929 =item Arguments: $path
 930
 931 =item Return value: $install_base_perl_path
 932
 933 =back
 934
 935 Returns a path describing where to install the Perl modules for this local
 936 library installation. Appends the directories C<lib> and C<perl5> to the given
 937 path.
 938
 939 =head2 lib_paths_for
 940
 941 =over 4
 942
 943 =item Arguments: $path
 944
 945 =item Return value: @lib_paths
 946
 947 =back
 948
 949 Returns the list of paths perl will search for libraries, given a base path.
 950 This includes the base path itself, the architecture specific subdirectory, and
 951 perl version specific subdirectories.  These paths may not all exist.
 952
 953 =head2 install_base_bin_path
 954
 955 =over 4
 956
 957 =item Arguments: $path
 958
 959 =item Return value: $install_base_bin_path
 960
 961 =back
 962
 963 Returns a path describing where to install the executable programs for this
 964 local library installation. Appends the directory C<bin> to the given path.
 965
 966 =head2 installer_options_for
 967
 968 =over 4
 969
 970 =item Arguments: $path
 971
 972 =item Return value: %installer_env_vars
 973
 974 =back
 975
 976 Returns a hash of environment variables that should be set to cause
 977 installation into the given path.
 978
 979 =head2 resolve_empty_path
 980
 981 =over 4
 982
 983 =item Arguments: $path
 984
 985 =item Return value: $base_path
 986
 987 =back
 988
 989 Builds and returns the base path into which to set up the local module
 990 installation. Defaults to C<~/perl5>.
 991
 992 =head2 resolve_home_path
 993
 994 =over 4
 995
 996 =item Arguments: $path
 997
 998 =item Return value: $home_path
 999
1000 =back
1001
1002 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
1003 for this purpose. If no definite answer is available, throws an exception.
1004
1005 =head2 resolve_relative_path
1006
1007 =over 4
1008
1009 =item Arguments: $path
1010
1011 =item Return value: $absolute_path
1012
1013 =back
1014
1015 Translates the given path into an absolute path.
1016
1017 =head2 resolve_path
1018
1019 =over 4
1020
1021 =item Arguments: $path
1022
1023 =item Return value: $absolute_path
1024
1025 =back
1026
1027 Calls the following in a pipeline, passing the result from the previous to the
1028 next, in an attempt to find where to configure the environment for a local
1029 library installation: L</resolve_empty_path>, L</resolve_home_path>,
1030 L</resolve_relative_path>. Passes the given path argument to
1031 L</resolve_empty_path> which then returns a result that is passed to
1032 L</resolve_home_path>, which then has its result passed to
1033 L</resolve_relative_path>. The result of this final call is returned from
1034 L</resolve_path>.
1035
1036 =head1 OBJECT INTERFACE
1037
1038 =head2 new
1039
1040 =over 4
1041
1042 =item Arguments: %attributes
1043
1044 =item Return value: $local_lib
1045
1046 =back
1047
1048 Constructs a new C<local::lib> object, representing the current state of
1049 C<@INC> and the relevant environment variables.
1050
1051 =head1 ATTRIBUTES
1052
1053 =head2 roots
1054
1055 An arrayref representing active C<local::lib> directories.
1056
1057 =head2 inc
1058
1059 An arrayref representing C<@INC>.
1060
1061 =head2 libs
1062
1063 An arrayref representing the PERL5LIB environment variable.
1064
1065 =head2 bins
1066
1067 An arrayref representing the PATH environment variable.
1068
1069 =head2 extra
1070
1071 A hashref of extra environment variables (e.g. C<PERL_MM_OPT> and
1072 C<PERL_MB_OPT>)
1073
1074 =head2 no_create
1075
1076 If set, C<local::lib> will not try to create directories when activating them.
1077
1078 =head1 OBJECT METHODS
1079
1080 =head2 clone
1081
1082 =over 4
1083
1084 =item Arguments: %attributes
1085
1086 =item Return value: $local_lib
1087
1088 =back
1089
1090 Constructs a new C<local::lib> object based on the existing one, overriding the
1091 specified attributes.
1092
1093 =head2 activate
1094
1095 =over 4
1096
1097 =item Arguments: $path
1098
1099 =item Return value: $new_local_lib
1100
1101 =back
1102
1103 Constructs a new instance with the specified path active.
1104
1105 =head2 deactivate
1106
1107 =over 4
1108
1109 =item Arguments: $path
1110
1111 =item Return value: $new_local_lib
1112
1113 =back
1114
1115 Constructs a new instance with the specified path deactivated.
1116
1117 =head2 deactivate_all
1118
1119 =over 4
1120
1121 =item Arguments: None
1122
1123 =item Return value: $new_local_lib
1124
1125 =back
1126
1127 Constructs a new instance with all C<local::lib> directories deactivated.
1128
1129 =head2 environment_vars_string
1130
1131 =over 4
1132
1133 =item Arguments: [ $shelltype ]
1134
1135 =item Return value: $shell_env_string
1136
1137 =back
1138
1139 Returns a string to set up the C<local::lib>, meant to be run by a shell.
1140
1141 =head2 build_environment_vars
1142
1143 =over 4
1144
1145 =item Arguments: None
1146
1147 =item Return value: %environment_vars
1148
1149 =back
1150
1151 Returns a hash with the variables listed above, properly set to use the
1152 given path as the base directory.
1153
1154 =head2 setup_env_hash
1155
1156 =over 4
1157
1158 =item Arguments: None
1159
1160 =item Return value: None
1161
1162 =back
1163
1164 Constructs the C<%ENV> keys for the given path, by calling
1165 L</build_environment_vars>.
1166
1167 =head2 setup_local_lib
1168
1169 Constructs the C<%ENV> hash using L</setup_env_hash>, and set up C<@INC>.
1170
1171 =head1 A WARNING ABOUT UNINST=1
1172
1173 Be careful about using local::lib in combination with "make install UNINST=1".
1174 The idea of this feature is that will uninstall an old version of a module
1175 before installing a new one. However it lacks a safety check that the old
1176 version and the new version will go in the same directory. Used in combination
1177 with local::lib, you can potentially delete a globally accessible version of a
1178 module while installing the new version in a local place. Only combine "make
1179 install UNINST=1" and local::lib if you understand these possible consequences.
1180
1181 =head1 LIMITATIONS
1182
1183 =over 4
1184
1185 =item * Directory names with spaces in them are not well supported by the perl
1186 toolchain and the programs it uses.  Pure-perl distributions should support
1187 spaces, but problems are more likely with dists that require compilation. A
1188 workaround you can do is moving your local::lib to a directory with spaces
1189 B<after> you installed all modules inside your local::lib bootstrap. But be
1190 aware that you can't update or install CPAN modules after the move.
1191
1192 =item * Rather basic shell detection. Right now anything with csh in its name is
1193 assumed to be a C shell or something compatible, and everything else is assumed
1194 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
1195 not set, a Bourne-compatible shell is assumed.
1196
1197 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
1198
1199 =item * Should probably auto-fixup CPAN config if not already done.
1200
1201 =item * local::lib loads L<File::Spec>.  When used to set shell variables,
1202 this isn't a problem.  When used inside a perl script, any L<File::Spec>
1203 version inside the local::lib will be ignored.  A workaround for this is using
1204 C<use lib "$ENV{HOME}/perl5/lib/perl5";> inside the script instead of using
1205 C<local::lib> directly.
1206
1207 =item * Conflicts with L<ExtUtils::MakeMaker>'s C<PREFIX> option.
1208 C<local::lib> uses the C<INSTALL_BASE> option, as it has more predictable and
1209 sane behavior.  If something attempts to use the C<PREFIX> option when running
1210 a F<Makefile.PL>, L<ExtUtils::MakeMaker> will refuse to run, as the two
1211 options conflict.  This can be worked around by temporarily unsetting the
1212 C<PERL_MM_OPT> environment variable.
1213
1214 =item * Conflicts with L<Module::Build>'s C<--prefix> option.  Similar to the
1215 previous limitation, but any C<--prefix> option specified will be ignored.
1216 This can be worked around by temporarily unsetting the C<PERL_MB_OPT>
1217 environment variable.
1218
1219 =back
1220
1221 Patches very much welcome for any of the above.
1222
1223 =over 4
1224
1225 =item * On Win32 systems, does not have a way to write the created environment
1226 variables to the registry, so that they can persist through a reboot.
1227
1228 =back
1229
1230 =head1 TROUBLESHOOTING
1231
1232 If you've configured local::lib to install CPAN modules somewhere in to your
1233 home directory, and at some point later you try to install a module with C<cpan
1234 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1235 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1236 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1237 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1238 you've somehow lost your updated ExtUtils::MakeMaker module.
1239
1240 To remedy this situation, rerun the bootstrapping procedure documented above.
1241
1242 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1243
1244 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1245
1246 =head1 ENVIRONMENT
1247
1248 =over 4
1249
1250 =item SHELL
1251
1252 =item COMSPEC
1253
1254 local::lib looks at the user's C<SHELL> environment variable when printing out
1255 commands to add to the shell configuration file.
1256
1257 On Win32 systems, C<COMSPEC> is also examined.
1258
1259 =back
1260
1261 =head1 SEE ALSO
1262
1263 =over 4
1264
1265 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1266
1267 =back
1268
1269 =head1 SUPPORT
1270
1271 IRC:
1272
1273     Join #local-lib on irc.perl.org.
1274
1275 =head1 AUTHOR
1276
1277 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1278
1279 auto_install fixes kindly sponsored by http://www.takkle.com/
1280
1281 =head1 CONTRIBUTORS
1282
1283 Patches to correctly output commands for csh style shells, as well as some
1284 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1285
1286 Doc patches for a custom local::lib directory, more cleanups in the english
1287 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1288 Torsten Raudssus <torsten@raudssus.de>.
1289
1290 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1291 things will install properly, submitted a fix for the bug causing problems with
1292 writing Makefiles during bootstrapping, contributed an example program, and
1293 submitted yet another fix to ensure that local::lib can install and bootstrap
1294 properly. Many, many thanks!
1295
1296 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1297 section. Many thanks!
1298
1299 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1300
1301 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1302 by a patch from Marco Emilio Poleggi.
1303
1304 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1305 '--self-contained' option.
1306
1307 Documentation patches to make win32 usage clearer by
1308 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1309
1310 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1311 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1312
1313 Improvements to stacking multiple local::lib dirs and removing them from the
1314 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1315
1316 Patch for Carp version mismatch contributed by Hakim Cassimally
1317 <osfameron@cpan.org>.
1318
1319 Rewrite of internals and numerous bug fixes and added features contributed by
1320 Graham Knop <haarg@haarg.org>.
1321
1322 =head1 COPYRIGHT
1323
1324 Copyright (c) 2007 - 2013 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1325 listed above.
1326
1327 =head1 LICENSE
1328
1329 This is free software; you can redistribute it and/or modify it under
1330 the same terms as the Perl 5 programming language system itself.
1331
1332 =cut