lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '1.008026'; # 1.8.26
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19
  20   while (@args) {
  21     my $arg = shift @args;
  22     # check for lethal dash first to stop processing before causing problems
  23     # the fancy dash is U+2212 or \xE2\x88\x92
  24     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  25       die <<'DEATH';
  26 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  27 These are *not* the traditional -- dashes that software recognizes. You
  28 probably got these by copy-pasting from the perldoc for this module as
  29 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  30 terminal, but can happen elsewhere too. Please try again after replacing the
  31 dashes with normal minus signs.
  32 DEATH
  33     }
  34     elsif ($arg eq '--self-contained') {
  35       die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  36     }
  37     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  38       my $path = defined $1 ? $1 : shift @args;
  39       push @steps, ['deactivate', $path];
  40     }
  41     elsif ( $arg eq '--deactivate-all' ) {
  42       push @steps, ['deactivate_all'];
  43     }
  44     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  45       my $shell = defined $1 ? $1 : shift @args;
  46       $opts{shelltype} = $shell;
  47     }
  48     elsif ( $arg eq '--no-create' ) {
  49       $opts{no_create} = 1;
  50     }
  51     elsif ( $arg =~ /^--/ ) {
  52       die "Unknown import argument: $arg";
  53     }
  54     else {
  55       push @steps, ['activate', $arg];
  56     }
  57   }
  58   if (!@steps) {
  59     push @steps, ['activate', undef];
  60   }
  61
  62   my $self = $class->new(%opts);
  63
  64   for (@steps) {
  65     my ($method, @args) = @$_;
  66     $self = $self->$method(@args);
  67   }
  68
  69   if ($0 eq '-') {
  70     $self->print_environment_vars_for;
  71     exit 0;
  72   }
  73   else {
  74     $self->setup_local_lib_for;
  75   }
  76 }
  77
  78 sub new {
  79   my $class = shift;
  80   bless {@_}, $class;
  81 }
  82
  83 sub clone {
  84   my $self = shift;
  85   bless {%$self, @_}, ref $self;
  86 }
  87
  88 sub inc { $_[0]->{inc}     ||= \@INC }
  89 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
  90 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
  91 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
  92 sub extra { $_[0]->{extra} ||= {} }
  93 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
  94 sub no_create { $_[0]->{no_create} }
  95
  96 my $_archname = $Config{archname};
  97 my $_version  = $Config{version};
  98 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
  99 my $_path_sep = $Config{path_sep};
 100
 101 sub _as_list {
 102   my $list = shift;
 103   grep length, map {
 104     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 105       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 106                         : ()
 107     )
 108   } ref $list ? @$list : $list;
 109 }
 110 sub _remove_from {
 111   my ($list, @remove) = @_;
 112   return @$list
 113     if !@remove;
 114   my %remove = map { $_ => 1 } @remove;
 115   grep !$remove{$_}, _as_list($list);
 116 }
 117
 118 my @_lib_subdirs = (
 119   [$_version, $_archname],
 120   [$_version],
 121   [$_archname],
 122   (@_inc_version_list ? \@_inc_version_list : ()),
 123   [],
 124 );
 125
 126 sub install_base_bin_path {
 127   my ($class, $path) = @_;
 128   return File::Spec->catdir($path, 'bin');
 129 }
 130 sub install_base_perl_path {
 131   my ($class, $path) = @_;
 132   return File::Spec->catdir($path, 'lib', 'perl5');
 133 }
 134 sub install_base_arch_path {
 135   my ($class, $path) = @_;
 136   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 137 }
 138
 139 sub lib_paths_for {
 140   my ($class, $path) = @_;
 141   my $base = $class->install_base_perl_path($path);
 142   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 143 }
 144
 145 sub _mm_escape_path {
 146   my $path = shift;
 147   $path =~ s/\\/\\\\\\\\/g;
 148   if ($path =~ s/ /\\ /g) {
 149     $path = qq{"\\"$path\\""};
 150   }
 151   return $path;
 152 }
 153
 154 sub _mb_escape_path {
 155   my $path = shift;
 156   $path =~ s/\\/\\\\/g;
 157   return qq{"$path"};
 158 }
 159
 160 sub installer_options_for {
 161   my ($class, $path) = @_;
 162   return {
 163     PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 164     PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef,
 165   };
 166 }
 167
 168 sub active_paths {
 169   my ($self) = @_;
 170   $self = ref $self ? $self : $self->new;
 171
 172   return grep {
 173     # screen out entries that aren't actually reflected in @INC
 174     my $active_ll = $self->install_base_perl_path($_);
 175     grep { $_ eq $active_ll } @{$self->inc};
 176   } _as_list($self->roots);
 177 }
 178
 179
 180 sub deactivate {
 181   my ($self, $path) = @_;
 182   $self = $self->new unless ref $self;
 183   $path = $self->resolve_path($path);
 184
 185   my @active_lls = $self->active_paths;
 186
 187   if (!grep { $_ eq $path } @active_lls) {
 188     warn "Tried to deactivate inactive local::lib '$path'\n";
 189     return $self;
 190   }
 191
 192   my %args = (
 193     bins  => [ _remove_from($self->bins,  $self->install_base_bin_path($path)) ],
 194     libs  => [ _remove_from($self->libs,  $self->install_base_perl_path($path)) ],
 195     inc   => [ _remove_from($self->inc,   $self->lib_paths_for($path)) ],
 196     roots => [ _remove_from($self->roots, $path) ],
 197   );
 198
 199   $args{extra} = $self->installer_options_for($args{roots}[0]);
 200
 201   $self->clone(%args);
 202 }
 203
 204 sub deactivate_all {
 205   my ($self) = @_;
 206   $self = $self->new unless ref $self;
 207
 208   my @active_lls = $self->active_paths;
 209
 210   my %args;
 211   if (@active_lls) {
 212     %args = (
 213       bins => [ _remove_from($self->bins,
 214         map $self->install_base_bin_path($_), @active_lls) ],
 215       libs => [ _remove_from($self->libs,
 216         map $self->install_base_perl_path($_), @active_lls) ],
 217       inc => [ _remove_from($self->inc,
 218         map $self->lib_paths_for($_), @active_lls) ],
 219       roots => [ _remove_from($self->roots, @active_lls) ],
 220     );
 221   }
 222
 223   $args{extra} = $self->installer_options_for(undef);
 224
 225   $self->clone(%args);
 226 }
 227
 228 sub activate {
 229   my ($self, $path) = @_;
 230   $self = $self->new unless ref $self;
 231   $path = $self->resolve_path($path);
 232   $self->ensure_dir_structure_for($path)
 233     unless $self->no_create;
 234
 235   $path = ( Win32::GetShortPathName($path) || $path )
 236     if $^O eq 'MSWin32';
 237
 238   my @active_lls = $self->active_paths;
 239
 240   if (grep { $_ eq $path } @active_lls[1 .. $#active_lls]) {
 241     $self = $self->deactivate($path);
 242   }
 243
 244   my %args;
 245   if (!@active_lls || $active_lls[0] ne $path) {
 246     %args = (
 247       bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 248       libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 249       inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 250       roots => [ $path, @{$self->roots} ],
 251     );
 252   }
 253
 254   $args{extra} = $self->installer_options_for($path);
 255
 256   $self->clone(%args);
 257 }
 258
 259 sub _legacy {
 260   my ($self, $path) = @_;
 261   $self = $self->new unless ref $self;
 262   if (defined $path) {
 263     $self = $self->activate($path);
 264   }
 265   $self;
 266 }
 267
 268 sub build_environment_vars_for {
 269   my ($self) = _legacy(@_);
 270   (
 271     PATH                => join($_path_sep, _as_list($self->bins)),
 272     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 273     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 274     %{$self->extra},
 275   );
 276 }
 277
 278 sub setup_local_lib_for {
 279   my ($self) = _legacy(@_);
 280   $self->setup_env_hash_for;
 281   @INC = @{$self->inc};
 282 }
 283
 284 sub setup_env_hash_for {
 285   my $self = shift;
 286   my %env = $self->build_environment_vars_for(@_);
 287   for my $key (keys %env) {
 288     if (defined $env{$key}) {
 289       $ENV{$key} = $env{$key};
 290     }
 291     else {
 292       delete $ENV{$key};
 293     }
 294   }
 295 }
 296
 297 sub print_environment_vars_for {
 298   my $self = shift;
 299   print $self->environment_vars_string_for(@_);
 300 }
 301
 302 sub environment_vars_string_for {
 303   my $self = _legacy(@_);
 304
 305   my $build_method = 'build_' . $self->shelltype . '_env_declaration';
 306
 307   my @envs = (
 308     PATH                => $self->bins,
 309     PERL5LIB            => $self->libs,
 310     PERL_LOCAL_LIB_ROOT => $self->roots,
 311     %{$self->extra},
 312   );
 313   my $out = '';
 314   while (@envs) {
 315     my ($name, $value) = (shift(@envs), shift(@envs));
 316     if (
 317         ref $value
 318         && @$value == 1
 319         && ref $value->[0]
 320         && ref $value->[0] eq 'SCALAR'
 321         && ${$value->[0]} eq $name) {
 322       next;
 323     }
 324     if (
 325         !ref $value
 326         and defined $value
 327           ? (defined $ENV{$name} && $value eq $ENV{$name})
 328           : !defined $ENV{$name}
 329     ) {
 330       next;
 331     }
 332     $out .= $self->$build_method($name, $value);
 333   }
 334   return $out;
 335 }
 336
 337 sub build_bourne_env_declaration {
 338   my ($class, $name, $args) = @_;
 339   my $value = $class->_interpolate($args);
 340   defined $value
 341     ? qq{export ${name}="${value}";\n}
 342     : qq{unset ${name};\n};
 343 }
 344 sub build_csh_env_declaration {
 345   my ($class, $name, $args) = @_;
 346   my ($value, @vars) = $class->_interpolate($args, undef, undef, '"', qq{"\\"});
 347   (join '', map qq{if ! \$?$_ setenv $_ "";\n}, @vars)
 348     . defined $value
 349       ? qq{setenv $name "$value";\n}
 350       : qq{unsetenv $name;\n};
 351 }
 352 sub build_cmd_env_declaration {
 353   my ($class, $name, $args) = @_;
 354   my $value = $class->_interpolate($args, '%', '%', qr([()!^"<>&|]), '^');
 355   defined $value
 356     ? qq{set $name=$value\n}
 357     : qq{set $name=\n};
 358 }
 359 sub build_powershell_env_declaration {
 360   my ($class, $name, $args) = @_;
 361   my $value = $class->_interpolate($args, '$env:', '', '"', '`');
 362   defined $value
 363     ? qq{\$env:$name = "$value"\n}
 364     : "Remove-Item Env:\\$name\n";
 365 }
 366
 367
 368 sub _interpolate {
 369   my ($class, $args, $start, $end, $escape, $escape_char) = @_;
 370   return
 371     unless defined $args;
 372   return $args
 373     unless ref $args;
 374   return
 375     unless @$args;
 376   $start = '$' unless defined $start;
 377   $end = '' unless defined $end;
 378   $escape = '"' unless defined $escape;
 379   $escape_char = "\\" unless defined $escape_char;
 380   my @vars;
 381   my $string = join($Config{path_sep}, map {
 382     if (ref $_ && ref $_ eq 'SCALAR') {
 383       push @vars, $$_;
 384       $start.$$_.$end;
 385     }
 386     else {
 387       my $str = $_;
 388       $str =~ s/($escape)/$escape_char$1/g;
 389       $str;
 390     }
 391   } @$args);
 392   return wantarray ? ($string, @vars) : $string;
 393 }
 394
 395 sub pipeline;
 396
 397 sub pipeline {
 398   my @methods = @_;
 399   my $last = pop(@methods);
 400   if (@methods) {
 401     \sub {
 402       my ($obj, @args) = @_;
 403       $obj->${pipeline @methods}(
 404         $obj->$last(@args)
 405       );
 406     };
 407   } else {
 408     \sub {
 409       shift->$last(@_);
 410     };
 411   }
 412 }
 413
 414 =begin testing
 415
 416 #:: test pipeline
 417
 418 package local::lib;
 419
 420 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 421 my $foo = bless({}, 'Foo');
 422 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 423
 424 =end testing
 425
 426 =cut
 427
 428 sub resolve_path {
 429   my ($class, $path) = @_;
 430
 431   $path = $class->${pipeline qw(
 432     resolve_relative_path
 433     resolve_home_path
 434     resolve_empty_path
 435   )}($path);
 436
 437   $path;
 438 }
 439
 440 sub resolve_empty_path {
 441   my ($class, $path) = @_;
 442   if (defined $path) {
 443     $path;
 444   } else {
 445     '~/perl5';
 446   }
 447 }
 448
 449 =begin testing
 450
 451 #:: test classmethod setup
 452
 453 my $c = 'local::lib';
 454
 455 =end testing
 456
 457 =begin testing
 458
 459 #:: test classmethod
 460
 461 is($c->resolve_empty_path, '~/perl5');
 462 is($c->resolve_empty_path('foo'), 'foo');
 463
 464 =end testing
 465
 466 =cut
 467
 468 sub resolve_home_path {
 469   my ($class, $path) = @_;
 470   return $path unless ($path =~ /^~/);
 471   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 472   my $homedir = do {
 473     if (!defined $user && defined $ENV{HOME}) {
 474       $ENV{HOME}
 475     }
 476     else {
 477       require File::Glob;
 478       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 479     }
 480   };
 481   unless (defined $homedir) {
 482     require Carp;
 483     Carp::croak(
 484       "Couldn't resolve homedir for "
 485       .(defined $user ? $user : 'current user')
 486     );
 487   }
 488   $path =~ s/^~[^\/]*/$homedir/;
 489   $path;
 490 }
 491
 492 sub resolve_relative_path {
 493   my ($class, $path) = @_;
 494   $path = File::Spec->rel2abs($path);
 495 }
 496
 497 =begin testing
 498
 499 #:: test classmethod
 500
 501 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 502 is($c->resolve_relative_path('bar'),'FOObar');
 503
 504 =end testing
 505
 506 =cut
 507
 508 sub ensure_dir_structure_for {
 509   my ($class, $path) = @_;
 510   unless (-d $path) {
 511     warn "Attempting to create directory ${path}\n";
 512   }
 513   require File::Basename;
 514   my @dirs;
 515   while(!-d $path) {
 516     push @dirs, $path;
 517     $path = File::Basename::dirname($path);
 518   }
 519   mkdir $_ for reverse @dirs;
 520   return;
 521 }
 522
 523 =begin testing
 524
 525 #:: test classmethod
 526
 527 File::Path::rmtree('t/var/splat');
 528
 529 $c->ensure_dir_structure_for('t/var/splat');
 530
 531 ok(-d 't/var/splat');
 532
 533 =end testing
 534
 535 =cut
 536
 537 sub guess_shelltype {
 538   my $shellbin
 539     = defined $ENV{SHELL}
 540       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 541     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 542       ? 'bash'
 543     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 544       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 545     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 546       ? 'powershell.exe'
 547     : 'sh';
 548
 549   for ($shellbin) {
 550     return
 551         /csh/             ? 'csh'
 552       : /command\.com/    ? 'cmd'
 553       : /cmd\.exe/        ? 'cmd'
 554       : /4nt\.exe/        ? 'cmd'
 555       : /powershell\.exe/ ? 'powershell'
 556                           : 'bourne';
 557   }
 558 }
 559
 560 1;
 561 __END__
 562
 563 =encoding utf8
 564
 565 =head1 NAME
 566
 567 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 568
 569 =head1 SYNOPSIS
 570
 571 In code -
 572
 573   use local::lib; # sets up a local lib at ~/perl5
 574
 575   use local::lib '~/foo'; # same, but ~/foo
 576
 577   # Or...
 578   use FindBin;
 579   use local::lib "$FindBin::Bin/../support";  # app-local support library
 580
 581 From the shell -
 582
 583   # Install LWP and its missing dependencies to the '~/perl5' directory
 584   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 585
 586   # Just print out useful shell commands
 587   $ perl -Mlocal::lib
 588   export PERL_MB_OPT='--install_base /home/username/perl5'
 589   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 590   export PERL5LIB="/home/username/perl5/lib/perl5"
 591   export PATH="/home/username/perl5/bin:$PATH"
 592
 593 =head2 The bootstrapping technique
 594
 595 A typical way to install local::lib is using what is known as the
 596 "bootstrapping" technique.  You would do this if your system administrator
 597 hasn't already installed local::lib.  In this case, you'll need to install
 598 local::lib in your home directory.
 599
 600 Even if you do have administrative privileges, you will still want to set up your
 601 environment variables, as discussed in step 4. Without this, you would still
 602 install the modules into the system CPAN installation and also your Perl scripts
 603 will not use the lib/ path you bootstrapped with local::lib.
 604
 605 By default local::lib installs itself and the CPAN modules into ~/perl5.
 606
 607 Windows users must also see L</Differences when using this module under Win32>.
 608
 609 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 610 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 611 or administrator.  Unpack the file in your home directory or in any other
 612 convenient location.
 613
 614 2. Run this:
 615
 616   perl Makefile.PL --bootstrap
 617
 618 If the system asks you whether it should automatically configure as much
 619 as possible, you would typically answer yes.
 620
 621 In order to install local::lib into a directory other than the default, you need
 622 to specify the name of the directory when you call bootstrap, as follows:
 623
 624   perl Makefile.PL --bootstrap=~/foo
 625
 626 3. Run this: (local::lib assumes you have make installed on your system)
 627
 628   make test && make install
 629
 630 4. Now we need to setup the appropriate environment variables, so that Perl
 631 starts using our newly generated lib/ directory. If you are using bash or
 632 any other Bourne shells, you can add this to your shell startup script this
 633 way:
 634
 635   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 636
 637 If you are using C shell, you can do this as follows:
 638
 639   /bin/csh
 640   echo $SHELL
 641   /bin/csh
 642   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 643
 644 If you passed to bootstrap a directory other than default, you also need to
 645 give that as import parameter to the call of the local::lib module like this
 646 way:
 647
 648   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 649
 650 After writing your shell configuration file, be sure to re-read it to get the
 651 changed settings into your current shell's environment. Bourne shells use
 652 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 653
 654 If you're on a slower machine, or are operating under draconian disk space
 655 limitations, you can disable the automatic generation of manpages from POD when
 656 installing modules by using the C<--no-manpages> argument when bootstrapping:
 657
 658   perl Makefile.PL --bootstrap --no-manpages
 659
 660 To avoid doing several bootstrap for several Perl module environments on the
 661 same account, for example if you use it for several different deployed
 662 applications independently, you can use one bootstrapped local::lib
 663 installation to install modules in different directories directly this way:
 664
 665   cd ~/mydir1
 666   perl -Mlocal::lib=./
 667   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 668   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 669   perl -MCPAN -e install ...    ### whatever modules you want
 670   cd ../mydir2
 671   ... REPEAT ...
 672
 673 If you are working with several C<local::lib> environments, you may want to
 674 remove some of them from the current environment without disturbing the others.
 675 You can deactivate one environment like this (using bourne sh):
 676
 677   eval $(perl -Mlocal::lib=--deactivate,~/path)
 678
 679 which will generate and run the commands needed to remove C<~/path> from your
 680 various search paths. Whichever environment was B<activated most recently> will
 681 remain the target for module installations. That is, if you activate
 682 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 683 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 684 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 685 installed in C<~/pathB> because pathB was activated later.
 686
 687 You can also ask C<local::lib> to clean itself completely out of the current
 688 shell's environment with the C<--deactivate-all> option.
 689 For multiple environments for multiple apps you may need to include a modified
 690 version of the C<< use FindBin >> instructions in the "In code" sample above.
 691 If you did something like the above, you have a set of Perl modules at C<<
 692 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 693 you need to tell it where to find the modules you installed for it at C<<
 694 ~/mydir1/lib >>.
 695
 696 In C<< ~/mydir1/scripts/myscript.pl >>:
 697
 698   use strict;
 699   use warnings;
 700   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 701   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 702
 703 Put this before any BEGIN { ... } blocks that require the modules you installed.
 704
 705 =head2 Differences when using this module under Win32
 706
 707 To set up the proper environment variables for your current session of
 708 C<CMD.exe>, you can use this:
 709
 710   C:\>perl -Mlocal::lib
 711   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 712   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 713   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 714   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 715
 716   ### To set the environment for this shell alone
 717   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 718   ### instead of $(perl -Mlocal::lib=./)
 719
 720 If you want the environment entries to persist, you'll need to add then to the
 721 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 722
 723 The "~" is translated to the user's profile directory (the directory named for
 724 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 725 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 726 directory is translated to a short name (which means the directory must exist)
 727 and the subdirectories are created.
 728
 729 =head1 RATIONALE
 730
 731 The version of a Perl package on your machine is not always the version you
 732 need.  Obviously, the best thing to do would be to update to the version you
 733 need.  However, you might be in a situation where you're prevented from doing
 734 this.  Perhaps you don't have system administrator privileges; or perhaps you
 735 are using a package management system such as Debian, and nobody has yet gotten
 736 around to packaging up the version you need.
 737
 738 local::lib solves this problem by allowing you to create your own directory of
 739 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 740 be within your own home directory).  The existing system Perl installation is
 741 not affected; you simply invoke Perl with special options so that Perl uses the
 742 packages in your own local package directory rather than the system packages.
 743 local::lib arranges things so that your locally installed version of the Perl
 744 packages takes precedence over the system installation.
 745
 746 If you are using a package management system (such as Debian), you don't need to
 747 worry about Debian and CPAN stepping on each other's toes.  Your local version
 748 of the packages will be written to an entirely separate directory from those
 749 installed by Debian.
 750
 751 =head1 DESCRIPTION
 752
 753 This module provides a quick, convenient way of bootstrapping a user-local Perl
 754 module library located within the user's home directory. It also constructs and
 755 prints out for the user the list of environment variables using the syntax
 756 appropriate for the user's current shell (as specified by the C<SHELL>
 757 environment variable), suitable for directly adding to one's shell
 758 configuration file.
 759
 760 More generally, local::lib allows for the bootstrapping and usage of a
 761 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 762 easier to ship an application with an app-specific copy of a Perl module, or
 763 collection of modules. Useful in cases like when an upstream maintainer hasn't
 764 applied a patch to a module of theirs that you need for your application.
 765
 766 On import, local::lib sets the following environment variables to appropriate
 767 values:
 768
 769 =over 4
 770
 771 =item PERL_MB_OPT
 772
 773 =item PERL_MM_OPT
 774
 775 =item PERL5LIB
 776
 777 =item PATH
 778
 779 =back
 780
 781 When possible, these will be appended to instead of overwritten entirely.
 782
 783 These values are then available for reference by any code after import.
 784
 785 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 786
 787 See L<lib::core::only> for one way to do this - but note that
 788 there are a number of caveats, and the best approach is always to perform a
 789 build against a clean perl (i.e. site and vendor as close to empty as possible).
 790
 791 =head1 OPTIONS
 792
 793 Options are values that can be passed to the C<local::lib> import besides the
 794 directory to use. They are specified as C<use local::lib '--option'[, path];>
 795 or C<perl -Mlocal::lib=--option[,path]>.
 796
 797 =head2 --deactivate
 798
 799 Remove the chosen path (or the default path) from the module search paths if it
 800 was added by C<local::lib>, instead of adding it.
 801
 802 =head2 --deactivate-all
 803
 804 Remove all directories that were added to search paths by C<local::lib> from the
 805 search paths.
 806
 807 =head2 --shelltype
 808
 809 Specify the shell type to use for output.  By default, the shell will be
 810 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 811 C<cmd>, or C<powershell>.
 812
 813 =head2 --no-create
 814
 815 Prevents C<local::lib> from creating directories when activating dirs.  This is
 816 likely to cause issues on Win32 systems.
 817
 818 =head1 METHODS
 819
 820 =head2 ensure_dir_structure_for
 821
 822 =over 4
 823
 824 =item Arguments: $path
 825
 826 =item Return value: None
 827
 828 =back
 829
 830 Attempts to create the given path, and all required parent directories. Throws
 831 an exception on failure.
 832
 833 =head2 print_environment_vars_for
 834
 835 =over 4
 836
 837 =item Arguments: $path
 838
 839 =item Return value: None
 840
 841 =back
 842
 843 Prints to standard output the variables listed above, properly set to use the
 844 given path as the base directory.
 845
 846 =head2 build_environment_vars_for
 847
 848 =over 4
 849
 850 =item Arguments: $path
 851
 852 =item Return value: %environment_vars
 853
 854 =back
 855
 856 Returns a hash with the variables listed above, properly set to use the
 857 given path as the base directory.
 858
 859 =head2 setup_env_hash_for
 860
 861 =over 4
 862
 863 =item Arguments: $path
 864
 865 =item Return value: None
 866
 867 =back
 868
 869 Constructs the C<%ENV> keys for the given path, by calling
 870 L</build_environment_vars_for>.
 871
 872 =head2 active_paths
 873
 874 =over 4
 875
 876 =item Arguments: None
 877
 878 =item Return value: @paths
 879
 880 =back
 881
 882 Returns a list of active C<local::lib> paths, according to the
 883 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 884 what is really in C<@INC>.
 885
 886 =head2 install_base_perl_path
 887
 888 =over 4
 889
 890 =item Arguments: $path
 891
 892 =item Return value: $install_base_perl_path
 893
 894 =back
 895
 896 Returns a path describing where to install the Perl modules for this local
 897 library installation. Appends the directories C<lib> and C<perl5> to the given
 898 path.
 899
 900 =head2 install_base_bin_path
 901
 902 =over 4
 903
 904 =item Arguments: $path
 905
 906 =item Return value: $install_base_bin_path
 907
 908 =back
 909
 910 Returns a path describing where to install the executable programs for this
 911 local library installation. Appends the directory C<bin> to the given path.
 912
 913 =head2 resolve_empty_path
 914
 915 =over 4
 916
 917 =item Arguments: $path
 918
 919 =item Return value: $base_path
 920
 921 =back
 922
 923 Builds and returns the base path into which to set up the local module
 924 installation. Defaults to C<~/perl5>.
 925
 926 =head2 resolve_home_path
 927
 928 =over 4
 929
 930 =item Arguments: $path
 931
 932 =item Return value: $home_path
 933
 934 =back
 935
 936 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 937 for this purpose. If no definite answer is available, throws an exception.
 938
 939 =head2 resolve_relative_path
 940
 941 =over 4
 942
 943 =item Arguments: $path
 944
 945 =item Return value: $absolute_path
 946
 947 =back
 948
 949 Translates the given path into an absolute path.
 950
 951 =head2 resolve_path
 952
 953 =over 4
 954
 955 =item Arguments: $path
 956
 957 =item Return value: $absolute_path
 958
 959 =back
 960
 961 Calls the following in a pipeline, passing the result from the previous to the
 962 next, in an attempt to find where to configure the environment for a local
 963 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 964 L</resolve_relative_path>. Passes the given path argument to
 965 L</resolve_empty_path> which then returns a result that is passed to
 966 L</resolve_home_path>, which then has its result passed to
 967 L</resolve_relative_path>. The result of this final call is returned from
 968 L</resolve_path>.
 969
 970 =head1 A WARNING ABOUT UNINST=1
 971
 972 Be careful about using local::lib in combination with "make install UNINST=1".
 973 The idea of this feature is that will uninstall an old version of a module
 974 before installing a new one. However it lacks a safety check that the old
 975 version and the new version will go in the same directory. Used in combination
 976 with local::lib, you can potentially delete a globally accessible version of a
 977 module while installing the new version in a local place. Only combine "make
 978 install UNINST=1" and local::lib if you understand these possible consequences.
 979
 980 =head1 LIMITATIONS
 981
 982 =over 4
 983
 984 =item * Directory names with spaces in them are not well supported by the perl
 985 toolchain and the programs it uses.  Pure-perl distributions should support
 986 spaces, but problems are more likely with dists that require compilation. A
 987 workaround you can do is moving your local::lib to a directory with spaces
 988 B<after> you installed all modules inside your local::lib bootstrap. But be
 989 aware that you can't update or install CPAN modules after the move.
 990
 991 =item * Rather basic shell detection. Right now anything with csh in its name is
 992 assumed to be a C shell or something compatible, and everything else is assumed
 993 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 994 not set, a Bourne-compatible shell is assumed.
 995
 996 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
 997
 998 =item * Should probably auto-fixup CPAN config if not already done.
 999
1000 =back
1001
1002 Patches very much welcome for any of the above.
1003
1004 =over 4
1005
1006 =item * On Win32 systems, does not have a way to write the created environment
1007 variables to the registry, so that they can persist through a reboot.
1008
1009 =back
1010
1011 =head1 TROUBLESHOOTING
1012
1013 If you've configured local::lib to install CPAN modules somewhere in to your
1014 home directory, and at some point later you try to install a module with C<cpan
1015 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1016 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1017 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1018 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1019 you've somehow lost your updated ExtUtils::MakeMaker module.
1020
1021 To remedy this situation, rerun the bootstrapping procedure documented above.
1022
1023 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1024
1025 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1026
1027 =head1 ENVIRONMENT
1028
1029 =over 4
1030
1031 =item SHELL
1032
1033 =item COMSPEC
1034
1035 local::lib looks at the user's C<SHELL> environment variable when printing out
1036 commands to add to the shell configuration file.
1037
1038 On Win32 systems, C<COMSPEC> is also examined.
1039
1040 =back
1041
1042 =head1 SEE ALSO
1043
1044 =over 4
1045
1046 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1047
1048 =back
1049
1050 =head1 SUPPORT
1051
1052 IRC:
1053
1054     Join #local-lib on irc.perl.org.
1055
1056 =head1 AUTHOR
1057
1058 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1059
1060 auto_install fixes kindly sponsored by http://www.takkle.com/
1061
1062 =head1 CONTRIBUTORS
1063
1064 Patches to correctly output commands for csh style shells, as well as some
1065 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1066
1067 Doc patches for a custom local::lib directory, more cleanups in the english
1068 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1069 Torsten Raudssus <torsten@raudssus.de>.
1070
1071 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1072 things will install properly, submitted a fix for the bug causing problems with
1073 writing Makefiles during bootstrapping, contributed an example program, and
1074 submitted yet another fix to ensure that local::lib can install and bootstrap
1075 properly. Many, many thanks!
1076
1077 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1078 section. Many thanks!
1079
1080 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1081
1082 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1083 by a patch from Marco Emilio Poleggi.
1084
1085 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1086 '--self-contained' option.
1087
1088 Documentation patches to make win32 usage clearer by
1089 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1090
1091 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1092 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1093
1094 Improvements to stacking multiple local::lib dirs and removing them from the
1095 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1096
1097 Patch for Carp version mismatch contributed by Hakim Cassimally
1098 <osfameron@cpan.org>.
1099
1100 =head1 COPYRIGHT
1101
1102 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1103 listed above.
1104
1105 =head1 LICENSE
1106
1107 This is free software; you can redistribute it and/or modify it under
1108 the same terms as the Perl 5 programming language system itself.
1109
1110 =cut