lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '2.000004'; # 2.0.4
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19   my $shelltype;
  20
  21   while (@args) {
  22     my $arg = shift @args;
  23     # check for lethal dash first to stop processing before causing problems
  24     # the fancy dash is U+2212 or \xE2\x88\x92
  25     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  26       die <<'DEATH';
  27 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  28 These are *not* the traditional -- dashes that software recognizes. You
  29 probably got these by copy-pasting from the perldoc for this module as
  30 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  31 terminal, but can happen elsewhere too. Please try again after replacing the
  32 dashes with normal minus signs.
  33 DEATH
  34     }
  35     elsif ($arg eq '--self-contained') {
  36       die <<'DEATH';
  37 FATAL: The local::lib --self-contained flag has never worked reliably and the
  38 original author, Mark Stosberg, was unable or unwilling to maintain it. As
  39 such, this flag has been removed from the local::lib codebase in order to
  40 prevent misunderstandings and potentially broken builds. The local::lib authors
  41 recommend that you look at the lib::core::only module shipped with this
  42 distribution in order to create a more robust environment that is equivalent to
  43 what --self-contained provided (although quite possibly not what you originally
  44 thought it provided due to the poor quality of the documentation, for which we
  45 apologise).
  46 DEATH
  47     }
  48     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  49       my $path = defined $1 ? $1 : shift @args;
  50       push @steps, ['deactivate', $path];
  51     }
  52     elsif ( $arg eq '--deactivate-all' ) {
  53       push @steps, ['deactivate_all'];
  54     }
  55     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  56       $shelltype = defined $1 ? $1 : shift @args;
  57     }
  58     elsif ( $arg eq '--no-create' ) {
  59       $opts{no_create} = 1;
  60     }
  61     elsif ( $arg =~ /^--/ ) {
  62       die "Unknown import argument: $arg";
  63     }
  64     else {
  65       push @steps, ['activate', $arg];
  66     }
  67   }
  68   if (!@steps) {
  69     push @steps, ['activate', undef];
  70   }
  71
  72   my $self = $class->new(%opts);
  73
  74   for (@steps) {
  75     my ($method, @args) = @$_;
  76     $self = $self->$method(@args);
  77   }
  78
  79   if ($0 eq '-') {
  80     print $self->environment_vars_string($shelltype);
  81     exit 0;
  82   }
  83   else {
  84     $self->setup_local_lib;
  85   }
  86 }
  87
  88 sub new {
  89   my $class = shift;
  90   bless {@_}, $class;
  91 }
  92
  93 sub clone {
  94   my $self = shift;
  95   bless {%$self, @_}, ref $self;
  96 }
  97
  98 sub inc { $_[0]->{inc}     ||= \@INC }
  99 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
 100 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
 101 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
 102 sub extra { $_[0]->{extra} ||= {} }
 103 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
 104 sub no_create { $_[0]->{no_create} }
 105
 106 my $_archname = $Config{archname};
 107 my $_version  = $Config{version};
 108 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
 109 my $_path_sep = $Config{path_sep};
 110
 111 sub _as_list {
 112   my $list = shift;
 113   grep length, map {
 114     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 115       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 116                         : ()
 117     )
 118   } ref $list ? @$list : $list;
 119 }
 120 sub _remove_from {
 121   my ($list, @remove) = @_;
 122   return @$list
 123     if !@remove;
 124   my %remove = map { $_ => 1 } @remove;
 125   grep !$remove{$_}, _as_list($list);
 126 }
 127
 128 my @_lib_subdirs = (
 129   [$_version, $_archname],
 130   [$_version],
 131   [$_archname],
 132   (@_inc_version_list ? \@_inc_version_list : ()),
 133   [],
 134 );
 135
 136 sub install_base_bin_path {
 137   my ($class, $path) = @_;
 138   return File::Spec->catdir($path, 'bin');
 139 }
 140 sub install_base_perl_path {
 141   my ($class, $path) = @_;
 142   return File::Spec->catdir($path, 'lib', 'perl5');
 143 }
 144 sub install_base_arch_path {
 145   my ($class, $path) = @_;
 146   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 147 }
 148
 149 sub lib_paths_for {
 150   my ($class, $path) = @_;
 151   my $base = $class->install_base_perl_path($path);
 152   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 153 }
 154
 155 sub _mm_escape_path {
 156   my $path = shift;
 157   $path =~ s/\\/\\\\\\\\/g;
 158   if ($path =~ s/ /\\ /g) {
 159     $path = qq{"\\"$path\\""};
 160   }
 161   return $path;
 162 }
 163
 164 sub _mb_escape_path {
 165   my $path = shift;
 166   $path =~ s/\\/\\\\/g;
 167   return qq{"$path"};
 168 }
 169
 170 sub installer_options_for {
 171   my ($class, $path) = @_;
 172   return (
 173     PERL_MM_OPT =>
 174       defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 175     PERL_MB_OPT =>
 176       defined $path ? "--install_base "._mb_escape_path($path) : undef,
 177   );
 178 }
 179
 180 sub active_paths {
 181   my ($self) = @_;
 182   $self = ref $self ? $self : $self->new;
 183
 184   return grep {
 185     # screen out entries that aren't actually reflected in @INC
 186     my $active_ll = $self->install_base_perl_path($_);
 187     grep { $_ eq $active_ll } @{$self->inc};
 188   } _as_list($self->roots);
 189 }
 190
 191
 192 sub deactivate {
 193   my ($self, $path) = @_;
 194   $self = $self->new unless ref $self;
 195   $path = $self->resolve_path($path);
 196   $path = $self->normalize_path($path);
 197
 198   my @active_lls = $self->active_paths;
 199
 200   if (!grep { $_ eq $path } @active_lls) {
 201     warn "Tried to deactivate inactive local::lib '$path'\n";
 202     return $self;
 203   }
 204
 205   my %args = (
 206     bins  => [ _remove_from($self->bins,
 207       $self->install_base_bin_path($path)) ],
 208     libs  => [ _remove_from($self->libs,
 209       $self->install_base_perl_path($path)) ],
 210     inc   => [ _remove_from($self->inc,
 211       $self->lib_paths_for($path)) ],
 212     roots => [ _remove_from($self->roots, $path) ],
 213   );
 214
 215   $args{extra} = { $self->installer_options_for($args{roots}[0]) };
 216
 217   $self->clone(%args);
 218 }
 219
 220 sub deactivate_all {
 221   my ($self) = @_;
 222   $self = $self->new unless ref $self;
 223
 224   my @active_lls = $self->active_paths;
 225
 226   my %args;
 227   if (@active_lls) {
 228     %args = (
 229       bins => [ _remove_from($self->bins,
 230         map $self->install_base_bin_path($_), @active_lls) ],
 231       libs => [ _remove_from($self->libs,
 232         map $self->install_base_perl_path($_), @active_lls) ],
 233       inc => [ _remove_from($self->inc,
 234         map $self->lib_paths_for($_), @active_lls) ],
 235       roots => [ _remove_from($self->roots, @active_lls) ],
 236     );
 237   }
 238
 239   $args{extra} = { $self->installer_options_for(undef) };
 240
 241   $self->clone(%args);
 242 }
 243
 244 sub activate {
 245   my ($self, $path) = @_;
 246   $self = $self->new unless ref $self;
 247   $path = $self->resolve_path($path);
 248   $self->ensure_dir_structure_for($path)
 249     unless $self->no_create;
 250
 251   $path = $self->normalize_path($path);
 252
 253   my @active_lls = $self->active_paths;
 254
 255   if (grep { $_ eq $path } @active_lls[1 .. $#active_lls]) {
 256     $self = $self->deactivate($path);
 257   }
 258
 259   my %args;
 260   if (!@active_lls || $active_lls[0] ne $path) {
 261     %args = (
 262       bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 263       libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 264       inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 265       roots => [ $path, @{$self->roots} ],
 266     );
 267   }
 268
 269   $args{extra} = { $self->installer_options_for($path) };
 270
 271   $self->clone(%args);
 272 }
 273
 274 sub normalize_path {
 275   my ($self, $path) = @_;
 276   $path = ( Win32::GetShortPathName($path) || $path )
 277     if $^O eq 'MSWin32';
 278   return $path;
 279 }
 280
 281 sub build_environment_vars_for {
 282   my $self = $_[0]->new->activate($_[1]);
 283   $self->build_environment_vars;
 284 }
 285 sub build_environment_vars {
 286   my $self = shift;
 287   (
 288     PATH                => join($_path_sep, _as_list($self->bins)),
 289     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 290     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 291     %{$self->extra},
 292   );
 293 }
 294
 295 sub setup_local_lib_for {
 296   my $self = $_[0]->new->activate($_[1]);
 297   $self->setup_local_lib;
 298 }
 299
 300 sub setup_local_lib {
 301   my $self = shift;
 302   $self->setup_env_hash;
 303   @INC = @{$self->inc};
 304 }
 305
 306 sub setup_env_hash_for {
 307   my $self = $_[0]->new->activate($_[1]);
 308   $self->setup_env_hash;
 309 }
 310 sub setup_env_hash {
 311   my $self = shift;
 312   my %env = $self->build_environment_vars;
 313   for my $key (keys %env) {
 314     if (defined $env{$key}) {
 315       $ENV{$key} = $env{$key};
 316     }
 317     else {
 318       delete $ENV{$key};
 319     }
 320   }
 321 }
 322
 323 sub print_environment_vars_for {
 324   print $_[0]->environment_vars_string_for(@_[1..$#_]);
 325 }
 326
 327 sub environment_vars_string_for {
 328   my $self = $_[0]->new->activate($_[1]);
 329   $self->environment_vars_string;
 330 }
 331 sub environment_vars_string {
 332   my ($self, $shelltype) = @_;
 333
 334   $shelltype ||= $self->guess_shelltype;
 335
 336   my $build_method = "build_${shelltype}_env_declaration";
 337
 338   my @envs = (
 339     PATH                => $self->bins,
 340     PERL5LIB            => $self->libs,
 341     PERL_LOCAL_LIB_ROOT => $self->roots,
 342     %{$self->extra},
 343   );
 344   my $out = '';
 345   while (@envs) {
 346     my ($name, $value) = (shift(@envs), shift(@envs));
 347     if (
 348         ref $value
 349         && @$value == 1
 350         && ref $value->[0]
 351         && ref $value->[0] eq 'SCALAR'
 352         && ${$value->[0]} eq $name) {
 353       next;
 354     }
 355     if (
 356         !ref $value
 357         and defined $value
 358           ? (defined $ENV{$name} && $value eq $ENV{$name})
 359           : !defined $ENV{$name}
 360     ) {
 361       next;
 362     }
 363     $out .= $self->$build_method($name, $value);
 364   }
 365   my $wrap_method = 'wrap_' . $self->shelltype . '_output';
 366   if ($self->can($wrap_method)) {
 367     return $self->$wrap_method($out);
 368   }
 369   return $out;
 370 }
 371
 372 sub build_bourne_env_declaration {
 373   my ($class, $name, $args) = @_;
 374   my $value = $class->_interpolate($args, '$%s', '"', '\\%s');
 375
 376   if (!defined $value) {
 377     return qq{unset $name;\n};
 378   }
 379
 380   $value =~ s/(^|\G|$_path_sep)\$$name$_path_sep/$1\$$name\${$name+$_path_sep}/g;
 381   $value =~ s/$_path_sep\$$name$/\${$name+$_path_sep}\$$name/;
 382
 383   qq{${name}="$value";\nexport ${name};\n}
 384 }
 385
 386 sub build_csh_env_declaration {
 387   my ($class, $name, $args) = @_;
 388   my ($value, @vars) = $class->_interpolate($args, '$%s', '"', '"\\%s"');
 389   if (!defined $value) {
 390     return qq{unsetenv $name;\n};
 391   }
 392
 393   my $out = '';
 394   for my $var (@vars) {
 395     $out .= qq{if ! \$?$name setenv $name '';\n};
 396   }
 397
 398   my $value_without = $value;
 399   if ($value_without =~ s/(?:^|$_path_sep)\$$name(?:$_path_sep|$)//g) {
 400     $out .= qq{if "\$$name" != '' setenv $name "$value";\n};
 401     $out .= qq{if "\$$name" == '' };
 402   }
 403   $out .= qq{setenv $name "$value_without";\n};
 404   return $out;
 405 }
 406
 407 sub build_cmd_env_declaration {
 408   my ($class, $name, $args) = @_;
 409   my $value = $class->_interpolate($args, '%%%s%%', qr([()!^"<>&|]), '^%s');
 410   if (!$value) {
 411     return qq{\@set $name=\n};
 412   }
 413
 414   my $out = '';
 415   my $value_without = $value;
 416   if ($value_without =~ s/(?:^|$_path_sep)%$name%(?:$_path_sep|$)//g) {
 417     $out .= qq{\@if not "%$name%"=="" set $name=$value\n};
 418     $out .= qq{\@if "%$name%"=="" };
 419   }
 420   $out .= qq{\@set $name=$value_without\n};
 421   return $out;
 422 }
 423
 424 sub build_powershell_env_declaration {
 425   my ($class, $name, $args) = @_;
 426   my $value = $class->_interpolate($args, '$env:%s', '"', '`%s');
 427
 428   if (!$value) {
 429     return qq{Remove-Item -ErrorAction 0 Env:\\$name;\n};
 430   }
 431
 432   my $maybe_path_sep = qq{\$(if("\$env:$name"-eq""){""}else{"$_path_sep"})};
 433   $value =~ s/(^|\G|$_path_sep)\$env:$name$_path_sep/$1\$env:$name"+$maybe_path_sep+"/g;
 434   $value =~ s/$_path_sep\$env:$name$/"+$maybe_path_sep+\$env:$name+"/;
 435
 436   qq{\$env:$name = \$("$value");\n};
 437 }
 438 sub wrap_powershell_output {
 439   my ($class, $out) = @_;
 440   return $out || " \n";
 441 }
 442
 443 sub _interpolate {
 444   my ($class, $args, $var_pat, $escape, $escape_pat) = @_;
 445   return
 446     unless defined $args;
 447   my @args = ref $args ? @$args : $args;
 448   return
 449     unless @args;
 450   my @vars = map { $$_ } grep { ref $_ eq 'SCALAR' } @args;
 451   my $string = join $_path_sep, map {
 452     ref $_ eq 'SCALAR' ? sprintf($var_pat, $$_) : do {
 453       s/($escape)/sprintf($escape_pat, $1)/ge; $_;
 454     };
 455   } @args;
 456   return wantarray ? ($string, \@vars) : $string;
 457 }
 458
 459 sub pipeline;
 460
 461 sub pipeline {
 462   my @methods = @_;
 463   my $last = pop(@methods);
 464   if (@methods) {
 465     \sub {
 466       my ($obj, @args) = @_;
 467       $obj->${pipeline @methods}(
 468         $obj->$last(@args)
 469       );
 470     };
 471   } else {
 472     \sub {
 473       shift->$last(@_);
 474     };
 475   }
 476 }
 477
 478 sub resolve_path {
 479   my ($class, $path) = @_;
 480
 481   $path = $class->${pipeline qw(
 482     resolve_relative_path
 483     resolve_home_path
 484     resolve_empty_path
 485   )}($path);
 486
 487   $path;
 488 }
 489
 490 sub resolve_empty_path {
 491   my ($class, $path) = @_;
 492   if (defined $path) {
 493     $path;
 494   } else {
 495     '~/perl5';
 496   }
 497 }
 498
 499 sub resolve_home_path {
 500   my ($class, $path) = @_;
 501   return $path unless ($path =~ /^~/);
 502   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 503   my $homedir = do {
 504     if (!defined $user && defined $ENV{HOME}) {
 505       $ENV{HOME}
 506     }
 507     else {
 508       require File::Glob;
 509       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 510     }
 511   };
 512   unless (defined $homedir) {
 513     require Carp;
 514     Carp::croak(
 515       "Couldn't resolve homedir for "
 516       .(defined $user ? $user : 'current user')
 517     );
 518   }
 519   $path =~ s/^~[^\/]*/$homedir/;
 520   $path;
 521 }
 522
 523 sub resolve_relative_path {
 524   my ($class, $path) = @_;
 525   $path = File::Spec->rel2abs($path);
 526 }
 527
 528 sub ensure_dir_structure_for {
 529   my ($class, $path) = @_;
 530   unless (-d $path) {
 531     warn "Attempting to create directory ${path}\n";
 532   }
 533   require File::Basename;
 534   my @dirs;
 535   while(!-d $path) {
 536     push @dirs, $path;
 537     $path = File::Basename::dirname($path);
 538   }
 539   mkdir $_ for reverse @dirs;
 540   return;
 541 }
 542
 543 sub guess_shelltype {
 544   my $shellbin
 545     = defined $ENV{SHELL}
 546       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 547     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 548       ? 'bash'
 549     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 550       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 551     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 552       ? 'powershell.exe'
 553     : 'sh';
 554
 555   for ($shellbin) {
 556     return
 557         /csh$/                   ? 'csh'
 558       : /command(?:\.com)?$/i    ? 'cmd'
 559       : /cmd(?:\.exe)?$/i        ? 'cmd'
 560       : /4nt(?:\.exe)?$/i        ? 'cmd'
 561       : /powershell(?:\.exe)?$/i ? 'powershell'
 562                                  : 'bourne';
 563   }
 564 }
 565
 566 1;
 567 __END__
 568
 569 =encoding utf8
 570
 571 =head1 NAME
 572
 573 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 574
 575 =head1 SYNOPSIS
 576
 577 In code -
 578
 579   use local::lib; # sets up a local lib at ~/perl5
 580
 581   use local::lib '~/foo'; # same, but ~/foo
 582
 583   # Or...
 584   use FindBin;
 585   use local::lib "$FindBin::Bin/../support";  # app-local support library
 586
 587 From the shell -
 588
 589   # Install LWP and its missing dependencies to the '~/perl5' directory
 590   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 591
 592   # Just print out useful shell commands
 593   $ perl -Mlocal::lib
 594   export PERL_MB_OPT='--install_base /home/username/perl5'
 595   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 596   export PERL5LIB="/home/username/perl5/lib/perl5"
 597   export PATH="/home/username/perl5/bin:$PATH"
 598
 599 From a .bashrc file -
 600
 601   [ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)"
 602
 603 =head2 The bootstrapping technique
 604
 605 A typical way to install local::lib is using what is known as the
 606 "bootstrapping" technique.  You would do this if your system administrator
 607 hasn't already installed local::lib.  In this case, you'll need to install
 608 local::lib in your home directory.
 609
 610 Even if you do have administrative privileges, you will still want to set up your
 611 environment variables, as discussed in step 4. Without this, you would still
 612 install the modules into the system CPAN installation and also your Perl scripts
 613 will not use the lib/ path you bootstrapped with local::lib.
 614
 615 By default local::lib installs itself and the CPAN modules into ~/perl5.
 616
 617 Windows users must also see L</Differences when using this module under Win32>.
 618
 619 =over 4
 620
 621 =item 1.
 622
 623 Download and unpack the local::lib tarball from CPAN (search for "Download"
 624 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 625 or administrator.  Unpack the file in your home directory or in any other
 626 convenient location.
 627
 628 =item 2.
 629
 630 Run this:
 631
 632   perl Makefile.PL --bootstrap
 633
 634 If the system asks you whether it should automatically configure as much
 635 as possible, you would typically answer yes.
 636
 637 In order to install local::lib into a directory other than the default, you need
 638 to specify the name of the directory when you call bootstrap, as follows:
 639
 640   perl Makefile.PL --bootstrap=~/foo
 641
 642 =item 3.
 643
 644 Run this: (local::lib assumes you have make installed on your system)
 645
 646   make test && make install
 647
 648 =item 4.
 649
 650 Now we need to setup the appropriate environment variables, so that Perl
 651 starts using our newly generated lib/ directory. If you are using bash or
 652 any other Bourne shells, you can add this to your shell startup script this
 653 way:
 654
 655   echo '[ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)"' >>~/.bashrc
 656
 657 If you are using C shell, you can do this as follows:
 658
 659   /bin/csh
 660   echo $SHELL
 661   /bin/csh
 662   echo 'eval `perl -I$HOME/perl5/lib/perl5 -Mlocal::lib`' >> ~/.cshrc
 663
 664 If you passed to bootstrap a directory other than default, you also need to
 665 give that as import parameter to the call of the local::lib module like this
 666 way:
 667
 668   echo '[ $SHLVL -eq 1 ] && eval "$(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)"' >>~/.bashrc
 669
 670 After writing your shell configuration file, be sure to re-read it to get the
 671 changed settings into your current shell's environment. Bourne shells use
 672 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 673
 674 =back
 675
 676 If you're on a slower machine, or are operating under draconian disk space
 677 limitations, you can disable the automatic generation of manpages from POD when
 678 installing modules by using the C<--no-manpages> argument when bootstrapping:
 679
 680   perl Makefile.PL --bootstrap --no-manpages
 681
 682 To avoid doing several bootstrap for several Perl module environments on the
 683 same account, for example if you use it for several different deployed
 684 applications independently, you can use one bootstrapped local::lib
 685 installation to install modules in different directories directly this way:
 686
 687   cd ~/mydir1
 688   perl -Mlocal::lib=./
 689   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 690   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 691   perl -MCPAN -e install ...    ### whatever modules you want
 692   cd ../mydir2
 693   ... REPEAT ...
 694
 695 When used in a C<.bashrc> file, it is recommended that you protect against
 696 re-activating a directory in a sub-shell.  This can be done by checking the
 697 C<$SHLVL> variable as shown in synopsis.  Without this, sub-shells created by
 698 the user or other programs will override changes made to the parent shell's
 699 environment.
 700
 701 If you are working with several C<local::lib> environments, you may want to
 702 remove some of them from the current environment without disturbing the others.
 703 You can deactivate one environment like this (using bourne sh):
 704
 705   eval $(perl -Mlocal::lib=--deactivate,~/path)
 706
 707 which will generate and run the commands needed to remove C<~/path> from your
 708 various search paths. Whichever environment was B<activated most recently> will
 709 remain the target for module installations. That is, if you activate
 710 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 711 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 712 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 713 installed in C<~/pathB> because pathB was activated later.
 714
 715 You can also ask C<local::lib> to clean itself completely out of the current
 716 shell's environment with the C<--deactivate-all> option.
 717 For multiple environments for multiple apps you may need to include a modified
 718 version of the C<< use FindBin >> instructions in the "In code" sample above.
 719 If you did something like the above, you have a set of Perl modules at C<<
 720 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 721 you need to tell it where to find the modules you installed for it at C<<
 722 ~/mydir1/lib >>.
 723
 724 In C<< ~/mydir1/scripts/myscript.pl >>:
 725
 726   use strict;
 727   use warnings;
 728   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 729   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 730
 731 Put this before any BEGIN { ... } blocks that require the modules you installed.
 732
 733 =head2 Differences when using this module under Win32
 734
 735 To set up the proper environment variables for your current session of
 736 C<CMD.exe>, you can use this:
 737
 738   C:\>perl -Mlocal::lib
 739   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 740   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 741   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 742   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 743
 744   ### To set the environment for this shell alone
 745   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 746   ### instead of $(perl -Mlocal::lib=./)
 747
 748 If you want the environment entries to persist, you'll need to add them to the
 749 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 750
 751 The "~" is translated to the user's profile directory (the directory named for
 752 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 753 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 754 directory is translated to a short name (which means the directory must exist)
 755 and the subdirectories are created.
 756
 757 =head3 PowerShell
 758
 759 local::lib also supports PowerShell, and can be used with the
 760 C<Invoke-Expression> cmdlet.
 761
 762   Invoke-Expression "$(perl -Mlocal::lib)"
 763
 764 =head1 RATIONALE
 765
 766 The version of a Perl package on your machine is not always the version you
 767 need.  Obviously, the best thing to do would be to update to the version you
 768 need.  However, you might be in a situation where you're prevented from doing
 769 this.  Perhaps you don't have system administrator privileges; or perhaps you
 770 are using a package management system such as Debian, and nobody has yet gotten
 771 around to packaging up the version you need.
 772
 773 local::lib solves this problem by allowing you to create your own directory of
 774 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 775 be within your own home directory).  The existing system Perl installation is
 776 not affected; you simply invoke Perl with special options so that Perl uses the
 777 packages in your own local package directory rather than the system packages.
 778 local::lib arranges things so that your locally installed version of the Perl
 779 packages takes precedence over the system installation.
 780
 781 If you are using a package management system (such as Debian), you don't need to
 782 worry about Debian and CPAN stepping on each other's toes.  Your local version
 783 of the packages will be written to an entirely separate directory from those
 784 installed by Debian.
 785
 786 =head1 DESCRIPTION
 787
 788 This module provides a quick, convenient way of bootstrapping a user-local Perl
 789 module library located within the user's home directory. It also constructs and
 790 prints out for the user the list of environment variables using the syntax
 791 appropriate for the user's current shell (as specified by the C<SHELL>
 792 environment variable), suitable for directly adding to one's shell
 793 configuration file.
 794
 795 More generally, local::lib allows for the bootstrapping and usage of a
 796 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 797 easier to ship an application with an app-specific copy of a Perl module, or
 798 collection of modules. Useful in cases like when an upstream maintainer hasn't
 799 applied a patch to a module of theirs that you need for your application.
 800
 801 On import, local::lib sets the following environment variables to appropriate
 802 values:
 803
 804 =over 4
 805
 806 =item PERL_MB_OPT
 807
 808 =item PERL_MM_OPT
 809
 810 =item PERL5LIB
 811
 812 =item PATH
 813
 814 =item PERL_LOCAL_LIB_ROOT
 815
 816 =back
 817
 818 When possible, these will be appended to instead of overwritten entirely.
 819
 820 These values are then available for reference by any code after import.
 821
 822 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 823
 824 See L<lib::core::only> for one way to do this - but note that
 825 there are a number of caveats, and the best approach is always to perform a
 826 build against a clean perl (i.e. site and vendor as close to empty as possible).
 827
 828 =head1 IMPORT OPTIONS
 829
 830 Options are values that can be passed to the C<local::lib> import besides the
 831 directory to use. They are specified as C<use local::lib '--option'[, path];>
 832 or C<perl -Mlocal::lib=--option[,path]>.
 833
 834 =head2 --deactivate
 835
 836 Remove the chosen path (or the default path) from the module search paths if it
 837 was added by C<local::lib>, instead of adding it.
 838
 839 =head2 --deactivate-all
 840
 841 Remove all directories that were added to search paths by C<local::lib> from the
 842 search paths.
 843
 844 =head2 --shelltype
 845
 846 Specify the shell type to use for output.  By default, the shell will be
 847 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 848 C<cmd>, or C<powershell>.
 849
 850 =head2 --no-create
 851
 852 Prevents C<local::lib> from creating directories when activating dirs.  This is
 853 likely to cause issues on Win32 systems.
 854
 855 =head1 CLASS METHODS
 856
 857 =head2 ensure_dir_structure_for
 858
 859 =over 4
 860
 861 =item Arguments: $path
 862
 863 =item Return value: None
 864
 865 =back
 866
 867 Attempts to create the given path, and all required parent directories. Throws
 868 an exception on failure.
 869
 870 =head2 print_environment_vars_for
 871
 872 =over 4
 873
 874 =item Arguments: $path
 875
 876 =item Return value: None
 877
 878 =back
 879
 880 Prints to standard output the variables listed above, properly set to use the
 881 given path as the base directory.
 882
 883 =head2 build_environment_vars_for
 884
 885 =over 4
 886
 887 =item Arguments: $path
 888
 889 =item Return value: %environment_vars
 890
 891 =back
 892
 893 Returns a hash with the variables listed above, properly set to use the
 894 given path as the base directory.
 895
 896 =head2 setup_env_hash_for
 897
 898 =over 4
 899
 900 =item Arguments: $path
 901
 902 =item Return value: None
 903
 904 =back
 905
 906 Constructs the C<%ENV> keys for the given path, by calling
 907 L</build_environment_vars_for>.
 908
 909 =head2 active_paths
 910
 911 =over 4
 912
 913 =item Arguments: None
 914
 915 =item Return value: @paths
 916
 917 =back
 918
 919 Returns a list of active C<local::lib> paths, according to the
 920 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 921 what is really in C<@INC>.
 922
 923 =head2 install_base_perl_path
 924
 925 =over 4
 926
 927 =item Arguments: $path
 928
 929 =item Return value: $install_base_perl_path
 930
 931 =back
 932
 933 Returns a path describing where to install the Perl modules for this local
 934 library installation. Appends the directories C<lib> and C<perl5> to the given
 935 path.
 936
 937 =head2 lib_paths_for
 938
 939 =over 4
 940
 941 =item Arguments: $path
 942
 943 =item Return value: @lib_paths
 944
 945 =back
 946
 947 Returns the list of paths perl will search for libraries, given a base path.
 948 This includes the base path itself, the architecture specific subdirectory, and
 949 perl version specific subdirectories.  These paths may not all exist.
 950
 951 =head2 install_base_bin_path
 952
 953 =over 4
 954
 955 =item Arguments: $path
 956
 957 =item Return value: $install_base_bin_path
 958
 959 =back
 960
 961 Returns a path describing where to install the executable programs for this
 962 local library installation. Appends the directory C<bin> to the given path.
 963
 964 =head2 installer_options_for
 965
 966 =over 4
 967
 968 =item Arguments: $path
 969
 970 =item Return value: %installer_env_vars
 971
 972 =back
 973
 974 Returns a hash of environment variables that should be set to cause
 975 installation into the given path.
 976
 977 =head2 resolve_empty_path
 978
 979 =over 4
 980
 981 =item Arguments: $path
 982
 983 =item Return value: $base_path
 984
 985 =back
 986
 987 Builds and returns the base path into which to set up the local module
 988 installation. Defaults to C<~/perl5>.
 989
 990 =head2 resolve_home_path
 991
 992 =over 4
 993
 994 =item Arguments: $path
 995
 996 =item Return value: $home_path
 997
 998 =back
 999
1000 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
1001 for this purpose. If no definite answer is available, throws an exception.
1002
1003 =head2 resolve_relative_path
1004
1005 =over 4
1006
1007 =item Arguments: $path
1008
1009 =item Return value: $absolute_path
1010
1011 =back
1012
1013 Translates the given path into an absolute path.
1014
1015 =head2 resolve_path
1016
1017 =over 4
1018
1019 =item Arguments: $path
1020
1021 =item Return value: $absolute_path
1022
1023 =back
1024
1025 Calls the following in a pipeline, passing the result from the previous to the
1026 next, in an attempt to find where to configure the environment for a local
1027 library installation: L</resolve_empty_path>, L</resolve_home_path>,
1028 L</resolve_relative_path>. Passes the given path argument to
1029 L</resolve_empty_path> which then returns a result that is passed to
1030 L</resolve_home_path>, which then has its result passed to
1031 L</resolve_relative_path>. The result of this final call is returned from
1032 L</resolve_path>.
1033
1034 =head1 OBJECT INTERFACE
1035
1036 =head2 new
1037
1038 =over 4
1039
1040 =item Arguments: %attributes
1041
1042 =item Return value: $local_lib
1043
1044 =back
1045
1046 Constructs a new C<local::lib> object, representing the current state of
1047 C<@INC> and the relevant environment variables.
1048
1049 =head1 ATTRIBUTES
1050
1051 =head2 roots
1052
1053 An arrayref representing active C<local::lib> directories.
1054
1055 =head2 inc
1056
1057 An arrayref representing C<@INC>.
1058
1059 =head2 libs
1060
1061 An arrayref representing the PERL5LIB environment variable.
1062
1063 =head2 bins
1064
1065 An arrayref representing the PATH environment variable.
1066
1067 =head2 extra
1068
1069 A hashref of extra environment variables (e.g. C<PERL_MM_OPT> and
1070 C<PERL_MB_OPT>)
1071
1072 =head2 no_create
1073
1074 If set, C<local::lib> will not try to create directories when activating them.
1075
1076 =head1 OBJECT METHODS
1077
1078 =head2 clone
1079
1080 =over 4
1081
1082 =item Arguments: %attributes
1083
1084 =item Return value: $local_lib
1085
1086 =back
1087
1088 Constructs a new C<local::lib> object based on the existing one, overriding the
1089 specified attributes.
1090
1091 =head2 activate
1092
1093 =over 4
1094
1095 =item Arguments: $path
1096
1097 =item Return value: $new_local_lib
1098
1099 =back
1100
1101 Constructs a new instance with the specified path active.
1102
1103 =head2 deactivate
1104
1105 =over 4
1106
1107 =item Arguments: $path
1108
1109 =item Return value: $new_local_lib
1110
1111 =back
1112
1113 Constructs a new instance with the specified path deactivated.
1114
1115 =head2 deactivate_all
1116
1117 =over 4
1118
1119 =item Arguments: None
1120
1121 =item Return value: $new_local_lib
1122
1123 =back
1124
1125 Constructs a new instance with all C<local::lib> directories deactivated.
1126
1127 =head2 environment_vars_string
1128
1129 =over 4
1130
1131 =item Arguments: [ $shelltype ]
1132
1133 =item Return value: $shell_env_string
1134
1135 =back
1136
1137 Returns a string to set up the C<local::lib>, meant to be run by a shell.
1138
1139 =head2 build_environment_vars
1140
1141 =over 4
1142
1143 =item Arguments: None
1144
1145 =item Return value: %environment_vars
1146
1147 =back
1148
1149 Returns a hash with the variables listed above, properly set to use the
1150 given path as the base directory.
1151
1152 =head2 setup_env_hash
1153
1154 =over 4
1155
1156 =item Arguments: None
1157
1158 =item Return value: None
1159
1160 =back
1161
1162 Constructs the C<%ENV> keys for the given path, by calling
1163 L</build_environment_vars>.
1164
1165 =head2 setup_local_lib
1166
1167 Constructs the C<%ENV> hash using L</setup_env_hash>, and set up C<@INC>.
1168
1169 =head1 A WARNING ABOUT UNINST=1
1170
1171 Be careful about using local::lib in combination with "make install UNINST=1".
1172 The idea of this feature is that will uninstall an old version of a module
1173 before installing a new one. However it lacks a safety check that the old
1174 version and the new version will go in the same directory. Used in combination
1175 with local::lib, you can potentially delete a globally accessible version of a
1176 module while installing the new version in a local place. Only combine "make
1177 install UNINST=1" and local::lib if you understand these possible consequences.
1178
1179 =head1 LIMITATIONS
1180
1181 =over 4
1182
1183 =item * Directory names with spaces in them are not well supported by the perl
1184 toolchain and the programs it uses.  Pure-perl distributions should support
1185 spaces, but problems are more likely with dists that require compilation. A
1186 workaround you can do is moving your local::lib to a directory with spaces
1187 B<after> you installed all modules inside your local::lib bootstrap. But be
1188 aware that you can't update or install CPAN modules after the move.
1189
1190 =item * Rather basic shell detection. Right now anything with csh in its name is
1191 assumed to be a C shell or something compatible, and everything else is assumed
1192 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
1193 not set, a Bourne-compatible shell is assumed.
1194
1195 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
1196
1197 =item * Should probably auto-fixup CPAN config if not already done.
1198
1199 =item * local::lib loads L<File::Spec>.  When used to set shell variables,
1200 this isn't a problem.  When used inside a perl script, any L<File::Spec>
1201 version inside the local::lib will be ignored.  A workaround for this is using
1202 C<use lib "$ENV{HOME}/perl5/lib/perl5";> inside the script instead of using
1203 C<local::lib> directly.
1204
1205 =item * Conflicts with L<ExtUtils::MakeMaker>'s C<PREFIX> option.
1206 C<local::lib> uses the C<INSTALL_BASE> option, as it has more predictable and
1207 sane behavior.  If something attempts to use the C<PREFIX> option when running
1208 a F<Makefile.PL>, L<ExtUtils::MakeMaker> will refuse to run, as the two
1209 options conflict.  This can be worked around by temporarily unsetting the
1210 C<PERL_MM_OPT> environment variable.
1211
1212 =item * Conflicts with L<Module::Build>'s C<--prefix> option.  Similar to the
1213 previous limitation, but any C<--prefix> option specified will be ignored.
1214 This can be worked around by temporarily unsetting the C<PERL_MB_OPT>
1215 environment variable.
1216
1217 =back
1218
1219 Patches very much welcome for any of the above.
1220
1221 =over 4
1222
1223 =item * On Win32 systems, does not have a way to write the created environment
1224 variables to the registry, so that they can persist through a reboot.
1225
1226 =back
1227
1228 =head1 TROUBLESHOOTING
1229
1230 If you've configured local::lib to install CPAN modules somewhere in to your
1231 home directory, and at some point later you try to install a module with C<cpan
1232 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1233 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1234 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1235 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1236 you've somehow lost your updated ExtUtils::MakeMaker module.
1237
1238 To remedy this situation, rerun the bootstrapping procedure documented above.
1239
1240 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1241
1242 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1243
1244 =head1 ENVIRONMENT
1245
1246 =over 4
1247
1248 =item SHELL
1249
1250 =item COMSPEC
1251
1252 local::lib looks at the user's C<SHELL> environment variable when printing out
1253 commands to add to the shell configuration file.
1254
1255 On Win32 systems, C<COMSPEC> is also examined.
1256
1257 =back
1258
1259 =head1 SEE ALSO
1260
1261 =over 4
1262
1263 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1264
1265 =back
1266
1267 =head1 SUPPORT
1268
1269 IRC:
1270
1271     Join #local-lib on irc.perl.org.
1272
1273 =head1 AUTHOR
1274
1275 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1276
1277 auto_install fixes kindly sponsored by http://www.takkle.com/
1278
1279 =head1 CONTRIBUTORS
1280
1281 Patches to correctly output commands for csh style shells, as well as some
1282 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1283
1284 Doc patches for a custom local::lib directory, more cleanups in the english
1285 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1286 Torsten Raudssus <torsten@raudssus.de>.
1287
1288 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1289 things will install properly, submitted a fix for the bug causing problems with
1290 writing Makefiles during bootstrapping, contributed an example program, and
1291 submitted yet another fix to ensure that local::lib can install and bootstrap
1292 properly. Many, many thanks!
1293
1294 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1295 section. Many thanks!
1296
1297 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1298
1299 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1300 by a patch from Marco Emilio Poleggi.
1301
1302 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1303 '--self-contained' option.
1304
1305 Documentation patches to make win32 usage clearer by
1306 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1307
1308 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1309 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1310
1311 Improvements to stacking multiple local::lib dirs and removing them from the
1312 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1313
1314 Patch for Carp version mismatch contributed by Hakim Cassimally
1315 <osfameron@cpan.org>.
1316
1317 Rewrite of internals and numerous bug fixes and added features contributed by
1318 Graham Knop <haarg@haarg.org>.
1319
1320 =head1 COPYRIGHT
1321
1322 Copyright (c) 2007 - 2013 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1323 listed above.
1324
1325 =head1 LICENSE
1326
1327 This is free software; you can redistribute it and/or modify it under
1328 the same terms as the Perl 5 programming language system itself.
1329
1330 =cut