lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.008001; # probably works with earlier versions but I'm not supporting them
   7               # (patches would, of course, be welcome)
   8
   9 use File::Spec ();
  10 use File::Path ();
  11 use Config;
  12
  13 our $VERSION = '1.008007'; # 1.8.4
  14
  15 our @KNOWN_FLAGS = qw(--self-contained --deactivate --deactivate-all);
  16
  17 sub DEACTIVATE_ONE () { 1 }
  18 sub DEACTIVATE_ALL () { 2 }
  19
  20 sub INTERPOLATE_ENV () { 1 }
  21 sub LITERAL_ENV     () { 0 }
  22
  23 sub import {
  24   my ($class, @args) = @_;
  25
  26   # Remember what PERL5LIB was when we started
  27   my $perl5lib = $ENV{PERL5LIB} || '';
  28
  29   my %arg_store;
  30   for my $arg (@args) {
  31     # check for lethal dash first to stop processing before causing problems
  32     if ($arg =~ /−/) {
  33       die <<'DEATH';
  34 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  35 These are *not* the traditional -- dashes that software recognizes. You
  36 probably got these by copy-pasting from the perldoc for this module as
  37 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  38 terminal, but can happen elsewhere too. Please try again after replacing the
  39 dashes with normal minus signs.
  40 DEATH
  41     }
  42     elsif(grep { $arg eq $_ } @KNOWN_FLAGS) {
  43       (my $flag = $arg) =~ s/--//;
  44       $arg_store{$flag} = 1;
  45     }
  46     elsif($arg =~ /^--/) {
  47       die "Unknown import argument: $arg";
  48     }
  49     else {
  50       # assume that what's left is a path
  51       $arg_store{path} = $arg;
  52     }
  53   }
  54
  55   if($arg_store{'self-contained'}) {
  56     die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  57   }
  58
  59   my $deactivating = 0;
  60   if ($arg_store{deactivate}) {
  61     $deactivating = DEACTIVATE_ONE;
  62   }
  63   if ($arg_store{'deactivate-all'}) {
  64     $deactivating = DEACTIVATE_ALL;
  65   }
  66
  67   $arg_store{path} = $class->resolve_path($arg_store{path});
  68   $class->setup_local_lib_for($arg_store{path}, $deactivating);
  69
  70   for (@INC) { # Untaint @INC
  71     next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc.
  72     m/(.*)/ and $_ = $1;
  73   }
  74 }
  75
  76 sub pipeline;
  77
  78 sub pipeline {
  79   my @methods = @_;
  80   my $last = pop(@methods);
  81   if (@methods) {
  82     \sub {
  83       my ($obj, @args) = @_;
  84       $obj->${pipeline @methods}(
  85         $obj->$last(@args)
  86       );
  87     };
  88   } else {
  89     \sub {
  90       shift->$last(@_);
  91     };
  92   }
  93 }
  94
  95 =begin testing
  96
  97 #:: test pipeline
  98
  99 package local::lib;
 100
 101 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 102 my $foo = bless({}, 'Foo');
 103 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 104
 105 =end testing
 106
 107 =cut
 108
 109 sub _uniq {
 110     my %seen;
 111     grep { ! $seen{$_}++ } @_;
 112 }
 113
 114 sub resolve_path {
 115   my ($class, $path) = @_;
 116   $class->${pipeline qw(
 117     resolve_relative_path
 118     resolve_home_path
 119     resolve_empty_path
 120   )}($path);
 121 }
 122
 123 sub resolve_empty_path {
 124   my ($class, $path) = @_;
 125   if (defined $path) {
 126     $path;
 127   } else {
 128     '~/perl5';
 129   }
 130 }
 131
 132 =begin testing
 133
 134 #:: test classmethod setup
 135
 136 my $c = 'local::lib';
 137
 138 =end testing
 139
 140 =begin testing
 141
 142 #:: test classmethod
 143
 144 is($c->resolve_empty_path, '~/perl5');
 145 is($c->resolve_empty_path('foo'), 'foo');
 146
 147 =end testing
 148
 149 =cut
 150
 151 sub resolve_home_path {
 152   my ($class, $path) = @_;
 153   return $path unless ($path =~ /^~/);
 154   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 155   my $tried_file_homedir;
 156   my $homedir = do {
 157     if (eval { require File::HomeDir } && $File::HomeDir::VERSION >= 0.65) {
 158       $tried_file_homedir = 1;
 159       if (defined $user) {
 160         File::HomeDir->users_home($user);
 161       } else {
 162         File::HomeDir->my_home;
 163       }
 164     } else {
 165       if (defined $user) {
 166         (getpwnam $user)[7];
 167       } else {
 168         if (defined $ENV{HOME}) {
 169           $ENV{HOME};
 170         } else {
 171           (getpwuid $<)[7];
 172         }
 173       }
 174     }
 175   };
 176   unless (defined $homedir) {
 177     require Carp;
 178     Carp::croak(
 179       "Couldn't resolve homedir for "
 180       .(defined $user ? $user : 'current user')
 181       .($tried_file_homedir ? '' : ' - consider installing File::HomeDir')
 182     );
 183   }
 184   $path =~ s/^~[^\/]*/$homedir/;
 185   $path;
 186 }
 187
 188 sub resolve_relative_path {
 189   my ($class, $path) = @_;
 190   $path = File::Spec->rel2abs($path);
 191 }
 192
 193 =begin testing
 194
 195 #:: test classmethod
 196
 197 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 198 is($c->resolve_relative_path('bar'),'FOObar');
 199
 200 =end testing
 201
 202 =cut
 203
 204 sub setup_local_lib_for {
 205   my ($class, $path, $deactivating) = @_;
 206
 207   my $interpolate = LITERAL_ENV;
 208   my @active_lls = $class->active_paths;
 209
 210   $class->ensure_dir_structure_for($path);
 211
 212   # On Win32 directories often contain spaces. But some parts of the CPAN
 213   # toolchain don't like that. To avoid this, GetShortPathName() gives us
 214   # an alternate representation that has none.
 215   # This only works if the directory already exists.
 216   $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32';
 217
 218   if (! $deactivating) {
 219     if (@active_lls && $active_lls[-1] eq $path) {
 220       exit 0 if $0 eq '-';
 221       return; # Asked to add what's already at the top of the stack
 222     } elsif (grep { $_ eq $path} @active_lls) {
 223       # Asked to add a dir that's lower in the stack -- so we remove it from
 224       # where it is, and then add it back at the top.
 225       $class->setup_env_hash_for($path, DEACTIVATE_ONE);
 226       # Which means we can no longer output "PERL5LIB=...:$PERL5LIB" stuff
 227       # anymore because we're taking something *out*.
 228       $interpolate = INTERPOLATE_ENV;
 229     }
 230   }
 231
 232   if ($0 eq '-') {
 233     $class->print_environment_vars_for($path, $deactivating, $interpolate);
 234     exit 0;
 235   } else {
 236     $class->setup_env_hash_for($path, $deactivating);
 237     @INC = _uniq(split($Config{path_sep}, $ENV{PERL5LIB}), @INC);
 238   }
 239 }
 240
 241 sub install_base_bin_path {
 242   my ($class, $path) = @_;
 243   File::Spec->catdir($path, 'bin');
 244 }
 245
 246 sub install_base_perl_path {
 247   my ($class, $path) = @_;
 248   File::Spec->catdir($path, 'lib', 'perl5');
 249 }
 250
 251 sub install_base_arch_path {
 252   my ($class, $path) = @_;
 253   File::Spec->catdir($class->install_base_perl_path($path), $Config{archname});
 254 }
 255
 256 sub ensure_dir_structure_for {
 257   my ($class, $path) = @_;
 258   unless (-d $path) {
 259     warn "Attempting to create directory ${path}\n";
 260   }
 261   File::Path::mkpath($path);
 262   return
 263 }
 264
 265 sub guess_shelltype {
 266   my $shellbin = 'sh';
 267   if(defined $ENV{'SHELL'}) {
 268       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 269       $shellbin = $shell_bin_path_parts[-1];
 270   }
 271   my $shelltype = do {
 272       local $_ = $shellbin;
 273       if(/csh/) {
 274           'csh'
 275       } else {
 276           'bourne'
 277       }
 278   };
 279
 280   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 281   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 282       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 283       $shellbin = $shell_bin_path_parts[-1];
 284          $shelltype = do {
 285                  local $_ = $shellbin;
 286                  if(/command\.com/) {
 287                          'win32'
 288                  } elsif(/cmd\.exe/) {
 289                          'win32'
 290                  } elsif(/4nt\.exe/) {
 291                          'win32'
 292                  } else {
 293                          $shelltype
 294                  }
 295          };
 296   }
 297   return $shelltype;
 298 }
 299
 300 sub print_environment_vars_for {
 301   my ($class, $path, $deactivating, $interpolate) = @_;
 302   print $class->environment_vars_string_for($path, $deactivating, $interpolate);
 303 }
 304
 305 sub environment_vars_string_for {
 306   my ($class, $path, $deactivating, $interpolate) = @_;
 307   my @envs = $class->build_environment_vars_for($path, $deactivating, $interpolate);
 308   my $out = '';
 309
 310   # rather basic csh detection, goes on the assumption that something won't
 311   # call itself csh unless it really is. also, default to bourne in the
 312   # pathological situation where a user doesn't have $ENV{SHELL} defined.
 313   # note also that shells with funny names, like zoid, are assumed to be
 314   # bourne.
 315
 316   my $shelltype = $class->guess_shelltype;
 317
 318   while (@envs) {
 319     my ($name, $value) = (shift(@envs), shift(@envs));
 320     $value =~ s/(\\")/\\$1/g if defined $value;
 321     $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value);
 322   }
 323   return $out;
 324 }
 325
 326 # simple routines that take two arguments: an %ENV key and a value. return
 327 # strings that are suitable for passing directly to the relevant shell to set
 328 # said key to said value.
 329 sub build_bourne_env_declaration {
 330   my $class = shift;
 331   my($name, $value) = @_;
 332   return defined($value) ? qq{export ${name}="${value}";\n} : qq{unset ${name};\n};
 333 }
 334
 335 sub build_csh_env_declaration {
 336   my $class = shift;
 337   my($name, $value) = @_;
 338   return defined($value) ? qq{setenv ${name} "${value}"\n} : qq{unsetenv ${name}\n};
 339 }
 340
 341 sub build_win32_env_declaration {
 342   my $class = shift;
 343   my($name, $value) = @_;
 344   return defined($value) ? qq{set ${name}=${value}\n} : qq{set ${name}=\n};
 345 }
 346
 347 sub setup_env_hash_for {
 348   my ($class, $path, $deactivating) = @_;
 349   my %envs = $class->build_environment_vars_for($path, $deactivating, INTERPOLATE_ENV);
 350   @ENV{keys %envs} = values %envs;
 351 }
 352
 353 sub build_environment_vars_for {
 354   my ($class, $path, $deactivating, $interpolate) = @_;
 355
 356   if ($deactivating == DEACTIVATE_ONE) {
 357     return $class->build_deactivate_environment_vars_for($path, $interpolate);
 358   } elsif ($deactivating == DEACTIVATE_ALL) {
 359     return $class->build_deact_all_environment_vars_for($path, $interpolate);
 360   } else {
 361     return $class->build_activate_environment_vars_for($path, $interpolate);
 362   }
 363 }
 364
 365 # Build an environment value for a variable like PATH from a list of paths.
 366 # References to existing variables are given as references to the variable name.
 367 # Duplicates are removed.
 368 #
 369 # options:
 370 # - interpolate: INTERPOLATE_ENV/LITERAL_ENV
 371 # - exists: paths are included only if they exist (default: interpolate == INTERPOLATE_ENV)
 372 # - filter: function to apply to each path do decide if it must be included
 373 # - empty: the value to return in the case of empty value
 374 my %ENV_LIST_VALUE_DEFAULTS = (
 375     interpolate => INTERPOLATE_ENV,
 376     exists => undef,
 377     filter => sub { 1 },
 378     empty => undef,
 379 );
 380 sub _env_list_value {
 381   my $options = shift;
 382   die(sprintf "unknown option '$_' at %s line %u\n", (caller)[1..2])
 383     for grep { !exists $ENV_LIST_VALUE_DEFAULTS{$_} } keys %$options;
 384   my %options = (%ENV_LIST_VALUE_DEFAULTS, %{ $options });
 385   $options{exists} = $options{interpolate} == INTERPOLATE_ENV
 386     unless defined $options{exists};
 387
 388   my %seen;
 389
 390   my $value = join($Config{path_sep}, map {
 391       ref $_ ? ($^O eq 'MSWin32' ? "%${$_}%" : "\$${$_}") : $_
 392     } grep {
 393       ref $_ || (defined $_
 394                  && length($_) > 0
 395                  && !$seen{$_}++
 396                  && $options{filter}->($_)
 397                  && (!$options{exists} || -e $_))
 398     } map {
 399       if (ref $_ eq 'SCALAR' && $options{interpolate} == INTERPOLATE_ENV) {
 400         exists $ENV{${$_}} ? (split /\Q$Config{path_sep}/, $ENV{${$_}}) : ()
 401       } else {
 402         $_
 403       }
 404     } @_);
 405   return length($value) ? $value : $options{empty};
 406 }
 407
 408 sub build_activate_environment_vars_for {
 409   my ($class, $path, $interpolate) = @_;
 410   return (
 411     PERL_LOCAL_LIB_ROOT =>
 412             _env_list_value(
 413               { interpolate => $interpolate, exists => 0, empty => '' },
 414               \'PERL_LOCAL_LIB_ROOT',
 415               $path,
 416             ),
 417     PERL_MB_OPT => "--install_base ${path}",
 418     PERL_MM_OPT => "INSTALL_BASE=${path}",
 419     PERL5LIB =>
 420             _env_list_value(
 421               { interpolate => $interpolate, exists => 0, empty => '' },
 422               $class->install_base_arch_path($path),
 423               $class->install_base_perl_path($path),
 424               \'PERL5LIB',
 425             ),
 426     PATH => _env_list_value(
 427               { interpolate => $interpolate, exists => 0, empty => '' },
 428               $class->install_base_bin_path($path),
 429               \'PATH',
 430             ),
 431   )
 432 }
 433
 434 sub active_paths {
 435   my ($class) = @_;
 436
 437   return () unless defined $ENV{PERL_LOCAL_LIB_ROOT};
 438   return grep { $_ ne '' } split /\Q$Config{path_sep}/, $ENV{PERL_LOCAL_LIB_ROOT};
 439 }
 440
 441 sub build_deactivate_environment_vars_for {
 442   my ($class, $path, $interpolate) = @_;
 443
 444   my @active_lls = $class->active_paths;
 445
 446   if (!grep { $_ eq $path } @active_lls) {
 447     warn "Tried to deactivate inactive local::lib '$path'\n";
 448     return ();
 449   }
 450
 451   my $perl_path = $class->install_base_perl_path($path);
 452   my $arch_path = $class->install_base_arch_path($path);
 453   my $bin_path = $class->install_base_bin_path($path);
 454
 455
 456   my %env = (
 457     PERL_LOCAL_LIB_ROOT => _env_list_value(
 458       {
 459         exists => 0,
 460       },
 461       grep { $_ ne $path } @active_lls
 462     ),
 463     PERL5LIB => _env_list_value(
 464       {
 465         exists => 0,
 466         filter => sub {
 467           $_ ne $perl_path && $_ ne $arch_path
 468         },
 469       },
 470       \'PERL5LIB',
 471     ),
 472     PATH => _env_list_value(
 473       {
 474         exists => 0,
 475         filter => sub { $_ ne $bin_path },
 476       },
 477       \'PATH',
 478     ),
 479   );
 480
 481   # If removing ourselves from the "top of the stack", set install paths to
 482   # correspond with the new top of stack.
 483   if ($active_lls[-1] eq $path) {
 484     my $new_top = $active_lls[-2];
 485     $env{PERL_MB_OPT} = defined($new_top) ? "--install_base ${new_top}" : undef;
 486     $env{PERL_MM_OPT} = defined($new_top) ? "INSTALL_BASE=${new_top}" : undef;
 487   }
 488
 489   return %env;
 490 }
 491
 492 sub build_deact_all_environment_vars_for {
 493   my ($class, $path, $interpolate) = @_;
 494
 495   my @active_lls = $class->active_paths;
 496
 497   my %perl_paths = map { (
 498       $class->install_base_perl_path($_) => 1,
 499       $class->install_base_arch_path($_) => 1
 500     ) } @active_lls;
 501   my %bin_paths = map { (
 502       $class->install_base_bin_path($_) => 1,
 503     ) } @active_lls;
 504
 505   my %env = (
 506     PERL_LOCAL_LIB_ROOT => undef,
 507     PERL_MM_OPT => undef,
 508     PERL_MB_OPT => undef,
 509     PERL5LIB => _env_list_value(
 510       {
 511         exists => 0,
 512         filter => sub {
 513           ! scalar grep { exists $perl_paths{$_} } $_[0]
 514         },
 515       },
 516       \'PERL5LIB'
 517     ),
 518     PATH => _env_list_value(
 519       {
 520         exists => 0,
 521         filter => sub {
 522           ! scalar grep { exists $bin_paths{$_} } $_[0]
 523         },
 524       },
 525       \'PATH'
 526     ),
 527   );
 528
 529   return %env;
 530 }
 531
 532 =begin testing
 533
 534 #:: test classmethod
 535
 536 File::Path::rmtree('t/var/splat');
 537
 538 $c->ensure_dir_structure_for('t/var/splat');
 539
 540 ok(-d 't/var/splat');
 541
 542 =end testing
 543
 544 =encoding utf8
 545
 546 =head1 NAME
 547
 548 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 549
 550 =head1 SYNOPSIS
 551
 552 In code -
 553
 554   use local::lib; # sets up a local lib at ~/perl5
 555
 556   use local::lib '~/foo'; # same, but ~/foo
 557
 558   # Or...
 559   use FindBin;
 560   use local::lib "$FindBin::Bin/../support";  # app-local support library
 561
 562 From the shell -
 563
 564   # Install LWP and its missing dependencies to the '~/perl5' directory
 565   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 566
 567   # Just print out useful shell commands
 568   $ perl -Mlocal::lib
 569   export PERL_MB_OPT='--install_base /home/username/perl5'
 570   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 571   export PERL5LIB='/home/username/perl5/lib/perl5/i386-linux:/home/username/perl5/lib/perl5'
 572   export PATH="/home/username/perl5/bin:$PATH"
 573
 574 =head2 The bootstrapping technique
 575
 576 A typical way to install local::lib is using what is known as the
 577 "bootstrapping" technique.  You would do this if your system administrator
 578 hasn't already installed local::lib.  In this case, you'll need to install
 579 local::lib in your home directory.
 580
 581 If you do have administrative privileges, you will still want to set up your
 582 environment variables, as discussed in step 4. Without this, you would still
 583 install the modules into the system CPAN installation and also your Perl scripts
 584 will not use the lib/ path you bootstrapped with local::lib.
 585
 586 By default local::lib installs itself and the CPAN modules into ~/perl5.
 587
 588 Windows users must also see L</Differences when using this module under Win32>.
 589
 590 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 591 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 592 or administrator.  Unpack the file in your home directory or in any other
 593 convenient location.
 594
 595 2. Run this:
 596
 597   perl Makefile.PL --bootstrap
 598
 599 If the system asks you whether it should automatically configure as much
 600 as possible, you would typically answer yes.
 601
 602 In order to install local::lib into a directory other than the default, you need
 603 to specify the name of the directory when you call bootstrap, as follows:
 604
 605   perl Makefile.PL --bootstrap=~/foo
 606
 607 3. Run this: (local::lib assumes you have make installed on your system)
 608
 609   make test && make install
 610
 611 4. Now we need to setup the appropriate environment variables, so that Perl
 612 starts using our newly generated lib/ directory. If you are using bash or
 613 any other Bourne shells, you can add this to your shell startup script this
 614 way:
 615
 616   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 617
 618 If you are using C shell, you can do this as follows:
 619
 620   /bin/csh
 621   echo $SHELL
 622   /bin/csh
 623   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 624
 625 If you passed to bootstrap a directory other than default, you also need to give that as
 626 import parameter to the call of the local::lib module like this way:
 627
 628   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 629
 630 After writing your shell configuration file, be sure to re-read it to get the
 631 changed settings into your current shell's environment. Bourne shells use
 632 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 633
 634 If you're on a slower machine, or are operating under draconian disk space
 635 limitations, you can disable the automatic generation of manpages from POD when
 636 installing modules by using the C<--no-manpages> argument when bootstrapping:
 637
 638   perl Makefile.PL --bootstrap --no-manpages
 639
 640 To avoid doing several bootstrap for several Perl module environments on the
 641 same account, for example if you use it for several different deployed
 642 applications independently, you can use one bootstrapped local::lib
 643 installation to install modules in different directories directly this way:
 644
 645   cd ~/mydir1
 646   perl -Mlocal::lib=./
 647   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 648   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 649   perl -MCPAN -e install ...    ### whatever modules you want
 650   cd ../mydir2
 651   ... REPEAT ...
 652
 653 If you are working with several C<local::lib> environments, you may want to
 654 remove some of them from the current environment without disturbing the others.
 655 You can deactivate one environment like this (using bourne sh):
 656
 657   eval $(perl -Mlocal::lib=--deactivate,~/path)
 658
 659 which will generate and run the commands needed to remove C<~/path> from your
 660 various search paths. Whichever environment was B<activated most recently> will
 661 remain the target for module installations. That is, if you activate
 662 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 663 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 664 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 665 installed in C<~/pathB> because pathB was activated later.
 666
 667 You can also ask C<local::lib> to clean itself completely out of the current
 668 shell's environment with the C<--deactivate-all> option.
 669 For multiple environments for multiple apps you may need to include a modified
 670 version of the C<< use FindBin >> instructions in the "In code" sample above.
 671 If you did something like the above, you have a set of Perl modules at C<<
 672 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 673 you need to tell it where to find the modules you installed for it at C<<
 674 ~/mydir1/lib >>.
 675
 676 In C<< ~/mydir1/scripts/myscript.pl >>:
 677
 678   use strict;
 679   use warnings;
 680   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 681   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 682
 683 Put this before any BEGIN { ... } blocks that require the modules you installed.
 684
 685 =head2 Differences when using this module under Win32
 686
 687 To set up the proper environment variables for your current session of
 688 C<CMD.exe>, you can use this:
 689
 690   C:\>perl -Mlocal::lib
 691   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 692   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 693   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread
 694   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 695
 696   ### To set the environment for this shell alone
 697   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 698   ### instead of $(perl -Mlocal::lib=./)
 699
 700 If you want the environment entries to persist, you'll need to add then to the
 701 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 702
 703 The "~" is translated to the user's profile directory (the directory named for
 704 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 705 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 706 directory is translated to a short name (which means the directory must exist)
 707 and the subdirectories are created.
 708
 709 =head1 RATIONALE
 710
 711 The version of a Perl package on your machine is not always the version you
 712 need.  Obviously, the best thing to do would be to update to the version you
 713 need.  However, you might be in a situation where you're prevented from doing
 714 this.  Perhaps you don't have system administrator privileges; or perhaps you
 715 are using a package management system such as Debian, and nobody has yet gotten
 716 around to packaging up the version you need.
 717
 718 local::lib solves this problem by allowing you to create your own directory of
 719 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 720 be within your own home directory).  The existing system Perl installation is
 721 not affected; you simply invoke Perl with special options so that Perl uses the
 722 packages in your own local package directory rather than the system packages.
 723 local::lib arranges things so that your locally installed version of the Perl
 724 packages takes precedence over the system installation.
 725
 726 If you are using a package management system (such as Debian), you don't need to
 727 worry about Debian and CPAN stepping on each other's toes.  Your local version
 728 of the packages will be written to an entirely separate directory from those
 729 installed by Debian.
 730
 731 =head1 DESCRIPTION
 732
 733 This module provides a quick, convenient way of bootstrapping a user-local Perl
 734 module library located within the user's home directory. It also constructs and
 735 prints out for the user the list of environment variables using the syntax
 736 appropriate for the user's current shell (as specified by the C<SHELL>
 737 environment variable), suitable for directly adding to one's shell
 738 configuration file.
 739
 740 More generally, local::lib allows for the bootstrapping and usage of a
 741 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 742 easier to ship an application with an app-specific copy of a Perl module, or
 743 collection of modules. Useful in cases like when an upstream maintainer hasn't
 744 applied a patch to a module of theirs that you need for your application.
 745
 746 On import, local::lib sets the following environment variables to appropriate
 747 values:
 748
 749 =over 4
 750
 751 =item PERL_MB_OPT
 752
 753 =item PERL_MM_OPT
 754
 755 =item PERL5LIB
 756
 757 =item PATH
 758
 759 PATH is appended to, rather than clobbered.
 760
 761 =back
 762
 763 These values are then available for reference by any code after import.
 764
 765 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 766
 767 See L<lib::core::only> for one way to do this - but note that
 768 there are a number of caveats, and the best approach is always to perform a
 769 build against a clean perl (i.e. site and vendor as close to empty as possible).
 770
 771 =head1 OPTIONS
 772
 773 Options are values that can be passed to the C<local::lib> import besides the
 774 directory to use. They are specified as C<use local::lib '--option'[, path];>
 775 or C<perl -Mlocal::lib=--option[,path]>.
 776
 777 =head2 --deactivate
 778
 779 Remove the chosen path (or the default path) from the module search paths if it
 780 was added by C<local::lib>, instead of adding it.
 781
 782 =head2 --deactivate-all
 783
 784 Remove all directories that were added to search paths by C<local::lib> from the
 785 search paths.
 786
 787 =head1 METHODS
 788
 789 =head2 ensure_dir_structure_for
 790
 791 =over 4
 792
 793 =item Arguments: $path
 794
 795 =item Return value: None
 796
 797 =back
 798
 799 Attempts to create the given path, and all required parent directories. Throws
 800 an exception on failure.
 801
 802 =head2 print_environment_vars_for
 803
 804 =over 4
 805
 806 =item Arguments: $path
 807
 808 =item Return value: None
 809
 810 =back
 811
 812 Prints to standard output the variables listed above, properly set to use the
 813 given path as the base directory.
 814
 815 =head2 build_environment_vars_for
 816
 817 =over 4
 818
 819 =item Arguments: $path, $interpolate
 820
 821 =item Return value: \%environment_vars
 822
 823 =back
 824
 825 Returns a hash with the variables listed above, properly set to use the
 826 given path as the base directory.
 827
 828 =head2 setup_env_hash_for
 829
 830 =over 4
 831
 832 =item Arguments: $path
 833
 834 =item Return value: None
 835
 836 =back
 837
 838 Constructs the C<%ENV> keys for the given path, by calling
 839 L</build_environment_vars_for>.
 840
 841 =head2 active_paths
 842
 843 =over 4
 844
 845 =item Arguments: None
 846
 847 =item Return value: @paths
 848
 849 =back
 850
 851 Returns a list of active C<local::lib> paths, according to the
 852 C<PERL_LOCAL_LIB_ROOT> environment variable.
 853
 854 =head2 install_base_perl_path
 855
 856 =over 4
 857
 858 =item Arguments: $path
 859
 860 =item Return value: $install_base_perl_path
 861
 862 =back
 863
 864 Returns a path describing where to install the Perl modules for this local
 865 library installation. Appends the directories C<lib> and C<perl5> to the given
 866 path.
 867
 868 =head2 install_base_arch_path
 869
 870 =over 4
 871
 872 =item Arguments: $path
 873
 874 =item Return value: $install_base_arch_path
 875
 876 =back
 877
 878 Returns a path describing where to install the architecture-specific Perl
 879 modules for this local library installation. Based on the
 880 L</install_base_perl_path> method's return value, and appends the value of
 881 C<$Config{archname}>.
 882
 883 =head2 install_base_bin_path
 884
 885 =over 4
 886
 887 =item Arguments: $path
 888
 889 =item Return value: $install_base_bin_path
 890
 891 =back
 892
 893 Returns a path describing where to install the executable programs for this
 894 local library installation. Based on the L</install_base_perl_path> method's
 895 return value, and appends the directory C<bin>.
 896
 897 =head2 resolve_empty_path
 898
 899 =over 4
 900
 901 =item Arguments: $path
 902
 903 =item Return value: $base_path
 904
 905 =back
 906
 907 Builds and returns the base path into which to set up the local module
 908 installation. Defaults to C<~/perl5>.
 909
 910 =head2 resolve_home_path
 911
 912 =over 4
 913
 914 =item Arguments: $path
 915
 916 =item Return value: $home_path
 917
 918 =back
 919
 920 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 921 for this purpose. If no definite answer is available, throws an exception.
 922
 923 =head2 resolve_relative_path
 924
 925 =over 4
 926
 927 =item Arguments: $path
 928
 929 =item Return value: $absolute_path
 930
 931 =back
 932
 933 Translates the given path into an absolute path.
 934
 935 =head2 resolve_path
 936
 937 =over 4
 938
 939 =item Arguments: $path
 940
 941 =item Return value: $absolute_path
 942
 943 =back
 944
 945 Calls the following in a pipeline, passing the result from the previous to the
 946 next, in an attempt to find where to configure the environment for a local
 947 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 948 L</resolve_relative_path>. Passes the given path argument to
 949 L</resolve_empty_path> which then returns a result that is passed to
 950 L</resolve_home_path>, which then has its result passed to
 951 L</resolve_relative_path>. The result of this final call is returned from
 952 L</resolve_path>.
 953
 954 =head1 A WARNING ABOUT UNINST=1
 955
 956 Be careful about using local::lib in combination with "make install UNINST=1".
 957 The idea of this feature is that will uninstall an old version of a module
 958 before installing a new one. However it lacks a safety check that the old
 959 version and the new version will go in the same directory. Used in combination
 960 with local::lib, you can potentially delete a globally accessible version of a
 961 module while installing the new version in a local place. Only combine "make
 962 install UNINST=1" and local::lib if you understand these possible consequences.
 963
 964 =head1 LIMITATIONS
 965
 966 The perl toolchain is unable to handle directory names with spaces in it,
 967 so you cant put your local::lib bootstrap into a directory with spaces. What
 968 you can do is moving your local::lib to a directory with spaces B<after> you
 969 installed all modules inside your local::lib bootstrap. But be aware that you
 970 cant update or install CPAN modules after the move.
 971
 972 Rather basic shell detection. Right now anything with csh in its name is
 973 assumed to be a C shell or something compatible, and everything else is assumed
 974 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 975 not set, a Bourne-compatible shell is assumed.
 976
 977 Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you
 978 have CPANPLUS installed.
 979
 980 Kills any existing PERL5LIB, PERL_MM_OPT or PERL_MB_OPT.
 981
 982 Should probably auto-fixup CPAN config if not already done.
 983
 984 Patches very much welcome for any of the above.
 985
 986 On Win32 systems, does not have a way to write the created environment variables
 987 to the registry, so that they can persist through a reboot.
 988
 989 =head1 TROUBLESHOOTING
 990
 991 If you've configured local::lib to install CPAN modules somewhere in to your
 992 home directory, and at some point later you try to install a module with C<cpan
 993 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
 994 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
 995 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
 996 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
 997 you've somehow lost your updated ExtUtils::MakeMaker module.
 998
 999 To remedy this situation, rerun the bootstrapping procedure documented above.
1000
1001 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1002
1003 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1004
1005 =head1 ENVIRONMENT
1006
1007 =over 4
1008
1009 =item SHELL
1010
1011 =item COMSPEC
1012
1013 local::lib looks at the user's C<SHELL> environment variable when printing out
1014 commands to add to the shell configuration file.
1015
1016 On Win32 systems, C<COMSPEC> is also examined.
1017
1018 =back
1019
1020 =head1 SUPPORT
1021
1022 IRC:
1023
1024     Join #local-lib on irc.perl.org.
1025
1026 =head1 AUTHOR
1027
1028 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1029
1030 auto_install fixes kindly sponsored by http://www.takkle.com/
1031
1032 =head1 CONTRIBUTORS
1033
1034 Patches to correctly output commands for csh style shells, as well as some
1035 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1036
1037 Doc patches for a custom local::lib directory, more cleanups in the english
1038 documentation and a L<german documentation|POD2::DE::local::lib> contributed by Torsten Raudssus
1039 <torsten@raudssus.de>.
1040
1041 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1042 things will install properly, submitted a fix for the bug causing problems with
1043 writing Makefiles during bootstrapping, contributed an example program, and
1044 submitted yet another fix to ensure that local::lib can install and bootstrap
1045 properly. Many, many thanks!
1046
1047 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1048 section. Many thanks!
1049
1050 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1051
1052 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1053 by a patch from Marco Emilio Poleggi.
1054
1055 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1056 '--self-contained' option.
1057
1058 Documentation patches to make win32 usage clearer by
1059 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1060
1061 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc patches contributed by Breno
1062 G. de Oliveira <garu@cpan.org>.
1063
1064 Improvements to stacking multiple local::lib dirs and removing them from the
1065 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1066
1067 Patch for Carp version mismatch contributed by Hakim Cassimally <osfameron@cpan.org>.
1068
1069 =head1 COPYRIGHT
1070
1071 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1072 listed above.
1073
1074 =head1 LICENSE
1075
1076 This library is free software and may be distributed under the same terms
1077 as perl itself.
1078
1079 =cut
1080
1081 1;