lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '1.008026'; # 1.8.26
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19
  20   while (@args) {
  21     my $arg = shift @args;
  22     # check for lethal dash first to stop processing before causing problems
  23     # the fancy dash is U+2212 or \xE2\x88\x92
  24     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  25       die <<'DEATH';
  26 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  27 These are *not* the traditional -- dashes that software recognizes. You
  28 probably got these by copy-pasting from the perldoc for this module as
  29 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  30 terminal, but can happen elsewhere too. Please try again after replacing the
  31 dashes with normal minus signs.
  32 DEATH
  33     }
  34     elsif ($arg eq '--self-contained') {
  35       die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  36     }
  37     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  38       my $path = defined $1 ? $1 : shift @args;
  39       push @steps, ['deactivate', $path];
  40     }
  41     elsif ( $arg eq '--deactivate-all' ) {
  42       push @steps, ['deactivate_all'];
  43     }
  44     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  45       my $shell = defined $1 ? $1 : shift @args;
  46       $opts{shelltype} = $shell;
  47     }
  48     elsif ( $arg eq '--no-create' ) {
  49       $opts{no_create} = 1;
  50     }
  51     elsif ( $arg =~ /^--/ ) {
  52       die "Unknown import argument: $arg";
  53     }
  54     else {
  55       push @steps, ['activate', $arg];
  56     }
  57   }
  58   if (!@steps) {
  59     push @steps, ['activate', undef];
  60   }
  61
  62   my $self = $class->new(%opts);
  63
  64   for (@steps) {
  65     my ($method, @args) = @$_;
  66     $self = $self->$method(@args);
  67   }
  68
  69   if ($0 eq '-') {
  70     $self->print_environment_vars;
  71     exit 0;
  72   }
  73   else {
  74     $self->setup_local_lib;
  75   }
  76 }
  77
  78 sub new {
  79   my $class = shift;
  80   bless {@_}, $class;
  81 }
  82
  83 sub clone {
  84   my $self = shift;
  85   bless {%$self, @_}, ref $self;
  86 }
  87
  88 sub inc { $_[0]->{inc}     ||= \@INC }
  89 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
  90 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
  91 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
  92 sub extra { $_[0]->{extra} ||= {} }
  93 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
  94 sub no_create { $_[0]->{no_create} }
  95
  96 my $_archname = $Config{archname};
  97 my $_version  = $Config{version};
  98 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
  99 my $_path_sep = $Config{path_sep};
 100
 101 sub _as_list {
 102   my $list = shift;
 103   grep length, map {
 104     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 105       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 106                         : ()
 107     )
 108   } ref $list ? @$list : $list;
 109 }
 110 sub _remove_from {
 111   my ($list, @remove) = @_;
 112   return @$list
 113     if !@remove;
 114   my %remove = map { $_ => 1 } @remove;
 115   grep !$remove{$_}, _as_list($list);
 116 }
 117
 118 my @_lib_subdirs = (
 119   [$_version, $_archname],
 120   [$_version],
 121   [$_archname],
 122   (@_inc_version_list ? \@_inc_version_list : ()),
 123   [],
 124 );
 125
 126 sub install_base_bin_path {
 127   my ($class, $path) = @_;
 128   return File::Spec->catdir($path, 'bin');
 129 }
 130 sub install_base_perl_path {
 131   my ($class, $path) = @_;
 132   return File::Spec->catdir($path, 'lib', 'perl5');
 133 }
 134 sub install_base_arch_path {
 135   my ($class, $path) = @_;
 136   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 137 }
 138
 139 sub lib_paths_for {
 140   my ($class, $path) = @_;
 141   my $base = $class->install_base_perl_path($path);
 142   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 143 }
 144
 145 sub _mm_escape_path {
 146   my $path = shift;
 147   $path =~ s/\\/\\\\\\\\/g;
 148   if ($path =~ s/ /\\ /g) {
 149     $path = qq{"\\"$path\\""};
 150   }
 151   return $path;
 152 }
 153
 154 sub _mb_escape_path {
 155   my $path = shift;
 156   $path =~ s/\\/\\\\/g;
 157   return qq{"$path"};
 158 }
 159
 160 sub installer_options_for {
 161   my ($class, $path) = @_;
 162   return {
 163     PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 164     PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef,
 165   };
 166 }
 167
 168 sub active_paths {
 169   my ($self) = @_;
 170   $self = ref $self ? $self : $self->new;
 171
 172   return grep {
 173     # screen out entries that aren't actually reflected in @INC
 174     my $active_ll = $self->install_base_perl_path($_);
 175     grep { $_ eq $active_ll } @{$self->inc};
 176   } _as_list($self->roots);
 177 }
 178
 179
 180 sub deactivate {
 181   my ($self, $path) = @_;
 182   $self = $self->new unless ref $self;
 183   $path = $self->resolve_path($path);
 184   $path = $self->normalize_path($path);
 185
 186   my @active_lls = $self->active_paths;
 187
 188   if (!grep { $_ eq $path } @active_lls) {
 189     warn "Tried to deactivate inactive local::lib '$path'\n";
 190     return $self;
 191   }
 192
 193   my %args = (
 194     bins  => [ _remove_from($self->bins,  $self->install_base_bin_path($path)) ],
 195     libs  => [ _remove_from($self->libs,  $self->install_base_perl_path($path)) ],
 196     inc   => [ _remove_from($self->inc,   $self->lib_paths_for($path)) ],
 197     roots => [ _remove_from($self->roots, $path) ],
 198   );
 199
 200   $args{extra} = $self->installer_options_for($args{roots}[0]);
 201
 202   $self->clone(%args);
 203 }
 204
 205 sub deactivate_all {
 206   my ($self) = @_;
 207   $self = $self->new unless ref $self;
 208
 209   my @active_lls = $self->active_paths;
 210
 211   my %args;
 212   if (@active_lls) {
 213     %args = (
 214       bins => [ _remove_from($self->bins,
 215         map $self->install_base_bin_path($_), @active_lls) ],
 216       libs => [ _remove_from($self->libs,
 217         map $self->install_base_perl_path($_), @active_lls) ],
 218       inc => [ _remove_from($self->inc,
 219         map $self->lib_paths_for($_), @active_lls) ],
 220       roots => [ _remove_from($self->roots, @active_lls) ],
 221     );
 222   }
 223
 224   $args{extra} = $self->installer_options_for(undef);
 225
 226   $self->clone(%args);
 227 }
 228
 229 sub activate {
 230   my ($self, $path) = @_;
 231   $self = $self->new unless ref $self;
 232   $path = $self->resolve_path($path);
 233   $self->ensure_dir_structure_for($path)
 234     unless $self->no_create;
 235
 236   $path = $self->normalize_path($path);
 237
 238   my @active_lls = $self->active_paths;
 239
 240   if (grep { $_ eq $path } @active_lls[1 .. $#active_lls]) {
 241     $self = $self->deactivate($path);
 242   }
 243
 244   my %args;
 245   if (!@active_lls || $active_lls[0] ne $path) {
 246     %args = (
 247       bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 248       libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 249       inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 250       roots => [ $path, @{$self->roots} ],
 251     );
 252   }
 253
 254   $args{extra} = $self->installer_options_for($path);
 255
 256   $self->clone(%args);
 257 }
 258
 259 sub normalize_path {
 260   my ($self, $path) = @_;
 261   $path = ( Win32::GetShortPathName($path) || $path )
 262     if $^O eq 'MSWin32';
 263   return $path;
 264 }
 265
 266 sub build_environment_vars_for {
 267   my $self = $_[0]->new->activate($_[1]);
 268   $self->build_environment_vars;
 269 }
 270 sub build_environment_vars {
 271   my $self = shift;
 272   (
 273     PATH                => join($_path_sep, _as_list($self->bins)),
 274     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 275     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 276     %{$self->extra},
 277   );
 278 }
 279
 280 sub setup_local_lib_for {
 281   my $self = $_[0]->new->activate($_[1]);
 282   $self->setup_local_lib;
 283 }
 284
 285 sub setup_local_lib {
 286   my $self = shift;
 287   $self->setup_env_hash;
 288   @INC = @{$self->inc};
 289 }
 290
 291 sub setup_env_hash_for {
 292   my $self = $_[0]->new->activate($_[1]);
 293   $self->setup_env_hash;
 294 }
 295 sub setup_env_hash {
 296   my $self = shift;
 297   my %env = $self->build_environment_vars;
 298   for my $key (keys %env) {
 299     if (defined $env{$key}) {
 300       $ENV{$key} = $env{$key};
 301     }
 302     else {
 303       delete $ENV{$key};
 304     }
 305   }
 306 }
 307
 308 sub print_environment_vars_for {
 309   my $self = $_[0]->new->activate($_[1]);
 310   $self->print_environment_vars;
 311 }
 312 sub print_environment_vars {
 313   my $self = shift;
 314   print $self->environment_vars_string;
 315 }
 316
 317 sub environment_vars_string_for {
 318   my $self = $_[0]->new->activate($_[1]);
 319   $self->environment_vars_string;
 320 }
 321 sub environment_vars_string {
 322   my $self = shift;
 323
 324   my $build_method = 'build_' . $self->shelltype . '_env_declaration';
 325
 326   my @envs = (
 327     PATH                => $self->bins,
 328     PERL5LIB            => $self->libs,
 329     PERL_LOCAL_LIB_ROOT => $self->roots,
 330     %{$self->extra},
 331   );
 332   my $out = '';
 333   while (@envs) {
 334     my ($name, $value) = (shift(@envs), shift(@envs));
 335     if (
 336         ref $value
 337         && @$value == 1
 338         && ref $value->[0]
 339         && ref $value->[0] eq 'SCALAR'
 340         && ${$value->[0]} eq $name) {
 341       next;
 342     }
 343     if (
 344         !ref $value
 345         and defined $value
 346           ? (defined $ENV{$name} && $value eq $ENV{$name})
 347           : !defined $ENV{$name}
 348     ) {
 349       next;
 350     }
 351     $out .= $self->$build_method($name, $value);
 352   }
 353   my $wrap_method = 'wrap_' . $self->shelltype . '_output';
 354   if ($self->can($wrap_method)) {
 355     return $self->$wrap_method($out);
 356   }
 357   return $out;
 358 }
 359
 360 sub build_bourne_env_declaration {
 361   my ($class, $name, $args) = @_;
 362   my $value = $class->_interpolate($args, '$%s', '"', '\\%s');
 363
 364   if (!defined $value) {
 365     return qq{unset $name;\n};
 366   }
 367
 368   $value =~ s/(^|\G|$_path_sep)\$$name$_path_sep/$1\$$name\${$name+$_path_sep}/g;
 369   $value =~ s/$_path_sep\$$name$/\${$name+$_path_sep}\$$name/;
 370
 371   qq{export ${name}="$value";\n}
 372 }
 373
 374 sub build_csh_env_declaration {
 375   my ($class, $name, $args) = @_;
 376   my ($value, @vars) = $class->_interpolate($args, '$%s', '"', '"\\%s"');
 377   if (!defined $value) {
 378     return qq{unsetenv $name;\n};
 379   }
 380
 381   my $out = '';
 382   for my $var (@vars) {
 383     $out .= qq{if ! \$?$name setenv $name '';\n};
 384   }
 385
 386   my $value_without = $value;
 387   if ($value_without =~ s/(?:^|$_path_sep)\$$name(?:$_path_sep|$)//g) {
 388     $out .= qq{if "\$$name" != '' setenv $name "$value";\n};
 389     $out .= qq{if "\$$name" == '' };
 390   }
 391   $out .= qq{setenv $name "$value_without";\n};
 392   return $out;
 393 }
 394
 395 sub build_cmd_env_declaration {
 396   my ($class, $name, $args) = @_;
 397   my $value = $class->_interpolate($args, '%%%s%%', qr([()!^"<>&|]), '^%s');
 398   if (!$value) {
 399     return qq{\@set $name=\n};
 400   }
 401
 402   my $out = '';
 403   my $value_without = $value;
 404   if ($value_without =~ s/(?:^|$_path_sep)%$name%(?:$_path_sep|$)//g) {
 405     $out .= qq{\@if not "%$name%"=="" set $name=$value\n};
 406     $out .= qq{\@if "%$name%"=="" };
 407   }
 408   $out .= qq{\@set $name=$value_without\n};
 409   return $out;
 410 }
 411
 412 sub build_powershell_env_declaration {
 413   my ($class, $name, $args) = @_;
 414   my $value = $class->_interpolate($args, '$env:%s', '"', '`%s');
 415
 416   if (!$value) {
 417     return qq{Remove-Item Env:\\$name;\n};
 418   }
 419
 420   my $maybe_path_sep = qq{\$(if("\$env:$name"-eq""){""}else{"$_path_sep"})};
 421   $value =~ s/(^|\G|$_path_sep)\$env:$name$_path_sep/$1\$env:$name"+$maybe_path_sep+"/g;
 422   $value =~ s/$_path_sep\$env:$name$/"+$maybe_path_sep+\$env:$name+"/;
 423
 424   qq{\$env:$name = \$("$value");\n};
 425 }
 426 sub wrap_powershell_output {
 427   my ($class, $out) = @_;
 428   return $out || " \n";
 429 }
 430
 431 sub _interpolate {
 432   my ($class, $args, $var_pat, $escape, $escape_pat) = @_;
 433   return
 434     unless defined $args;
 435   my @args = ref $args ? @$args : $args;
 436   return
 437     unless @args;
 438   my @vars = map { $$_ } grep { ref $_ eq 'SCALAR' } @args;
 439   my $string = join $_path_sep, map {
 440     ref $_ eq 'SCALAR' ? sprintf($var_pat, $$_) : do {
 441       s/($escape)/sprintf($escape_pat, $1)/ge; $_;
 442     };
 443   } @args;
 444   return wantarray ? ($string, \@vars) : $string;
 445 }
 446
 447 sub pipeline;
 448
 449 sub pipeline {
 450   my @methods = @_;
 451   my $last = pop(@methods);
 452   if (@methods) {
 453     \sub {
 454       my ($obj, @args) = @_;
 455       $obj->${pipeline @methods}(
 456         $obj->$last(@args)
 457       );
 458     };
 459   } else {
 460     \sub {
 461       shift->$last(@_);
 462     };
 463   }
 464 }
 465
 466 =begin testing
 467
 468 #:: test pipeline
 469
 470 package local::lib;
 471
 472 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 473 my $foo = bless({}, 'Foo');
 474 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 475
 476 =end testing
 477
 478 =cut
 479
 480 sub resolve_path {
 481   my ($class, $path) = @_;
 482
 483   $path = $class->${pipeline qw(
 484     resolve_relative_path
 485     resolve_home_path
 486     resolve_empty_path
 487   )}($path);
 488
 489   $path;
 490 }
 491
 492 sub resolve_empty_path {
 493   my ($class, $path) = @_;
 494   if (defined $path) {
 495     $path;
 496   } else {
 497     '~/perl5';
 498   }
 499 }
 500
 501 =begin testing
 502
 503 #:: test classmethod setup
 504
 505 my $c = 'local::lib';
 506
 507 =end testing
 508
 509 =begin testing
 510
 511 #:: test classmethod
 512
 513 is($c->resolve_empty_path, '~/perl5');
 514 is($c->resolve_empty_path('foo'), 'foo');
 515
 516 =end testing
 517
 518 =cut
 519
 520 sub resolve_home_path {
 521   my ($class, $path) = @_;
 522   return $path unless ($path =~ /^~/);
 523   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 524   my $homedir = do {
 525     if (!defined $user && defined $ENV{HOME}) {
 526       $ENV{HOME}
 527     }
 528     else {
 529       require File::Glob;
 530       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 531     }
 532   };
 533   unless (defined $homedir) {
 534     require Carp;
 535     Carp::croak(
 536       "Couldn't resolve homedir for "
 537       .(defined $user ? $user : 'current user')
 538     );
 539   }
 540   $path =~ s/^~[^\/]*/$homedir/;
 541   $path;
 542 }
 543
 544 sub resolve_relative_path {
 545   my ($class, $path) = @_;
 546   $path = File::Spec->rel2abs($path);
 547 }
 548
 549 =begin testing
 550
 551 #:: test classmethod
 552
 553 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 554 is($c->resolve_relative_path('bar'),'FOObar');
 555
 556 =end testing
 557
 558 =cut
 559
 560 sub ensure_dir_structure_for {
 561   my ($class, $path) = @_;
 562   unless (-d $path) {
 563     warn "Attempting to create directory ${path}\n";
 564   }
 565   require File::Basename;
 566   my @dirs;
 567   while(!-d $path) {
 568     push @dirs, $path;
 569     $path = File::Basename::dirname($path);
 570   }
 571   mkdir $_ for reverse @dirs;
 572   return;
 573 }
 574
 575 =begin testing
 576
 577 #:: test classmethod
 578
 579 File::Path::rmtree('t/var/splat');
 580
 581 $c->ensure_dir_structure_for('t/var/splat');
 582
 583 ok(-d 't/var/splat');
 584
 585 =end testing
 586
 587 =cut
 588
 589 sub guess_shelltype {
 590   my $shellbin
 591     = defined $ENV{SHELL}
 592       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 593     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 594       ? 'bash'
 595     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 596       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 597     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 598       ? 'powershell.exe'
 599     : 'sh';
 600
 601   for ($shellbin) {
 602     return
 603         /csh/              ? 'csh'
 604       : /command\.com/i    ? 'cmd'
 605       : /cmd\.exe/i        ? 'cmd'
 606       : /4nt\.exe/i        ? 'cmd'
 607       : /powershell\.exe/i ? 'powershell'
 608                            : 'bourne';
 609   }
 610 }
 611
 612 1;
 613 __END__
 614
 615 =encoding utf8
 616
 617 =head1 NAME
 618
 619 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 620
 621 =head1 SYNOPSIS
 622
 623 In code -
 624
 625   use local::lib; # sets up a local lib at ~/perl5
 626
 627   use local::lib '~/foo'; # same, but ~/foo
 628
 629   # Or...
 630   use FindBin;
 631   use local::lib "$FindBin::Bin/../support";  # app-local support library
 632
 633 From the shell -
 634
 635   # Install LWP and its missing dependencies to the '~/perl5' directory
 636   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 637
 638   # Just print out useful shell commands
 639   $ perl -Mlocal::lib
 640   export PERL_MB_OPT='--install_base /home/username/perl5'
 641   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 642   export PERL5LIB="/home/username/perl5/lib/perl5"
 643   export PATH="/home/username/perl5/bin:$PATH"
 644
 645 =head2 The bootstrapping technique
 646
 647 A typical way to install local::lib is using what is known as the
 648 "bootstrapping" technique.  You would do this if your system administrator
 649 hasn't already installed local::lib.  In this case, you'll need to install
 650 local::lib in your home directory.
 651
 652 Even if you do have administrative privileges, you will still want to set up your
 653 environment variables, as discussed in step 4. Without this, you would still
 654 install the modules into the system CPAN installation and also your Perl scripts
 655 will not use the lib/ path you bootstrapped with local::lib.
 656
 657 By default local::lib installs itself and the CPAN modules into ~/perl5.
 658
 659 Windows users must also see L</Differences when using this module under Win32>.
 660
 661 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 662 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 663 or administrator.  Unpack the file in your home directory or in any other
 664 convenient location.
 665
 666 2. Run this:
 667
 668   perl Makefile.PL --bootstrap
 669
 670 If the system asks you whether it should automatically configure as much
 671 as possible, you would typically answer yes.
 672
 673 In order to install local::lib into a directory other than the default, you need
 674 to specify the name of the directory when you call bootstrap, as follows:
 675
 676   perl Makefile.PL --bootstrap=~/foo
 677
 678 3. Run this: (local::lib assumes you have make installed on your system)
 679
 680   make test && make install
 681
 682 4. Now we need to setup the appropriate environment variables, so that Perl
 683 starts using our newly generated lib/ directory. If you are using bash or
 684 any other Bourne shells, you can add this to your shell startup script this
 685 way:
 686
 687   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 688
 689 If you are using C shell, you can do this as follows:
 690
 691   /bin/csh
 692   echo $SHELL
 693   /bin/csh
 694   echo 'eval `perl -I$HOME/perl5/lib/perl5 -Mlocal::lib`' >> ~/.cshrc
 695
 696 If you passed to bootstrap a directory other than default, you also need to
 697 give that as import parameter to the call of the local::lib module like this
 698 way:
 699
 700   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 701
 702 After writing your shell configuration file, be sure to re-read it to get the
 703 changed settings into your current shell's environment. Bourne shells use
 704 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 705
 706 If you're on a slower machine, or are operating under draconian disk space
 707 limitations, you can disable the automatic generation of manpages from POD when
 708 installing modules by using the C<--no-manpages> argument when bootstrapping:
 709
 710   perl Makefile.PL --bootstrap --no-manpages
 711
 712 To avoid doing several bootstrap for several Perl module environments on the
 713 same account, for example if you use it for several different deployed
 714 applications independently, you can use one bootstrapped local::lib
 715 installation to install modules in different directories directly this way:
 716
 717   cd ~/mydir1
 718   perl -Mlocal::lib=./
 719   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 720   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 721   perl -MCPAN -e install ...    ### whatever modules you want
 722   cd ../mydir2
 723   ... REPEAT ...
 724
 725 If you are working with several C<local::lib> environments, you may want to
 726 remove some of them from the current environment without disturbing the others.
 727 You can deactivate one environment like this (using bourne sh):
 728
 729   eval $(perl -Mlocal::lib=--deactivate,~/path)
 730
 731 which will generate and run the commands needed to remove C<~/path> from your
 732 various search paths. Whichever environment was B<activated most recently> will
 733 remain the target for module installations. That is, if you activate
 734 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 735 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 736 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 737 installed in C<~/pathB> because pathB was activated later.
 738
 739 You can also ask C<local::lib> to clean itself completely out of the current
 740 shell's environment with the C<--deactivate-all> option.
 741 For multiple environments for multiple apps you may need to include a modified
 742 version of the C<< use FindBin >> instructions in the "In code" sample above.
 743 If you did something like the above, you have a set of Perl modules at C<<
 744 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 745 you need to tell it where to find the modules you installed for it at C<<
 746 ~/mydir1/lib >>.
 747
 748 In C<< ~/mydir1/scripts/myscript.pl >>:
 749
 750   use strict;
 751   use warnings;
 752   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 753   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 754
 755 Put this before any BEGIN { ... } blocks that require the modules you installed.
 756
 757 =head2 Differences when using this module under Win32
 758
 759 To set up the proper environment variables for your current session of
 760 C<CMD.exe>, you can use this:
 761
 762   C:\>perl -Mlocal::lib
 763   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 764   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 765   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 766   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 767
 768   ### To set the environment for this shell alone
 769   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 770   ### instead of $(perl -Mlocal::lib=./)
 771
 772 If you want the environment entries to persist, you'll need to add them to the
 773 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 774
 775 The "~" is translated to the user's profile directory (the directory named for
 776 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 777 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 778 directory is translated to a short name (which means the directory must exist)
 779 and the subdirectories are created.
 780
 781 =head3 PowerShell
 782
 783 local::lib also supports PowerShell, and an be used with the
 784 C<Invoke-Expression> cmdlet.
 785
 786   Invoke-Expression "$(perl -Mlocal::lib)"
 787
 788 =head1 RATIONALE
 789
 790 The version of a Perl package on your machine is not always the version you
 791 need.  Obviously, the best thing to do would be to update to the version you
 792 need.  However, you might be in a situation where you're prevented from doing
 793 this.  Perhaps you don't have system administrator privileges; or perhaps you
 794 are using a package management system such as Debian, and nobody has yet gotten
 795 around to packaging up the version you need.
 796
 797 local::lib solves this problem by allowing you to create your own directory of
 798 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 799 be within your own home directory).  The existing system Perl installation is
 800 not affected; you simply invoke Perl with special options so that Perl uses the
 801 packages in your own local package directory rather than the system packages.
 802 local::lib arranges things so that your locally installed version of the Perl
 803 packages takes precedence over the system installation.
 804
 805 If you are using a package management system (such as Debian), you don't need to
 806 worry about Debian and CPAN stepping on each other's toes.  Your local version
 807 of the packages will be written to an entirely separate directory from those
 808 installed by Debian.
 809
 810 =head1 DESCRIPTION
 811
 812 This module provides a quick, convenient way of bootstrapping a user-local Perl
 813 module library located within the user's home directory. It also constructs and
 814 prints out for the user the list of environment variables using the syntax
 815 appropriate for the user's current shell (as specified by the C<SHELL>
 816 environment variable), suitable for directly adding to one's shell
 817 configuration file.
 818
 819 More generally, local::lib allows for the bootstrapping and usage of a
 820 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 821 easier to ship an application with an app-specific copy of a Perl module, or
 822 collection of modules. Useful in cases like when an upstream maintainer hasn't
 823 applied a patch to a module of theirs that you need for your application.
 824
 825 On import, local::lib sets the following environment variables to appropriate
 826 values:
 827
 828 =over 4
 829
 830 =item PERL_MB_OPT
 831
 832 =item PERL_MM_OPT
 833
 834 =item PERL5LIB
 835
 836 =item PATH
 837
 838 =back
 839
 840 When possible, these will be appended to instead of overwritten entirely.
 841
 842 These values are then available for reference by any code after import.
 843
 844 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 845
 846 See L<lib::core::only> for one way to do this - but note that
 847 there are a number of caveats, and the best approach is always to perform a
 848 build against a clean perl (i.e. site and vendor as close to empty as possible).
 849
 850 =head1 OPTIONS
 851
 852 Options are values that can be passed to the C<local::lib> import besides the
 853 directory to use. They are specified as C<use local::lib '--option'[, path];>
 854 or C<perl -Mlocal::lib=--option[,path]>.
 855
 856 =head2 --deactivate
 857
 858 Remove the chosen path (or the default path) from the module search paths if it
 859 was added by C<local::lib>, instead of adding it.
 860
 861 =head2 --deactivate-all
 862
 863 Remove all directories that were added to search paths by C<local::lib> from the
 864 search paths.
 865
 866 =head2 --shelltype
 867
 868 Specify the shell type to use for output.  By default, the shell will be
 869 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 870 C<cmd>, or C<powershell>.
 871
 872 =head2 --no-create
 873
 874 Prevents C<local::lib> from creating directories when activating dirs.  This is
 875 likely to cause issues on Win32 systems.
 876
 877 =head1 METHODS
 878
 879 =head2 ensure_dir_structure_for
 880
 881 =over 4
 882
 883 =item Arguments: $path
 884
 885 =item Return value: None
 886
 887 =back
 888
 889 Attempts to create the given path, and all required parent directories. Throws
 890 an exception on failure.
 891
 892 =head2 print_environment_vars_for
 893
 894 =over 4
 895
 896 =item Arguments: $path
 897
 898 =item Return value: None
 899
 900 =back
 901
 902 Prints to standard output the variables listed above, properly set to use the
 903 given path as the base directory.
 904
 905 =head2 build_environment_vars_for
 906
 907 =over 4
 908
 909 =item Arguments: $path
 910
 911 =item Return value: %environment_vars
 912
 913 =back
 914
 915 Returns a hash with the variables listed above, properly set to use the
 916 given path as the base directory.
 917
 918 =head2 setup_env_hash_for
 919
 920 =over 4
 921
 922 =item Arguments: $path
 923
 924 =item Return value: None
 925
 926 =back
 927
 928 Constructs the C<%ENV> keys for the given path, by calling
 929 L</build_environment_vars_for>.
 930
 931 =head2 active_paths
 932
 933 =over 4
 934
 935 =item Arguments: None
 936
 937 =item Return value: @paths
 938
 939 =back
 940
 941 Returns a list of active C<local::lib> paths, according to the
 942 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 943 what is really in C<@INC>.
 944
 945 =head2 install_base_perl_path
 946
 947 =over 4
 948
 949 =item Arguments: $path
 950
 951 =item Return value: $install_base_perl_path
 952
 953 =back
 954
 955 Returns a path describing where to install the Perl modules for this local
 956 library installation. Appends the directories C<lib> and C<perl5> to the given
 957 path.
 958
 959 =head2 install_base_bin_path
 960
 961 =over 4
 962
 963 =item Arguments: $path
 964
 965 =item Return value: $install_base_bin_path
 966
 967 =back
 968
 969 Returns a path describing where to install the executable programs for this
 970 local library installation. Appends the directory C<bin> to the given path.
 971
 972 =head2 resolve_empty_path
 973
 974 =over 4
 975
 976 =item Arguments: $path
 977
 978 =item Return value: $base_path
 979
 980 =back
 981
 982 Builds and returns the base path into which to set up the local module
 983 installation. Defaults to C<~/perl5>.
 984
 985 =head2 resolve_home_path
 986
 987 =over 4
 988
 989 =item Arguments: $path
 990
 991 =item Return value: $home_path
 992
 993 =back
 994
 995 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 996 for this purpose. If no definite answer is available, throws an exception.
 997
 998 =head2 resolve_relative_path
 999
1000 =over 4
1001
1002 =item Arguments: $path
1003
1004 =item Return value: $absolute_path
1005
1006 =back
1007
1008 Translates the given path into an absolute path.
1009
1010 =head2 resolve_path
1011
1012 =over 4
1013
1014 =item Arguments: $path
1015
1016 =item Return value: $absolute_path
1017
1018 =back
1019
1020 Calls the following in a pipeline, passing the result from the previous to the
1021 next, in an attempt to find where to configure the environment for a local
1022 library installation: L</resolve_empty_path>, L</resolve_home_path>,
1023 L</resolve_relative_path>. Passes the given path argument to
1024 L</resolve_empty_path> which then returns a result that is passed to
1025 L</resolve_home_path>, which then has its result passed to
1026 L</resolve_relative_path>. The result of this final call is returned from
1027 L</resolve_path>.
1028
1029 =head1 A WARNING ABOUT UNINST=1
1030
1031 Be careful about using local::lib in combination with "make install UNINST=1".
1032 The idea of this feature is that will uninstall an old version of a module
1033 before installing a new one. However it lacks a safety check that the old
1034 version and the new version will go in the same directory. Used in combination
1035 with local::lib, you can potentially delete a globally accessible version of a
1036 module while installing the new version in a local place. Only combine "make
1037 install UNINST=1" and local::lib if you understand these possible consequences.
1038
1039 =head1 LIMITATIONS
1040
1041 =over 4
1042
1043 =item * Directory names with spaces in them are not well supported by the perl
1044 toolchain and the programs it uses.  Pure-perl distributions should support
1045 spaces, but problems are more likely with dists that require compilation. A
1046 workaround you can do is moving your local::lib to a directory with spaces
1047 B<after> you installed all modules inside your local::lib bootstrap. But be
1048 aware that you can't update or install CPAN modules after the move.
1049
1050 =item * Rather basic shell detection. Right now anything with csh in its name is
1051 assumed to be a C shell or something compatible, and everything else is assumed
1052 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
1053 not set, a Bourne-compatible shell is assumed.
1054
1055 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
1056
1057 =item * Should probably auto-fixup CPAN config if not already done.
1058
1059 =back
1060
1061 Patches very much welcome for any of the above.
1062
1063 =over 4
1064
1065 =item * On Win32 systems, does not have a way to write the created environment
1066 variables to the registry, so that they can persist through a reboot.
1067
1068 =back
1069
1070 =head1 TROUBLESHOOTING
1071
1072 If you've configured local::lib to install CPAN modules somewhere in to your
1073 home directory, and at some point later you try to install a module with C<cpan
1074 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1075 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1076 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1077 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1078 you've somehow lost your updated ExtUtils::MakeMaker module.
1079
1080 To remedy this situation, rerun the bootstrapping procedure documented above.
1081
1082 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1083
1084 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1085
1086 =head1 ENVIRONMENT
1087
1088 =over 4
1089
1090 =item SHELL
1091
1092 =item COMSPEC
1093
1094 local::lib looks at the user's C<SHELL> environment variable when printing out
1095 commands to add to the shell configuration file.
1096
1097 On Win32 systems, C<COMSPEC> is also examined.
1098
1099 =back
1100
1101 =head1 SEE ALSO
1102
1103 =over 4
1104
1105 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1106
1107 =back
1108
1109 =head1 SUPPORT
1110
1111 IRC:
1112
1113     Join #local-lib on irc.perl.org.
1114
1115 =head1 AUTHOR
1116
1117 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1118
1119 auto_install fixes kindly sponsored by http://www.takkle.com/
1120
1121 =head1 CONTRIBUTORS
1122
1123 Patches to correctly output commands for csh style shells, as well as some
1124 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1125
1126 Doc patches for a custom local::lib directory, more cleanups in the english
1127 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1128 Torsten Raudssus <torsten@raudssus.de>.
1129
1130 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1131 things will install properly, submitted a fix for the bug causing problems with
1132 writing Makefiles during bootstrapping, contributed an example program, and
1133 submitted yet another fix to ensure that local::lib can install and bootstrap
1134 properly. Many, many thanks!
1135
1136 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1137 section. Many thanks!
1138
1139 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1140
1141 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1142 by a patch from Marco Emilio Poleggi.
1143
1144 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1145 '--self-contained' option.
1146
1147 Documentation patches to make win32 usage clearer by
1148 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1149
1150 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1151 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1152
1153 Improvements to stacking multiple local::lib dirs and removing them from the
1154 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1155
1156 Patch for Carp version mismatch contributed by Hakim Cassimally
1157 <osfameron@cpan.org>.
1158
1159 =head1 COPYRIGHT
1160
1161 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1162 listed above.
1163
1164 =head1 LICENSE
1165
1166 This is free software; you can redistribute it and/or modify it under
1167 the same terms as the Perl 5 programming language system itself.
1168
1169 =cut