lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '1.008026'; # 1.8.26
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19
  20   while (@args) {
  21     my $arg = shift @args;
  22     # check for lethal dash first to stop processing before causing problems
  23     # the fancy dash is U+2212 or \xE2\x88\x92
  24     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  25       die <<'DEATH';
  26 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  27 These are *not* the traditional -- dashes that software recognizes. You
  28 probably got these by copy-pasting from the perldoc for this module as
  29 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  30 terminal, but can happen elsewhere too. Please try again after replacing the
  31 dashes with normal minus signs.
  32 DEATH
  33     }
  34     elsif ($arg eq '--self-contained') {
  35       die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  36     }
  37     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  38       my $path = defined $1 ? $1 : shift @args;
  39       push @steps, ['deactivate', $path];
  40     }
  41     elsif ( $arg eq '--deactivate-all' ) {
  42       push @steps, ['deactivate_all'];
  43     }
  44     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  45       my $shell = defined $1 ? $1 : shift @args;
  46       $opts{shelltype} = $shell;
  47     }
  48     elsif ( $arg =~ /^--/ ) {
  49       die "Unknown import argument: $arg";
  50     }
  51     else {
  52       push @steps, ['activate', $arg];
  53     }
  54   }
  55   if (!@steps) {
  56     push @steps, ['activate', undef];
  57   }
  58
  59   my $self = $class->new(%opts);
  60
  61   for (@steps) {
  62     my ($method, @args) = @$_;
  63     $self = $self->$method(@args);
  64   }
  65
  66   if ($0 eq '-') {
  67     $self->print_environment_vars_for;
  68     exit 0;
  69   }
  70   else {
  71     $self->setup_local_lib_for;
  72   }
  73 }
  74
  75 sub new {
  76   my $class = shift;
  77   bless {@_}, $class;
  78 }
  79
  80 sub clone {
  81   my $self = shift;
  82   bless {%$self, @_}, ref $self;
  83 }
  84
  85 sub inc { $_[0]->{inc}     ||= \@INC }
  86 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
  87 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
  88 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
  89 sub extra { $_[0]->{extra} ||= {} }
  90 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
  91
  92 my $_archname = $Config{archname};
  93 my $_version  = $Config{version};
  94 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
  95 my $_path_sep = $Config{path_sep};
  96
  97 sub _as_list {
  98   my $list = shift;
  99   grep length, map {
 100     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 101       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 102                         : ()
 103     )
 104   } ref $list ? @$list : $list;
 105 }
 106 sub _remove_from {
 107   my ($list, @remove) = @_;
 108   my %remove = map { $_ => 1 } @remove;
 109   grep !$remove{$_}, _as_list($list);
 110 }
 111
 112 my @_lib_subdirs = (
 113   [$_version, $_archname],
 114   [$_version],
 115   [$_archname],
 116   (@_inc_version_list ? \@_inc_version_list : ()),
 117   [],
 118 );
 119
 120 sub install_base_bin_path {
 121   my ($class, $path) = @_;
 122   return File::Spec->catdir($path, 'bin');
 123 }
 124 sub install_base_perl_path {
 125   my ($class, $path) = @_;
 126   return File::Spec->catdir($path, 'lib', 'perl5');
 127 }
 128 sub install_base_arch_path {
 129   my ($class, $path) = @_;
 130   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 131 }
 132
 133 sub lib_paths_for {
 134   my ($class, $path) = @_;
 135   my $base = $class->install_base_perl_path($path);
 136   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 137 }
 138
 139 sub _mm_escape_path {
 140   my $path = shift;
 141   $path =~ s/\\/\\\\\\\\/g;
 142   if ($path =~ s/ /\\ /g) {
 143     $path = qq{"\\"$path\\""};
 144   }
 145   return $path;
 146 }
 147
 148 sub _mb_escape_path {
 149   my $path = shift;
 150   $path =~ s/\\/\\\\/g;
 151   return qq{"$path"};
 152 }
 153
 154 sub installer_options_for {
 155   my ($class, $path) = @_;
 156   return {
 157     PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 158     PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef,
 159   };
 160 }
 161
 162 sub active_paths {
 163   my ($self) = @_;
 164   $self = ref $self ? $self : $self->new;
 165
 166   return grep {
 167     # screen out entries that aren't actually reflected in @INC
 168     my $active_ll = $self->install_base_perl_path($_);
 169     grep { $_ eq $active_ll } @{$self->inc};
 170   } _as_list($self->roots);
 171 }
 172
 173
 174 sub deactivate {
 175   my ($self, $path) = @_;
 176   $self = $self->new unless ref $self;
 177   $path = $self->resolve_path($path);
 178
 179   my @active_lls = $self->active_paths;
 180
 181   if (!grep { $_ eq $path } @active_lls) {
 182     warn "Tried to deactivate inactive local::lib '$path'\n";
 183     return;
 184   }
 185
 186   my %args = (
 187     bins  => [ _remove_from($self->bins,  $self->install_base_bin_path($path)) ],
 188     libs  => [ _remove_from($self->libs,  $self->install_base_perl_path($path)) ],
 189     inc   => [ _remove_from($self->inc,   $self->lib_paths_for($path)) ],
 190     roots => [ _remove_from($self->roots, $path) ],
 191   );
 192
 193   $args{extra} = $self->installer_options_for($args{roots}[0]);
 194
 195   $self->clone(%args);
 196 }
 197
 198 sub deactivate_all {
 199   my ($self) = @_;
 200   $self = $self->new unless ref $self;
 201
 202   my @active_lls = $self->active_paths;
 203
 204   my %args = (
 205     bins => [ _remove_from($self->bins,
 206       map $self->install_base_bin_path($_), @active_lls) ],
 207     libs => [ _remove_from($self->libs,
 208       map $self->install_base_perl_path($_), @active_lls) ],
 209     inc => [ _remove_from($self->inc,
 210       map $self->lib_paths_for($_), @active_lls) ],
 211     roots => [ _remove_from($self->roots, @active_lls) ],
 212   );
 213
 214   $args{extra} = $self->installer_options_for(undef);
 215
 216   $self->clone(%args);
 217 }
 218
 219 sub activate {
 220   my ($self, $path) = @_;
 221   $self = $self->new unless ref $self;
 222   $path = $self->resolve_path($path);
 223   $self->ensure_dir_structure_for($path);
 224
 225   my @active_lls = $self->active_paths;
 226
 227   if (grep { $_ eq $path } @active_lls) {
 228     $self = $self->deactivate($path);
 229   }
 230
 231   my %args = (
 232     bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 233     libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 234     inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 235     roots => [ $path, @{$self->roots} ],
 236   );
 237
 238   $args{extra} = $self->installer_options_for($path);
 239
 240   $self->clone(%args);
 241 }
 242
 243 sub _legacy {
 244   my ($self, $path) = @_;
 245   $self = $self->new unless ref $self;
 246   if (defined $path) {
 247     $self = $self->activate($path);
 248   }
 249   $self;
 250 }
 251
 252 sub build_environment_vars_for {
 253   my ($self) = _legacy(@_);
 254   (
 255     PATH                => join($_path_sep, _as_list($self->bins)),
 256     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 257     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 258     %{$self->extra},
 259   );
 260 }
 261
 262 sub setup_local_lib_for {
 263   my ($self) = _legacy(@_);
 264   $self->setup_env_hash_for;
 265   @INC = @{$self->inc};
 266 }
 267
 268 sub setup_env_hash_for {
 269   my $self = shift;
 270   my %env = $self->build_environment_vars_for(@_);
 271   for my $key (keys %env) {
 272     if (defined $env{$key}) {
 273       $ENV{$key} = $env{$key};
 274     }
 275     else {
 276       delete $ENV{$key};
 277     }
 278   }
 279 }
 280
 281 sub print_environment_vars_for {
 282   my $self = shift;
 283   print $self->environment_vars_string_for(@_);
 284 }
 285
 286 sub environment_vars_string_for {
 287   my $self = _legacy(@_);
 288
 289   my $build_method = 'build_' . $self->shelltype . '_env_declaration';
 290
 291   my @envs = (
 292     PATH                => $self->bins,
 293     PERL5LIB            => $self->libs,
 294     PERL_LOCAL_LIB_ROOT => $self->roots,
 295     %{$self->extra},
 296   );
 297   my $out = '';
 298   while (@envs) {
 299     my ($name, $value) = (shift(@envs), shift(@envs));
 300     if (
 301         ref $value
 302         && @$value == 1
 303         && ref $value->[0]
 304         && ref $value->[0] eq 'SCALAR'
 305         && ${$value->[0]} eq $name) {
 306       next;
 307     }
 308     $out .= $self->$build_method($name, $value);
 309   }
 310   return $out;
 311 }
 312
 313 sub build_bourne_env_declaration {
 314   my ($class, $name, $args) = @_;
 315   my $value = $class->_interpolate($args);
 316   $value =~ s/"/\\"/g
 317     if defined $value;
 318   return defined($value) ? qq{export ${name}="${value}"\n} : qq{unset ${name}\n};
 319 }
 320 sub build_csh_env_declaration {
 321   my ($class, $name, $args) = @_;
 322   my ($value, @vars) = $class->_interpolate($args);
 323   @vars = grep { $_ ne $name || defined $value } @vars;
 324   $value =~ s/"/"\\""/g
 325     if defined $value;
 326   join '',
 327     (map qq{if ! \$?$_ setenv $_ "";\n}, @vars),
 328     (defined($value)
 329       ? qq{setenv $name "$value";\n}
 330       : qq{unsetenv $name;\n});
 331 }
 332 sub build_cmd_env_declaration {
 333   my ($class, $name, $args) = @_;
 334   my $value = $class->_interpolate($args, '%', '%');
 335   $value =~ s/"/\\"/g
 336     if defined $value;
 337   return qq{set $name=} . (defined($value) ? qq{"$value"} : '') . "\n";
 338 }
 339 sub build_powershell_env_declaration {
 340   my ($class, $name, $args) = @_;
 341   my $value = $class->_interpolate($args, '$env:');
 342   if (defined $value) {
 343     $value =~ s/"/\\"/g;
 344     return qq{\$env:$name = "$value"\n};
 345   }
 346   return "Remove-Item Env:\\$name\n";
 347 }
 348
 349
 350 sub _interpolate {
 351   my ($class, $args, $start, $end) = @_;
 352   return
 353     unless defined $args;
 354   return $args
 355     unless ref $args;
 356   return
 357     unless @$args;
 358   $start = '$' unless defined $start;
 359   $end = '' unless defined $end;
 360   my @vars;
 361   my $string = join($Config{path_sep}, map {
 362     (ref $_ && ref $_ eq 'SCALAR') ? do { push @vars, $$_; $start.$$_.$end }
 363       : $_
 364   } @$args);
 365   return wantarray ? ($string, @vars) : $string;
 366 }
 367
 368 sub pipeline;
 369
 370 sub pipeline {
 371   my @methods = @_;
 372   my $last = pop(@methods);
 373   if (@methods) {
 374     \sub {
 375       my ($obj, @args) = @_;
 376       $obj->${pipeline @methods}(
 377         $obj->$last(@args)
 378       );
 379     };
 380   } else {
 381     \sub {
 382       shift->$last(@_);
 383     };
 384   }
 385 }
 386
 387 =begin testing
 388
 389 #:: test pipeline
 390
 391 package local::lib;
 392
 393 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 394 my $foo = bless({}, 'Foo');
 395 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 396
 397 =end testing
 398
 399 =cut
 400
 401 sub resolve_path {
 402   my ($class, $path) = @_;
 403
 404   $path = $class->${pipeline qw(
 405     resolve_relative_path
 406     resolve_home_path
 407     resolve_empty_path
 408   )}($path);
 409
 410   $path = Win32::GetShortPathName($path)
 411     if $^O eq 'MSWin32';
 412
 413   $path;
 414 }
 415
 416 sub resolve_empty_path {
 417   my ($class, $path) = @_;
 418   if (defined $path) {
 419     $path;
 420   } else {
 421     '~/perl5';
 422   }
 423 }
 424
 425 =begin testing
 426
 427 #:: test classmethod setup
 428
 429 my $c = 'local::lib';
 430
 431 =end testing
 432
 433 =begin testing
 434
 435 #:: test classmethod
 436
 437 is($c->resolve_empty_path, '~/perl5');
 438 is($c->resolve_empty_path('foo'), 'foo');
 439
 440 =end testing
 441
 442 =cut
 443
 444 sub resolve_home_path {
 445   my ($class, $path) = @_;
 446   return $path unless ($path =~ /^~/);
 447   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 448   my $homedir = do {
 449     if (!defined $user && defined $ENV{HOME}) {
 450       $ENV{HOME}
 451     }
 452     else {
 453       require File::Glob;
 454       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 455     }
 456   };
 457   unless (defined $homedir) {
 458     require Carp;
 459     Carp::croak(
 460       "Couldn't resolve homedir for "
 461       .(defined $user ? $user : 'current user')
 462     );
 463   }
 464   $path =~ s/^~[^\/]*/$homedir/;
 465   $path;
 466 }
 467
 468 sub resolve_relative_path {
 469   my ($class, $path) = @_;
 470   $path = File::Spec->rel2abs($path);
 471 }
 472
 473 =begin testing
 474
 475 #:: test classmethod
 476
 477 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 478 is($c->resolve_relative_path('bar'),'FOObar');
 479
 480 =end testing
 481
 482 =cut
 483
 484 sub ensure_dir_structure_for {
 485   my ($class, $path) = @_;
 486   unless (-d $path) {
 487     warn "Attempting to create directory ${path}\n";
 488   }
 489   require File::Basename;
 490   my @dirs;
 491   while(!-d $path) {
 492     push @dirs, $path;
 493     $path = File::Basename::dirname($path);
 494   }
 495   mkdir $_ for reverse @dirs;
 496   return;
 497 }
 498
 499 =begin testing
 500
 501 #:: test classmethod
 502
 503 File::Path::rmtree('t/var/splat');
 504
 505 $c->ensure_dir_structure_for('t/var/splat');
 506
 507 ok(-d 't/var/splat');
 508
 509 =end testing
 510
 511 =cut
 512
 513 sub guess_shelltype {
 514   my $shellbin = 'sh';
 515   if(defined $ENV{'SHELL'}) {
 516       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 517       $shellbin = $shell_bin_path_parts[-1];
 518   }
 519   my $shelltype = do {
 520       local $_ = $shellbin;
 521       if(/csh/) {
 522           'csh'
 523       } else {
 524           'bourne'
 525       }
 526   };
 527
 528   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 529   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 530       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 531       $shellbin = $shell_bin_path_parts[-1];
 532          $shelltype = do {
 533                  local $_ = $shellbin;
 534                  if(/command\.com/) {
 535                          'cmd'
 536                  } elsif(/cmd\.exe/) {
 537                          'cmd'
 538                  } elsif(/4nt\.exe/) {
 539                          'cmd'
 540                  } else {
 541                          $shelltype
 542                  }
 543          };
 544   }
 545   return $shelltype;
 546 }
 547
 548 1;
 549 __END__
 550
 551 =encoding utf8
 552
 553 =head1 NAME
 554
 555 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 556
 557 =head1 SYNOPSIS
 558
 559 In code -
 560
 561   use local::lib; # sets up a local lib at ~/perl5
 562
 563   use local::lib '~/foo'; # same, but ~/foo
 564
 565   # Or...
 566   use FindBin;
 567   use local::lib "$FindBin::Bin/../support";  # app-local support library
 568
 569 From the shell -
 570
 571   # Install LWP and its missing dependencies to the '~/perl5' directory
 572   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 573
 574   # Just print out useful shell commands
 575   $ perl -Mlocal::lib
 576   export PERL_MB_OPT='--install_base /home/username/perl5'
 577   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 578   export PERL5LIB="/home/username/perl5/lib/perl5"
 579   export PATH="/home/username/perl5/bin:$PATH"
 580
 581 =head2 The bootstrapping technique
 582
 583 A typical way to install local::lib is using what is known as the
 584 "bootstrapping" technique.  You would do this if your system administrator
 585 hasn't already installed local::lib.  In this case, you'll need to install
 586 local::lib in your home directory.
 587
 588 Even if you do have administrative privileges, you will still want to set up your
 589 environment variables, as discussed in step 4. Without this, you would still
 590 install the modules into the system CPAN installation and also your Perl scripts
 591 will not use the lib/ path you bootstrapped with local::lib.
 592
 593 By default local::lib installs itself and the CPAN modules into ~/perl5.
 594
 595 Windows users must also see L</Differences when using this module under Win32>.
 596
 597 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 598 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 599 or administrator.  Unpack the file in your home directory or in any other
 600 convenient location.
 601
 602 2. Run this:
 603
 604   perl Makefile.PL --bootstrap
 605
 606 If the system asks you whether it should automatically configure as much
 607 as possible, you would typically answer yes.
 608
 609 In order to install local::lib into a directory other than the default, you need
 610 to specify the name of the directory when you call bootstrap, as follows:
 611
 612   perl Makefile.PL --bootstrap=~/foo
 613
 614 3. Run this: (local::lib assumes you have make installed on your system)
 615
 616   make test && make install
 617
 618 4. Now we need to setup the appropriate environment variables, so that Perl
 619 starts using our newly generated lib/ directory. If you are using bash or
 620 any other Bourne shells, you can add this to your shell startup script this
 621 way:
 622
 623   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 624
 625 If you are using C shell, you can do this as follows:
 626
 627   /bin/csh
 628   echo $SHELL
 629   /bin/csh
 630   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 631
 632 If you passed to bootstrap a directory other than default, you also need to
 633 give that as import parameter to the call of the local::lib module like this
 634 way:
 635
 636   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 637
 638 After writing your shell configuration file, be sure to re-read it to get the
 639 changed settings into your current shell's environment. Bourne shells use
 640 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 641
 642 If you're on a slower machine, or are operating under draconian disk space
 643 limitations, you can disable the automatic generation of manpages from POD when
 644 installing modules by using the C<--no-manpages> argument when bootstrapping:
 645
 646   perl Makefile.PL --bootstrap --no-manpages
 647
 648 To avoid doing several bootstrap for several Perl module environments on the
 649 same account, for example if you use it for several different deployed
 650 applications independently, you can use one bootstrapped local::lib
 651 installation to install modules in different directories directly this way:
 652
 653   cd ~/mydir1
 654   perl -Mlocal::lib=./
 655   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 656   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 657   perl -MCPAN -e install ...    ### whatever modules you want
 658   cd ../mydir2
 659   ... REPEAT ...
 660
 661 If you are working with several C<local::lib> environments, you may want to
 662 remove some of them from the current environment without disturbing the others.
 663 You can deactivate one environment like this (using bourne sh):
 664
 665   eval $(perl -Mlocal::lib=--deactivate,~/path)
 666
 667 which will generate and run the commands needed to remove C<~/path> from your
 668 various search paths. Whichever environment was B<activated most recently> will
 669 remain the target for module installations. That is, if you activate
 670 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 671 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 672 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 673 installed in C<~/pathB> because pathB was activated later.
 674
 675 You can also ask C<local::lib> to clean itself completely out of the current
 676 shell's environment with the C<--deactivate-all> option.
 677 For multiple environments for multiple apps you may need to include a modified
 678 version of the C<< use FindBin >> instructions in the "In code" sample above.
 679 If you did something like the above, you have a set of Perl modules at C<<
 680 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 681 you need to tell it where to find the modules you installed for it at C<<
 682 ~/mydir1/lib >>.
 683
 684 In C<< ~/mydir1/scripts/myscript.pl >>:
 685
 686   use strict;
 687   use warnings;
 688   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 689   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 690
 691 Put this before any BEGIN { ... } blocks that require the modules you installed.
 692
 693 =head2 Differences when using this module under Win32
 694
 695 To set up the proper environment variables for your current session of
 696 C<CMD.exe>, you can use this:
 697
 698   C:\>perl -Mlocal::lib
 699   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 700   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 701   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 702   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 703
 704   ### To set the environment for this shell alone
 705   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 706   ### instead of $(perl -Mlocal::lib=./)
 707
 708 If you want the environment entries to persist, you'll need to add then to the
 709 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 710
 711 The "~" is translated to the user's profile directory (the directory named for
 712 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 713 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 714 directory is translated to a short name (which means the directory must exist)
 715 and the subdirectories are created.
 716
 717 =head1 RATIONALE
 718
 719 The version of a Perl package on your machine is not always the version you
 720 need.  Obviously, the best thing to do would be to update to the version you
 721 need.  However, you might be in a situation where you're prevented from doing
 722 this.  Perhaps you don't have system administrator privileges; or perhaps you
 723 are using a package management system such as Debian, and nobody has yet gotten
 724 around to packaging up the version you need.
 725
 726 local::lib solves this problem by allowing you to create your own directory of
 727 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 728 be within your own home directory).  The existing system Perl installation is
 729 not affected; you simply invoke Perl with special options so that Perl uses the
 730 packages in your own local package directory rather than the system packages.
 731 local::lib arranges things so that your locally installed version of the Perl
 732 packages takes precedence over the system installation.
 733
 734 If you are using a package management system (such as Debian), you don't need to
 735 worry about Debian and CPAN stepping on each other's toes.  Your local version
 736 of the packages will be written to an entirely separate directory from those
 737 installed by Debian.
 738
 739 =head1 DESCRIPTION
 740
 741 This module provides a quick, convenient way of bootstrapping a user-local Perl
 742 module library located within the user's home directory. It also constructs and
 743 prints out for the user the list of environment variables using the syntax
 744 appropriate for the user's current shell (as specified by the C<SHELL>
 745 environment variable), suitable for directly adding to one's shell
 746 configuration file.
 747
 748 More generally, local::lib allows for the bootstrapping and usage of a
 749 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 750 easier to ship an application with an app-specific copy of a Perl module, or
 751 collection of modules. Useful in cases like when an upstream maintainer hasn't
 752 applied a patch to a module of theirs that you need for your application.
 753
 754 On import, local::lib sets the following environment variables to appropriate
 755 values:
 756
 757 =over 4
 758
 759 =item PERL_MB_OPT
 760
 761 =item PERL_MM_OPT
 762
 763 =item PERL5LIB
 764
 765 =item PATH
 766
 767 =back
 768
 769 When possible, these will be appended to instead of overwritten entirely.
 770
 771 These values are then available for reference by any code after import.
 772
 773 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 774
 775 See L<lib::core::only> for one way to do this - but note that
 776 there are a number of caveats, and the best approach is always to perform a
 777 build against a clean perl (i.e. site and vendor as close to empty as possible).
 778
 779 =head1 OPTIONS
 780
 781 Options are values that can be passed to the C<local::lib> import besides the
 782 directory to use. They are specified as C<use local::lib '--option'[, path];>
 783 or C<perl -Mlocal::lib=--option[,path]>.
 784
 785 =head2 --deactivate
 786
 787 Remove the chosen path (or the default path) from the module search paths if it
 788 was added by C<local::lib>, instead of adding it.
 789
 790 =head2 --deactivate-all
 791
 792 Remove all directories that were added to search paths by C<local::lib> from the
 793 search paths.
 794
 795 =head1 METHODS
 796
 797 =head2 ensure_dir_structure_for
 798
 799 =over 4
 800
 801 =item Arguments: $path
 802
 803 =item Return value: None
 804
 805 =back
 806
 807 Attempts to create the given path, and all required parent directories. Throws
 808 an exception on failure.
 809
 810 =head2 print_environment_vars_for
 811
 812 =over 4
 813
 814 =item Arguments: $path
 815
 816 =item Return value: None
 817
 818 =back
 819
 820 Prints to standard output the variables listed above, properly set to use the
 821 given path as the base directory.
 822
 823 =head2 build_environment_vars_for
 824
 825 =over 4
 826
 827 =item Arguments: $path, $interpolate
 828
 829 =item Return value: %environment_vars
 830
 831 =back
 832
 833 Returns a hash with the variables listed above, properly set to use the
 834 given path as the base directory.
 835
 836 =head2 setup_env_hash_for
 837
 838 =over 4
 839
 840 =item Arguments: $path
 841
 842 =item Return value: None
 843
 844 =back
 845
 846 Constructs the C<%ENV> keys for the given path, by calling
 847 L</build_environment_vars_for>.
 848
 849 =head2 active_paths
 850
 851 =over 4
 852
 853 =item Arguments: None
 854
 855 =item Return value: @paths
 856
 857 =back
 858
 859 Returns a list of active C<local::lib> paths, according to the
 860 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 861 what is really in C<@INC>.
 862
 863 =head2 install_base_perl_path
 864
 865 =over 4
 866
 867 =item Arguments: $path
 868
 869 =item Return value: $install_base_perl_path
 870
 871 =back
 872
 873 Returns a path describing where to install the Perl modules for this local
 874 library installation. Appends the directories C<lib> and C<perl5> to the given
 875 path.
 876
 877 =head2 install_base_bin_path
 878
 879 =over 4
 880
 881 =item Arguments: $path
 882
 883 =item Return value: $install_base_bin_path
 884
 885 =back
 886
 887 Returns a path describing where to install the executable programs for this
 888 local library installation. Appends the directory C<bin> to the given path.
 889
 890 =head2 resolve_empty_path
 891
 892 =over 4
 893
 894 =item Arguments: $path
 895
 896 =item Return value: $base_path
 897
 898 =back
 899
 900 Builds and returns the base path into which to set up the local module
 901 installation. Defaults to C<~/perl5>.
 902
 903 =head2 resolve_home_path
 904
 905 =over 4
 906
 907 =item Arguments: $path
 908
 909 =item Return value: $home_path
 910
 911 =back
 912
 913 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 914 for this purpose. If no definite answer is available, throws an exception.
 915
 916 =head2 resolve_relative_path
 917
 918 =over 4
 919
 920 =item Arguments: $path
 921
 922 =item Return value: $absolute_path
 923
 924 =back
 925
 926 Translates the given path into an absolute path.
 927
 928 =head2 resolve_path
 929
 930 =over 4
 931
 932 =item Arguments: $path
 933
 934 =item Return value: $absolute_path
 935
 936 =back
 937
 938 Calls the following in a pipeline, passing the result from the previous to the
 939 next, in an attempt to find where to configure the environment for a local
 940 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 941 L</resolve_relative_path>. Passes the given path argument to
 942 L</resolve_empty_path> which then returns a result that is passed to
 943 L</resolve_home_path>, which then has its result passed to
 944 L</resolve_relative_path>. The result of this final call is returned from
 945 L</resolve_path>.
 946
 947 =head1 A WARNING ABOUT UNINST=1
 948
 949 Be careful about using local::lib in combination with "make install UNINST=1".
 950 The idea of this feature is that will uninstall an old version of a module
 951 before installing a new one. However it lacks a safety check that the old
 952 version and the new version will go in the same directory. Used in combination
 953 with local::lib, you can potentially delete a globally accessible version of a
 954 module while installing the new version in a local place. Only combine "make
 955 install UNINST=1" and local::lib if you understand these possible consequences.
 956
 957 =head1 LIMITATIONS
 958
 959 =over 4
 960
 961 =item * Directory names with spaces in them are not well supported by the perl
 962 toolchain and the programs it uses.  Pure-perl distributions should support
 963 spaces, but problems are more likely with dists that require compilation. A
 964 workaround you can do is moving your local::lib to a directory with spaces
 965 B<after> you installed all modules inside your local::lib bootstrap. But be
 966 aware that you can't update or install CPAN modules after the move.
 967
 968 =item * Rather basic shell detection. Right now anything with csh in its name is
 969 assumed to be a C shell or something compatible, and everything else is assumed
 970 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 971 not set, a Bourne-compatible shell is assumed.
 972
 973 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
 974
 975 =item * Should probably auto-fixup CPAN config if not already done.
 976
 977 =back
 978
 979 Patches very much welcome for any of the above.
 980
 981 =over 4
 982
 983 =item * On Win32 systems, does not have a way to write the created environment
 984 variables to the registry, so that they can persist through a reboot.
 985
 986 =back
 987
 988 =head1 TROUBLESHOOTING
 989
 990 If you've configured local::lib to install CPAN modules somewhere in to your
 991 home directory, and at some point later you try to install a module with C<cpan
 992 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
 993 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
 994 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
 995 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
 996 you've somehow lost your updated ExtUtils::MakeMaker module.
 997
 998 To remedy this situation, rerun the bootstrapping procedure documented above.
 999
1000 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1001
1002 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1003
1004 =head1 ENVIRONMENT
1005
1006 =over 4
1007
1008 =item SHELL
1009
1010 =item COMSPEC
1011
1012 local::lib looks at the user's C<SHELL> environment variable when printing out
1013 commands to add to the shell configuration file.
1014
1015 On Win32 systems, C<COMSPEC> is also examined.
1016
1017 =back
1018
1019 =head1 SEE ALSO
1020
1021 =over 4
1022
1023 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1024
1025 =back
1026
1027 =head1 SUPPORT
1028
1029 IRC:
1030
1031     Join #local-lib on irc.perl.org.
1032
1033 =head1 AUTHOR
1034
1035 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1036
1037 auto_install fixes kindly sponsored by http://www.takkle.com/
1038
1039 =head1 CONTRIBUTORS
1040
1041 Patches to correctly output commands for csh style shells, as well as some
1042 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1043
1044 Doc patches for a custom local::lib directory, more cleanups in the english
1045 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1046 Torsten Raudssus <torsten@raudssus.de>.
1047
1048 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1049 things will install properly, submitted a fix for the bug causing problems with
1050 writing Makefiles during bootstrapping, contributed an example program, and
1051 submitted yet another fix to ensure that local::lib can install and bootstrap
1052 properly. Many, many thanks!
1053
1054 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1055 section. Many thanks!
1056
1057 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1058
1059 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1060 by a patch from Marco Emilio Poleggi.
1061
1062 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1063 '--self-contained' option.
1064
1065 Documentation patches to make win32 usage clearer by
1066 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1067
1068 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1069 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1070
1071 Improvements to stacking multiple local::lib dirs and removing them from the
1072 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1073
1074 Patch for Carp version mismatch contributed by Hakim Cassimally
1075 <osfameron@cpan.org>.
1076
1077 =head1 COPYRIGHT
1078
1079 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1080 listed above.
1081
1082 =head1 LICENSE
1083
1084 This is free software; you can redistribute it and/or modify it under
1085 the same terms as the Perl 5 programming language system itself.
1086
1087 =cut