lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '1.008026'; # 1.8.26
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19
  20   while (@args) {
  21     my $arg = shift @args;
  22     # check for lethal dash first to stop processing before causing problems
  23     # the fancy dash is U+2212 or \xE2\x88\x92
  24     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  25       die <<'DEATH';
  26 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  27 These are *not* the traditional -- dashes that software recognizes. You
  28 probably got these by copy-pasting from the perldoc for this module as
  29 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  30 terminal, but can happen elsewhere too. Please try again after replacing the
  31 dashes with normal minus signs.
  32 DEATH
  33     }
  34     elsif ($arg eq '--self-contained') {
  35       die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  36     }
  37     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  38       my $path = defined $1 ? $1 : shift @args;
  39       push @steps, ['deactivate', $path];
  40     }
  41     elsif ( $arg eq '--deactivate-all' ) {
  42       push @steps, ['deactivate_all'];
  43     }
  44     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  45       my $shell = defined $1 ? $1 : shift @args;
  46       $opts{shelltype} = $shell;
  47     }
  48     elsif ( $arg eq '--no-create' ) {
  49       $opts{no_create} = 1;
  50     }
  51     elsif ( $arg =~ /^--/ ) {
  52       die "Unknown import argument: $arg";
  53     }
  54     else {
  55       push @steps, ['activate', $arg];
  56     }
  57   }
  58   if (!@steps) {
  59     push @steps, ['activate', undef];
  60   }
  61
  62   my $self = $class->new(%opts);
  63
  64   for (@steps) {
  65     my ($method, @args) = @$_;
  66     $self = $self->$method(@args);
  67   }
  68
  69   if ($0 eq '-') {
  70     $self->print_environment_vars_for;
  71     exit 0;
  72   }
  73   else {
  74     $self->setup_local_lib_for;
  75   }
  76 }
  77
  78 sub new {
  79   my $class = shift;
  80   bless {@_}, $class;
  81 }
  82
  83 sub clone {
  84   my $self = shift;
  85   bless {%$self, @_}, ref $self;
  86 }
  87
  88 sub inc { $_[0]->{inc}     ||= \@INC }
  89 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
  90 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
  91 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
  92 sub extra { $_[0]->{extra} ||= {} }
  93 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
  94 sub no_create { $_[0]->{no_create} }
  95
  96 my $_archname = $Config{archname};
  97 my $_version  = $Config{version};
  98 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
  99 my $_path_sep = $Config{path_sep};
 100
 101 sub _as_list {
 102   my $list = shift;
 103   grep length, map {
 104     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 105       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 106                         : ()
 107     )
 108   } ref $list ? @$list : $list;
 109 }
 110 sub _remove_from {
 111   my ($list, @remove) = @_;
 112   return @$list
 113     if !@remove;
 114   my %remove = map { $_ => 1 } @remove;
 115   grep !$remove{$_}, _as_list($list);
 116 }
 117
 118 my @_lib_subdirs = (
 119   [$_version, $_archname],
 120   [$_version],
 121   [$_archname],
 122   (@_inc_version_list ? \@_inc_version_list : ()),
 123   [],
 124 );
 125
 126 sub install_base_bin_path {
 127   my ($class, $path) = @_;
 128   return File::Spec->catdir($path, 'bin');
 129 }
 130 sub install_base_perl_path {
 131   my ($class, $path) = @_;
 132   return File::Spec->catdir($path, 'lib', 'perl5');
 133 }
 134 sub install_base_arch_path {
 135   my ($class, $path) = @_;
 136   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 137 }
 138
 139 sub lib_paths_for {
 140   my ($class, $path) = @_;
 141   my $base = $class->install_base_perl_path($path);
 142   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 143 }
 144
 145 sub _mm_escape_path {
 146   my $path = shift;
 147   $path =~ s/\\/\\\\\\\\/g;
 148   if ($path =~ s/ /\\ /g) {
 149     $path = qq{"\\"$path\\""};
 150   }
 151   return $path;
 152 }
 153
 154 sub _mb_escape_path {
 155   my $path = shift;
 156   $path =~ s/\\/\\\\/g;
 157   return qq{"$path"};
 158 }
 159
 160 sub installer_options_for {
 161   my ($class, $path) = @_;
 162   return {
 163     PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 164     PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef,
 165   };
 166 }
 167
 168 sub active_paths {
 169   my ($self) = @_;
 170   $self = ref $self ? $self : $self->new;
 171
 172   return grep {
 173     # screen out entries that aren't actually reflected in @INC
 174     my $active_ll = $self->install_base_perl_path($_);
 175     grep { $_ eq $active_ll } @{$self->inc};
 176   } _as_list($self->roots);
 177 }
 178
 179
 180 sub deactivate {
 181   my ($self, $path) = @_;
 182   $self = $self->new unless ref $self;
 183   $path = $self->resolve_path($path);
 184
 185   my @active_lls = $self->active_paths;
 186
 187   if (!grep { $_ eq $path } @active_lls) {
 188     warn "Tried to deactivate inactive local::lib '$path'\n";
 189     return $self;
 190   }
 191
 192   my %args = (
 193     bins  => [ _remove_from($self->bins,  $self->install_base_bin_path($path)) ],
 194     libs  => [ _remove_from($self->libs,  $self->install_base_perl_path($path)) ],
 195     inc   => [ _remove_from($self->inc,   $self->lib_paths_for($path)) ],
 196     roots => [ _remove_from($self->roots, $path) ],
 197   );
 198
 199   $args{extra} = $self->installer_options_for($args{roots}[0]);
 200
 201   $self->clone(%args);
 202 }
 203
 204 sub deactivate_all {
 205   my ($self) = @_;
 206   $self = $self->new unless ref $self;
 207
 208   my @active_lls = $self->active_paths;
 209
 210   my %args;
 211   if (@active_lls) {
 212     %args = (
 213       bins => [ _remove_from($self->bins,
 214         map $self->install_base_bin_path($_), @active_lls) ],
 215       libs => [ _remove_from($self->libs,
 216         map $self->install_base_perl_path($_), @active_lls) ],
 217       inc => [ _remove_from($self->inc,
 218         map $self->lib_paths_for($_), @active_lls) ],
 219       roots => [ _remove_from($self->roots, @active_lls) ],
 220     );
 221   }
 222
 223   $args{extra} = $self->installer_options_for(undef);
 224
 225   $self->clone(%args);
 226 }
 227
 228 sub activate {
 229   my ($self, $path) = @_;
 230   $self = $self->new unless ref $self;
 231   $path = $self->resolve_path($path);
 232   $self->ensure_dir_structure_for($path)
 233     unless $self->no_create;
 234
 235   $path = ( Win32::GetShortPathName($path) || $path )
 236     if $^O eq 'MSWin32';
 237
 238   my @active_lls = $self->active_paths;
 239
 240   if (grep { $_ eq $path } @active_lls[1 .. $#active_lls]) {
 241     $self = $self->deactivate($path);
 242   }
 243
 244   my %args;
 245   if (!@active_lls || $active_lls[0] ne $path) {
 246     %args = (
 247       bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 248       libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 249       inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 250       roots => [ $path, @{$self->roots} ],
 251     );
 252   }
 253
 254   $args{extra} = $self->installer_options_for($path);
 255
 256   $self->clone(%args);
 257 }
 258
 259 sub _legacy {
 260   my ($self, $path) = @_;
 261   $self = $self->new unless ref $self;
 262   if (defined $path) {
 263     $self = $self->activate($path);
 264   }
 265   $self;
 266 }
 267
 268 sub build_environment_vars_for {
 269   my ($self) = _legacy(@_);
 270   (
 271     PATH                => join($_path_sep, _as_list($self->bins)),
 272     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 273     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 274     %{$self->extra},
 275   );
 276 }
 277
 278 sub setup_local_lib_for {
 279   my ($self) = _legacy(@_);
 280   $self->setup_env_hash_for;
 281   @INC = @{$self->inc};
 282 }
 283
 284 sub setup_env_hash_for {
 285   my $self = shift;
 286   my %env = $self->build_environment_vars_for(@_);
 287   for my $key (keys %env) {
 288     if (defined $env{$key}) {
 289       $ENV{$key} = $env{$key};
 290     }
 291     else {
 292       delete $ENV{$key};
 293     }
 294   }
 295 }
 296
 297 sub print_environment_vars_for {
 298   my $self = shift;
 299   print $self->environment_vars_string_for(@_);
 300 }
 301
 302 sub environment_vars_string_for {
 303   my $self = _legacy(@_);
 304
 305   my $build_method = 'build_' . $self->shelltype . '_env_declaration';
 306
 307   my @envs = (
 308     PATH                => $self->bins,
 309     PERL5LIB            => $self->libs,
 310     PERL_LOCAL_LIB_ROOT => $self->roots,
 311     %{$self->extra},
 312   );
 313   my $out = '';
 314   while (@envs) {
 315     my ($name, $value) = (shift(@envs), shift(@envs));
 316     if (
 317         ref $value
 318         && @$value == 1
 319         && ref $value->[0]
 320         && ref $value->[0] eq 'SCALAR'
 321         && ${$value->[0]} eq $name) {
 322       next;
 323     }
 324     if (
 325         !ref $value
 326         and defined $value
 327           ? (defined $ENV{$name} && $value eq $ENV{$name})
 328           : !defined $ENV{$name}
 329     ) {
 330       next;
 331     }
 332     $out .= $self->$build_method($name, $value);
 333   }
 334   my $wrap_method = 'wrap_' . $self->shelltype . '_output';
 335   if ($self->can($wrap_method)) {
 336     return $self->$wrap_method($out);
 337   }
 338   return $out;
 339 }
 340
 341 sub build_bourne_env_declaration {
 342   my ($class, $name, $args) = @_;
 343   my $value = $class->_interpolate($args);
 344   defined $value
 345     ? qq{export ${name}="${value}";\n}
 346     : qq{unset ${name};\n};
 347 }
 348 sub build_csh_env_declaration {
 349   my ($class, $name, $args) = @_;
 350   my ($value, @vars) = $class->_interpolate($args, undef, undef, '"', qq{"\\"});
 351   (join '', map qq{if ! \$?$_ setenv $_ "";\n}, @vars)
 352     . defined $value
 353       ? qq{setenv $name "$value";\n}
 354       : qq{unsetenv $name;\n};
 355 }
 356 sub build_cmd_env_declaration {
 357   my ($class, $name, $args) = @_;
 358   my $value = $class->_interpolate($args, '%', '%', qr([()!^"<>&|]), '^');
 359   defined $value
 360     ? qq{\@set $name=$value\n}
 361     : qq{\@set $name=\n};
 362 }
 363 sub build_powershell_env_declaration {
 364   my ($class, $name, $args) = @_;
 365   my $value = $class->_interpolate($args, '$env:', '', '"', '`');
 366   defined $value
 367     ? qq{\$env:$name = "$value";\n}
 368     : "Remove-Item Env:\\$name;\n";
 369 }
 370 sub wrap_powershell_output {
 371   my ($class, $out) = @_;
 372   return $out || " \n";
 373 }
 374
 375
 376 sub _interpolate {
 377   my ($class, $args, $start, $end, $escape, $escape_char) = @_;
 378   return
 379     unless defined $args;
 380   return $args
 381     unless ref $args;
 382   return
 383     unless @$args;
 384   $start = '$' unless defined $start;
 385   $end = '' unless defined $end;
 386   $escape = '"' unless defined $escape;
 387   $escape_char = "\\" unless defined $escape_char;
 388   my @vars;
 389   my $string = join($Config{path_sep}, map {
 390     if (ref $_ && ref $_ eq 'SCALAR') {
 391       push @vars, $$_;
 392       $start.$$_.$end;
 393     }
 394     else {
 395       my $str = $_;
 396       $str =~ s/($escape)/$escape_char$1/g;
 397       $str;
 398     }
 399   } @$args);
 400   return wantarray ? ($string, @vars) : $string;
 401 }
 402
 403 sub pipeline;
 404
 405 sub pipeline {
 406   my @methods = @_;
 407   my $last = pop(@methods);
 408   if (@methods) {
 409     \sub {
 410       my ($obj, @args) = @_;
 411       $obj->${pipeline @methods}(
 412         $obj->$last(@args)
 413       );
 414     };
 415   } else {
 416     \sub {
 417       shift->$last(@_);
 418     };
 419   }
 420 }
 421
 422 =begin testing
 423
 424 #:: test pipeline
 425
 426 package local::lib;
 427
 428 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 429 my $foo = bless({}, 'Foo');
 430 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 431
 432 =end testing
 433
 434 =cut
 435
 436 sub resolve_path {
 437   my ($class, $path) = @_;
 438
 439   $path = $class->${pipeline qw(
 440     resolve_relative_path
 441     resolve_home_path
 442     resolve_empty_path
 443   )}($path);
 444
 445   $path;
 446 }
 447
 448 sub resolve_empty_path {
 449   my ($class, $path) = @_;
 450   if (defined $path) {
 451     $path;
 452   } else {
 453     '~/perl5';
 454   }
 455 }
 456
 457 =begin testing
 458
 459 #:: test classmethod setup
 460
 461 my $c = 'local::lib';
 462
 463 =end testing
 464
 465 =begin testing
 466
 467 #:: test classmethod
 468
 469 is($c->resolve_empty_path, '~/perl5');
 470 is($c->resolve_empty_path('foo'), 'foo');
 471
 472 =end testing
 473
 474 =cut
 475
 476 sub resolve_home_path {
 477   my ($class, $path) = @_;
 478   return $path unless ($path =~ /^~/);
 479   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 480   my $homedir = do {
 481     if (!defined $user && defined $ENV{HOME}) {
 482       $ENV{HOME}
 483     }
 484     else {
 485       require File::Glob;
 486       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 487     }
 488   };
 489   unless (defined $homedir) {
 490     require Carp;
 491     Carp::croak(
 492       "Couldn't resolve homedir for "
 493       .(defined $user ? $user : 'current user')
 494     );
 495   }
 496   $path =~ s/^~[^\/]*/$homedir/;
 497   $path;
 498 }
 499
 500 sub resolve_relative_path {
 501   my ($class, $path) = @_;
 502   $path = File::Spec->rel2abs($path);
 503 }
 504
 505 =begin testing
 506
 507 #:: test classmethod
 508
 509 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 510 is($c->resolve_relative_path('bar'),'FOObar');
 511
 512 =end testing
 513
 514 =cut
 515
 516 sub ensure_dir_structure_for {
 517   my ($class, $path) = @_;
 518   unless (-d $path) {
 519     warn "Attempting to create directory ${path}\n";
 520   }
 521   require File::Basename;
 522   my @dirs;
 523   while(!-d $path) {
 524     push @dirs, $path;
 525     $path = File::Basename::dirname($path);
 526   }
 527   mkdir $_ for reverse @dirs;
 528   return;
 529 }
 530
 531 =begin testing
 532
 533 #:: test classmethod
 534
 535 File::Path::rmtree('t/var/splat');
 536
 537 $c->ensure_dir_structure_for('t/var/splat');
 538
 539 ok(-d 't/var/splat');
 540
 541 =end testing
 542
 543 =cut
 544
 545 sub guess_shelltype {
 546   my $shellbin
 547     = defined $ENV{SHELL}
 548       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 549     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 550       ? 'bash'
 551     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 552       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 553     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 554       ? 'powershell.exe'
 555     : 'sh';
 556
 557   for ($shellbin) {
 558     return
 559         /csh/             ? 'csh'
 560       : /command\.com/    ? 'cmd'
 561       : /cmd\.exe/        ? 'cmd'
 562       : /4nt\.exe/        ? 'cmd'
 563       : /powershell\.exe/ ? 'powershell'
 564                           : 'bourne';
 565   }
 566 }
 567
 568 1;
 569 __END__
 570
 571 =encoding utf8
 572
 573 =head1 NAME
 574
 575 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 576
 577 =head1 SYNOPSIS
 578
 579 In code -
 580
 581   use local::lib; # sets up a local lib at ~/perl5
 582
 583   use local::lib '~/foo'; # same, but ~/foo
 584
 585   # Or...
 586   use FindBin;
 587   use local::lib "$FindBin::Bin/../support";  # app-local support library
 588
 589 From the shell -
 590
 591   # Install LWP and its missing dependencies to the '~/perl5' directory
 592   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 593
 594   # Just print out useful shell commands
 595   $ perl -Mlocal::lib
 596   export PERL_MB_OPT='--install_base /home/username/perl5'
 597   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 598   export PERL5LIB="/home/username/perl5/lib/perl5"
 599   export PATH="/home/username/perl5/bin:$PATH"
 600
 601 =head2 The bootstrapping technique
 602
 603 A typical way to install local::lib is using what is known as the
 604 "bootstrapping" technique.  You would do this if your system administrator
 605 hasn't already installed local::lib.  In this case, you'll need to install
 606 local::lib in your home directory.
 607
 608 Even if you do have administrative privileges, you will still want to set up your
 609 environment variables, as discussed in step 4. Without this, you would still
 610 install the modules into the system CPAN installation and also your Perl scripts
 611 will not use the lib/ path you bootstrapped with local::lib.
 612
 613 By default local::lib installs itself and the CPAN modules into ~/perl5.
 614
 615 Windows users must also see L</Differences when using this module under Win32>.
 616
 617 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 618 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 619 or administrator.  Unpack the file in your home directory or in any other
 620 convenient location.
 621
 622 2. Run this:
 623
 624   perl Makefile.PL --bootstrap
 625
 626 If the system asks you whether it should automatically configure as much
 627 as possible, you would typically answer yes.
 628
 629 In order to install local::lib into a directory other than the default, you need
 630 to specify the name of the directory when you call bootstrap, as follows:
 631
 632   perl Makefile.PL --bootstrap=~/foo
 633
 634 3. Run this: (local::lib assumes you have make installed on your system)
 635
 636   make test && make install
 637
 638 4. Now we need to setup the appropriate environment variables, so that Perl
 639 starts using our newly generated lib/ directory. If you are using bash or
 640 any other Bourne shells, you can add this to your shell startup script this
 641 way:
 642
 643   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 644
 645 If you are using C shell, you can do this as follows:
 646
 647   /bin/csh
 648   echo $SHELL
 649   /bin/csh
 650   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 651
 652 If you passed to bootstrap a directory other than default, you also need to
 653 give that as import parameter to the call of the local::lib module like this
 654 way:
 655
 656   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 657
 658 After writing your shell configuration file, be sure to re-read it to get the
 659 changed settings into your current shell's environment. Bourne shells use
 660 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 661
 662 If you're on a slower machine, or are operating under draconian disk space
 663 limitations, you can disable the automatic generation of manpages from POD when
 664 installing modules by using the C<--no-manpages> argument when bootstrapping:
 665
 666   perl Makefile.PL --bootstrap --no-manpages
 667
 668 To avoid doing several bootstrap for several Perl module environments on the
 669 same account, for example if you use it for several different deployed
 670 applications independently, you can use one bootstrapped local::lib
 671 installation to install modules in different directories directly this way:
 672
 673   cd ~/mydir1
 674   perl -Mlocal::lib=./
 675   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 676   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 677   perl -MCPAN -e install ...    ### whatever modules you want
 678   cd ../mydir2
 679   ... REPEAT ...
 680
 681 If you are working with several C<local::lib> environments, you may want to
 682 remove some of them from the current environment without disturbing the others.
 683 You can deactivate one environment like this (using bourne sh):
 684
 685   eval $(perl -Mlocal::lib=--deactivate,~/path)
 686
 687 which will generate and run the commands needed to remove C<~/path> from your
 688 various search paths. Whichever environment was B<activated most recently> will
 689 remain the target for module installations. That is, if you activate
 690 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 691 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 692 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 693 installed in C<~/pathB> because pathB was activated later.
 694
 695 You can also ask C<local::lib> to clean itself completely out of the current
 696 shell's environment with the C<--deactivate-all> option.
 697 For multiple environments for multiple apps you may need to include a modified
 698 version of the C<< use FindBin >> instructions in the "In code" sample above.
 699 If you did something like the above, you have a set of Perl modules at C<<
 700 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 701 you need to tell it where to find the modules you installed for it at C<<
 702 ~/mydir1/lib >>.
 703
 704 In C<< ~/mydir1/scripts/myscript.pl >>:
 705
 706   use strict;
 707   use warnings;
 708   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 709   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 710
 711 Put this before any BEGIN { ... } blocks that require the modules you installed.
 712
 713 =head2 Differences when using this module under Win32
 714
 715 To set up the proper environment variables for your current session of
 716 C<CMD.exe>, you can use this:
 717
 718   C:\>perl -Mlocal::lib
 719   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 720   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 721   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 722   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 723
 724   ### To set the environment for this shell alone
 725   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 726   ### instead of $(perl -Mlocal::lib=./)
 727
 728 If you want the environment entries to persist, you'll need to add then to the
 729 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 730
 731 The "~" is translated to the user's profile directory (the directory named for
 732 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 733 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 734 directory is translated to a short name (which means the directory must exist)
 735 and the subdirectories are created.
 736
 737 =head1 RATIONALE
 738
 739 The version of a Perl package on your machine is not always the version you
 740 need.  Obviously, the best thing to do would be to update to the version you
 741 need.  However, you might be in a situation where you're prevented from doing
 742 this.  Perhaps you don't have system administrator privileges; or perhaps you
 743 are using a package management system such as Debian, and nobody has yet gotten
 744 around to packaging up the version you need.
 745
 746 local::lib solves this problem by allowing you to create your own directory of
 747 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 748 be within your own home directory).  The existing system Perl installation is
 749 not affected; you simply invoke Perl with special options so that Perl uses the
 750 packages in your own local package directory rather than the system packages.
 751 local::lib arranges things so that your locally installed version of the Perl
 752 packages takes precedence over the system installation.
 753
 754 If you are using a package management system (such as Debian), you don't need to
 755 worry about Debian and CPAN stepping on each other's toes.  Your local version
 756 of the packages will be written to an entirely separate directory from those
 757 installed by Debian.
 758
 759 =head1 DESCRIPTION
 760
 761 This module provides a quick, convenient way of bootstrapping a user-local Perl
 762 module library located within the user's home directory. It also constructs and
 763 prints out for the user the list of environment variables using the syntax
 764 appropriate for the user's current shell (as specified by the C<SHELL>
 765 environment variable), suitable for directly adding to one's shell
 766 configuration file.
 767
 768 More generally, local::lib allows for the bootstrapping and usage of a
 769 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 770 easier to ship an application with an app-specific copy of a Perl module, or
 771 collection of modules. Useful in cases like when an upstream maintainer hasn't
 772 applied a patch to a module of theirs that you need for your application.
 773
 774 On import, local::lib sets the following environment variables to appropriate
 775 values:
 776
 777 =over 4
 778
 779 =item PERL_MB_OPT
 780
 781 =item PERL_MM_OPT
 782
 783 =item PERL5LIB
 784
 785 =item PATH
 786
 787 =back
 788
 789 When possible, these will be appended to instead of overwritten entirely.
 790
 791 These values are then available for reference by any code after import.
 792
 793 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 794
 795 See L<lib::core::only> for one way to do this - but note that
 796 there are a number of caveats, and the best approach is always to perform a
 797 build against a clean perl (i.e. site and vendor as close to empty as possible).
 798
 799 =head1 OPTIONS
 800
 801 Options are values that can be passed to the C<local::lib> import besides the
 802 directory to use. They are specified as C<use local::lib '--option'[, path];>
 803 or C<perl -Mlocal::lib=--option[,path]>.
 804
 805 =head2 --deactivate
 806
 807 Remove the chosen path (or the default path) from the module search paths if it
 808 was added by C<local::lib>, instead of adding it.
 809
 810 =head2 --deactivate-all
 811
 812 Remove all directories that were added to search paths by C<local::lib> from the
 813 search paths.
 814
 815 =head2 --shelltype
 816
 817 Specify the shell type to use for output.  By default, the shell will be
 818 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 819 C<cmd>, or C<powershell>.
 820
 821 =head2 --no-create
 822
 823 Prevents C<local::lib> from creating directories when activating dirs.  This is
 824 likely to cause issues on Win32 systems.
 825
 826 =head1 METHODS
 827
 828 =head2 ensure_dir_structure_for
 829
 830 =over 4
 831
 832 =item Arguments: $path
 833
 834 =item Return value: None
 835
 836 =back
 837
 838 Attempts to create the given path, and all required parent directories. Throws
 839 an exception on failure.
 840
 841 =head2 print_environment_vars_for
 842
 843 =over 4
 844
 845 =item Arguments: $path
 846
 847 =item Return value: None
 848
 849 =back
 850
 851 Prints to standard output the variables listed above, properly set to use the
 852 given path as the base directory.
 853
 854 =head2 build_environment_vars_for
 855
 856 =over 4
 857
 858 =item Arguments: $path
 859
 860 =item Return value: %environment_vars
 861
 862 =back
 863
 864 Returns a hash with the variables listed above, properly set to use the
 865 given path as the base directory.
 866
 867 =head2 setup_env_hash_for
 868
 869 =over 4
 870
 871 =item Arguments: $path
 872
 873 =item Return value: None
 874
 875 =back
 876
 877 Constructs the C<%ENV> keys for the given path, by calling
 878 L</build_environment_vars_for>.
 879
 880 =head2 active_paths
 881
 882 =over 4
 883
 884 =item Arguments: None
 885
 886 =item Return value: @paths
 887
 888 =back
 889
 890 Returns a list of active C<local::lib> paths, according to the
 891 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 892 what is really in C<@INC>.
 893
 894 =head2 install_base_perl_path
 895
 896 =over 4
 897
 898 =item Arguments: $path
 899
 900 =item Return value: $install_base_perl_path
 901
 902 =back
 903
 904 Returns a path describing where to install the Perl modules for this local
 905 library installation. Appends the directories C<lib> and C<perl5> to the given
 906 path.
 907
 908 =head2 install_base_bin_path
 909
 910 =over 4
 911
 912 =item Arguments: $path
 913
 914 =item Return value: $install_base_bin_path
 915
 916 =back
 917
 918 Returns a path describing where to install the executable programs for this
 919 local library installation. Appends the directory C<bin> to the given path.
 920
 921 =head2 resolve_empty_path
 922
 923 =over 4
 924
 925 =item Arguments: $path
 926
 927 =item Return value: $base_path
 928
 929 =back
 930
 931 Builds and returns the base path into which to set up the local module
 932 installation. Defaults to C<~/perl5>.
 933
 934 =head2 resolve_home_path
 935
 936 =over 4
 937
 938 =item Arguments: $path
 939
 940 =item Return value: $home_path
 941
 942 =back
 943
 944 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 945 for this purpose. If no definite answer is available, throws an exception.
 946
 947 =head2 resolve_relative_path
 948
 949 =over 4
 950
 951 =item Arguments: $path
 952
 953 =item Return value: $absolute_path
 954
 955 =back
 956
 957 Translates the given path into an absolute path.
 958
 959 =head2 resolve_path
 960
 961 =over 4
 962
 963 =item Arguments: $path
 964
 965 =item Return value: $absolute_path
 966
 967 =back
 968
 969 Calls the following in a pipeline, passing the result from the previous to the
 970 next, in an attempt to find where to configure the environment for a local
 971 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 972 L</resolve_relative_path>. Passes the given path argument to
 973 L</resolve_empty_path> which then returns a result that is passed to
 974 L</resolve_home_path>, which then has its result passed to
 975 L</resolve_relative_path>. The result of this final call is returned from
 976 L</resolve_path>.
 977
 978 =head1 A WARNING ABOUT UNINST=1
 979
 980 Be careful about using local::lib in combination with "make install UNINST=1".
 981 The idea of this feature is that will uninstall an old version of a module
 982 before installing a new one. However it lacks a safety check that the old
 983 version and the new version will go in the same directory. Used in combination
 984 with local::lib, you can potentially delete a globally accessible version of a
 985 module while installing the new version in a local place. Only combine "make
 986 install UNINST=1" and local::lib if you understand these possible consequences.
 987
 988 =head1 LIMITATIONS
 989
 990 =over 4
 991
 992 =item * Directory names with spaces in them are not well supported by the perl
 993 toolchain and the programs it uses.  Pure-perl distributions should support
 994 spaces, but problems are more likely with dists that require compilation. A
 995 workaround you can do is moving your local::lib to a directory with spaces
 996 B<after> you installed all modules inside your local::lib bootstrap. But be
 997 aware that you can't update or install CPAN modules after the move.
 998
 999 =item * Rather basic shell detection. Right now anything with csh in its name is
1000 assumed to be a C shell or something compatible, and everything else is assumed
1001 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
1002 not set, a Bourne-compatible shell is assumed.
1003
1004 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
1005
1006 =item * Should probably auto-fixup CPAN config if not already done.
1007
1008 =back
1009
1010 Patches very much welcome for any of the above.
1011
1012 =over 4
1013
1014 =item * On Win32 systems, does not have a way to write the created environment
1015 variables to the registry, so that they can persist through a reboot.
1016
1017 =back
1018
1019 =head1 TROUBLESHOOTING
1020
1021 If you've configured local::lib to install CPAN modules somewhere in to your
1022 home directory, and at some point later you try to install a module with C<cpan
1023 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1024 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1025 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1026 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1027 you've somehow lost your updated ExtUtils::MakeMaker module.
1028
1029 To remedy this situation, rerun the bootstrapping procedure documented above.
1030
1031 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1032
1033 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1034
1035 =head1 ENVIRONMENT
1036
1037 =over 4
1038
1039 =item SHELL
1040
1041 =item COMSPEC
1042
1043 local::lib looks at the user's C<SHELL> environment variable when printing out
1044 commands to add to the shell configuration file.
1045
1046 On Win32 systems, C<COMSPEC> is also examined.
1047
1048 =back
1049
1050 =head1 SEE ALSO
1051
1052 =over 4
1053
1054 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1055
1056 =back
1057
1058 =head1 SUPPORT
1059
1060 IRC:
1061
1062     Join #local-lib on irc.perl.org.
1063
1064 =head1 AUTHOR
1065
1066 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1067
1068 auto_install fixes kindly sponsored by http://www.takkle.com/
1069
1070 =head1 CONTRIBUTORS
1071
1072 Patches to correctly output commands for csh style shells, as well as some
1073 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1074
1075 Doc patches for a custom local::lib directory, more cleanups in the english
1076 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1077 Torsten Raudssus <torsten@raudssus.de>.
1078
1079 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1080 things will install properly, submitted a fix for the bug causing problems with
1081 writing Makefiles during bootstrapping, contributed an example program, and
1082 submitted yet another fix to ensure that local::lib can install and bootstrap
1083 properly. Many, many thanks!
1084
1085 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1086 section. Many thanks!
1087
1088 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1089
1090 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1091 by a patch from Marco Emilio Poleggi.
1092
1093 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1094 '--self-contained' option.
1095
1096 Documentation patches to make win32 usage clearer by
1097 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1098
1099 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1100 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1101
1102 Improvements to stacking multiple local::lib dirs and removing them from the
1103 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1104
1105 Patch for Carp version mismatch contributed by Hakim Cassimally
1106 <osfameron@cpan.org>.
1107
1108 =head1 COPYRIGHT
1109
1110 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1111 listed above.
1112
1113 =head1 LICENSE
1114
1115 This is free software; you can redistribute it and/or modify it under
1116 the same terms as the Perl 5 programming language system itself.
1117
1118 =cut