lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.008001; # probably works with earlier versions but I'm not supporting them
   7               # (patches would, of course, be welcome)
   8
   9 use File::Spec ();
  10 use File::Path ();
  11 use Config;
  12
  13 our $VERSION = '1.008007'; # 1.8.4
  14
  15 our @KNOWN_FLAGS = qw(--self-contained --deactivate --deactivate-all);
  16
  17 sub DEACTIVATE_ONE () { 1 }
  18 sub DEACTIVATE_ALL () { 2 }
  19
  20 sub INTERPOLATE_ENV () { 1 }
  21 sub LITERAL_ENV     () { 0 }
  22
  23 sub import {
  24   my ($class, @args) = @_;
  25
  26   # Remember what PERL5LIB was when we started
  27   my $perl5lib = $ENV{PERL5LIB} || '';
  28
  29   my %arg_store;
  30   for my $arg (@args) {
  31     # check for lethal dash first to stop processing before causing problems
  32     if ($arg =~ /−/) {
  33       die <<'DEATH';
  34 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  35 These are *not* the traditional -- dashes that software recognizes. You
  36 probably got these by copy-pasting from the perldoc for this module as
  37 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  38 terminal, but can happen elsewhere too. Please try again after replacing the
  39 dashes with normal minus signs.
  40 DEATH
  41     }
  42     elsif(grep { $arg eq $_ } @KNOWN_FLAGS) {
  43       (my $flag = $arg) =~ s/--//;
  44       $arg_store{$flag} = 1;
  45     }
  46     elsif($arg =~ /^--/) {
  47       die "Unknown import argument: $arg";
  48     }
  49     else {
  50       # assume that what's left is a path
  51       $arg_store{path} = $arg;
  52     }
  53   }
  54
  55   if($arg_store{'self-contained'}) {
  56     die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  57   }
  58
  59   my $deactivating = 0;
  60   if ($arg_store{deactivate}) {
  61     $deactivating = DEACTIVATE_ONE;
  62   }
  63   if ($arg_store{'deactivate-all'}) {
  64     $deactivating = DEACTIVATE_ALL;
  65   }
  66
  67   $arg_store{path} = $class->resolve_path($arg_store{path});
  68   $class->setup_local_lib_for($arg_store{path}, $deactivating);
  69
  70   for (@INC) { # Untaint @INC
  71     next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc.
  72     m/(.*)/ and $_ = $1;
  73   }
  74 }
  75
  76 sub pipeline;
  77
  78 sub pipeline {
  79   my @methods = @_;
  80   my $last = pop(@methods);
  81   if (@methods) {
  82     \sub {
  83       my ($obj, @args) = @_;
  84       $obj->${pipeline @methods}(
  85         $obj->$last(@args)
  86       );
  87     };
  88   } else {
  89     \sub {
  90       shift->$last(@_);
  91     };
  92   }
  93 }
  94
  95 =begin testing
  96
  97 #:: test pipeline
  98
  99 package local::lib;
 100
 101 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 102 my $foo = bless({}, 'Foo');
 103 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 104
 105 =end testing
 106
 107 =cut
 108
 109 sub _uniq {
 110     my %seen;
 111     grep { ! $seen{$_}++ } @_;
 112 }
 113
 114 sub resolve_path {
 115   my ($class, $path) = @_;
 116   $class->${pipeline qw(
 117     resolve_relative_path
 118     resolve_home_path
 119     resolve_empty_path
 120   )}($path);
 121 }
 122
 123 sub resolve_empty_path {
 124   my ($class, $path) = @_;
 125   if (defined $path) {
 126     $path;
 127   } else {
 128     '~/perl5';
 129   }
 130 }
 131
 132 =begin testing
 133
 134 #:: test classmethod setup
 135
 136 my $c = 'local::lib';
 137
 138 =end testing
 139
 140 =begin testing
 141
 142 #:: test classmethod
 143
 144 is($c->resolve_empty_path, '~/perl5');
 145 is($c->resolve_empty_path('foo'), 'foo');
 146
 147 =end testing
 148
 149 =cut
 150
 151 sub resolve_home_path {
 152   my ($class, $path) = @_;
 153   return $path unless ($path =~ /^~/);
 154   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 155   my $tried_file_homedir;
 156   my $homedir = do {
 157     if (eval { require File::HomeDir } && $File::HomeDir::VERSION >= 0.65) {
 158       $tried_file_homedir = 1;
 159       if (defined $user) {
 160         File::HomeDir->users_home($user);
 161       } else {
 162         File::HomeDir->my_home;
 163       }
 164     } else {
 165       if (defined $user) {
 166         (getpwnam $user)[7];
 167       } else {
 168         if (defined $ENV{HOME}) {
 169           $ENV{HOME};
 170         } else {
 171           (getpwuid $<)[7];
 172         }
 173       }
 174     }
 175   };
 176   unless (defined $homedir) {
 177     require Carp;
 178     Carp::croak(
 179       "Couldn't resolve homedir for "
 180       .(defined $user ? $user : 'current user')
 181       .($tried_file_homedir ? '' : ' - consider installing File::HomeDir')
 182     );
 183   }
 184   $path =~ s/^~[^\/]*/$homedir/;
 185   $path;
 186 }
 187
 188 sub resolve_relative_path {
 189   my ($class, $path) = @_;
 190   $path = File::Spec->rel2abs($path);
 191 }
 192
 193 =begin testing
 194
 195 #:: test classmethod
 196
 197 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 198 is($c->resolve_relative_path('bar'),'FOObar');
 199
 200 =end testing
 201
 202 =cut
 203
 204 sub setup_local_lib_for {
 205   my ($class, $path, $deactivating) = @_;
 206
 207   my $interpolate = LITERAL_ENV;
 208   my @active_lls = $class->active_paths;
 209
 210   $class->ensure_dir_structure_for($path);
 211
 212   # On Win32 directories often contain spaces. But some parts of the CPAN
 213   # toolchain don't like that. To avoid this, GetShortPathName() gives us
 214   # an alternate representation that has none.
 215   # This only works if the directory already exists.
 216   $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32';
 217
 218   if (! $deactivating) {
 219     if (@active_lls && $active_lls[-1] eq $path) {
 220       exit 0 if $0 eq '-';
 221       return; # Asked to add what's already at the top of the stack
 222     } elsif (grep { $_ eq $path} @active_lls) {
 223       # Asked to add a dir that's lower in the stack -- so we remove it from
 224       # where it is, and then add it back at the top.
 225       $class->setup_env_hash_for($path, DEACTIVATE_ONE);
 226       # Which means we can no longer output "PERL5LIB=...:$PERL5LIB" stuff
 227       # anymore because we're taking something *out*.
 228       $interpolate = INTERPOLATE_ENV;
 229     }
 230   }
 231
 232   if ($0 eq '-') {
 233     $class->print_environment_vars_for($path, $deactivating, $interpolate);
 234     exit 0;
 235   } else {
 236     $class->setup_env_hash_for($path, $deactivating);
 237     my $arch_dir = $Config{archname};
 238     @INC = _uniq(
 239         (
 240             # Inject $path/$archname for each path in PERL5LIB
 241             map { ( File::Spec->catdir($_, $arch_dir), $_ ) }
 242             split($Config{path_sep}, $ENV{PERL5LIB})
 243         ),
 244         @INC
 245     );
 246   }
 247 }
 248
 249 sub install_base_bin_path {
 250   my ($class, $path) = @_;
 251   File::Spec->catdir($path, 'bin');
 252 }
 253
 254 sub install_base_perl_path {
 255   my ($class, $path) = @_;
 256   File::Spec->catdir($path, 'lib', 'perl5');
 257 }
 258
 259 sub install_base_arch_path {
 260   my ($class, $path) = @_;
 261   File::Spec->catdir($class->install_base_perl_path($path), $Config{archname});
 262 }
 263
 264 sub ensure_dir_structure_for {
 265   my ($class, $path) = @_;
 266   unless (-d $path) {
 267     warn "Attempting to create directory ${path}\n";
 268   }
 269   File::Path::mkpath($path);
 270   return
 271 }
 272
 273 sub guess_shelltype {
 274   my $shellbin = 'sh';
 275   if(defined $ENV{'SHELL'}) {
 276       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 277       $shellbin = $shell_bin_path_parts[-1];
 278   }
 279   my $shelltype = do {
 280       local $_ = $shellbin;
 281       if(/csh/) {
 282           'csh'
 283       } else {
 284           'bourne'
 285       }
 286   };
 287
 288   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 289   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 290       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 291       $shellbin = $shell_bin_path_parts[-1];
 292          $shelltype = do {
 293                  local $_ = $shellbin;
 294                  if(/command\.com/) {
 295                          'win32'
 296                  } elsif(/cmd\.exe/) {
 297                          'win32'
 298                  } elsif(/4nt\.exe/) {
 299                          'win32'
 300                  } else {
 301                          $shelltype
 302                  }
 303          };
 304   }
 305   return $shelltype;
 306 }
 307
 308 sub print_environment_vars_for {
 309   my ($class, $path, $deactivating, $interpolate) = @_;
 310   print $class->environment_vars_string_for($path, $deactivating, $interpolate);
 311 }
 312
 313 sub environment_vars_string_for {
 314   my ($class, $path, $deactivating, $interpolate) = @_;
 315   my @envs = $class->build_environment_vars_for($path, $deactivating, $interpolate);
 316   my $out = '';
 317
 318   # rather basic csh detection, goes on the assumption that something won't
 319   # call itself csh unless it really is. also, default to bourne in the
 320   # pathological situation where a user doesn't have $ENV{SHELL} defined.
 321   # note also that shells with funny names, like zoid, are assumed to be
 322   # bourne.
 323
 324   my $shelltype = $class->guess_shelltype;
 325
 326   while (@envs) {
 327     my ($name, $value) = (shift(@envs), shift(@envs));
 328     $value =~ s/(\\")/\\$1/g if defined $value;
 329     $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value);
 330   }
 331   return $out;
 332 }
 333
 334 # simple routines that take two arguments: an %ENV key and a value. return
 335 # strings that are suitable for passing directly to the relevant shell to set
 336 # said key to said value.
 337 sub build_bourne_env_declaration {
 338   my $class = shift;
 339   my($name, $value) = @_;
 340   return defined($value) ? qq{export ${name}="${value}";\n} : qq{unset ${name};\n};
 341 }
 342
 343 sub build_csh_env_declaration {
 344   my $class = shift;
 345   my($name, $value) = @_;
 346   return defined($value) ? qq{setenv ${name} "${value}"\n} : qq{unsetenv ${name}\n};
 347 }
 348
 349 sub build_win32_env_declaration {
 350   my $class = shift;
 351   my($name, $value) = @_;
 352   return defined($value) ? qq{set ${name}=${value}\n} : qq{set ${name}=\n};
 353 }
 354
 355 sub setup_env_hash_for {
 356   my ($class, $path, $deactivating) = @_;
 357   my %envs = $class->build_environment_vars_for($path, $deactivating, INTERPOLATE_ENV);
 358   @ENV{keys %envs} = values %envs;
 359 }
 360
 361 sub build_environment_vars_for {
 362   my ($class, $path, $deactivating, $interpolate) = @_;
 363
 364   if ($deactivating == DEACTIVATE_ONE) {
 365     return $class->build_deactivate_environment_vars_for($path, $interpolate);
 366   } elsif ($deactivating == DEACTIVATE_ALL) {
 367     return $class->build_deact_all_environment_vars_for($path, $interpolate);
 368   } else {
 369     return $class->build_activate_environment_vars_for($path, $interpolate);
 370   }
 371 }
 372
 373 # Build an environment value for a variable like PATH from a list of paths.
 374 # References to existing variables are given as references to the variable name.
 375 # Duplicates are removed.
 376 #
 377 # options:
 378 # - interpolate: INTERPOLATE_ENV/LITERAL_ENV
 379 # - exists: paths are included only if they exist (default: interpolate == INTERPOLATE_ENV)
 380 # - filter: function to apply to each path do decide if it must be included
 381 # - empty: the value to return in the case of empty value
 382 my %ENV_LIST_VALUE_DEFAULTS = (
 383     interpolate => INTERPOLATE_ENV,
 384     exists => undef,
 385     filter => sub { 1 },
 386     empty => undef,
 387 );
 388 sub _env_list_value {
 389   my $options = shift;
 390   die(sprintf "unknown option '$_' at %s line %u\n", (caller)[1..2])
 391     for grep { !exists $ENV_LIST_VALUE_DEFAULTS{$_} } keys %$options;
 392   my %options = (%ENV_LIST_VALUE_DEFAULTS, %{ $options });
 393   $options{exists} = $options{interpolate} == INTERPOLATE_ENV
 394     unless defined $options{exists};
 395
 396   my %seen;
 397
 398   my $value = join($Config{path_sep}, map {
 399       ref $_ ? ($^O eq 'MSWin32' ? "%${$_}%" : "\$${$_}") : $_
 400     } grep {
 401       ref $_ || (defined $_
 402                  && length($_) > 0
 403                  && !$seen{$_}++
 404                  && $options{filter}->($_)
 405                  && (!$options{exists} || -e $_))
 406     } map {
 407       if (ref $_ eq 'SCALAR' && $options{interpolate} == INTERPOLATE_ENV) {
 408         exists $ENV{${$_}} ? (split /\Q$Config{path_sep}/, $ENV{${$_}}) : ()
 409       } else {
 410         $_
 411       }
 412     } @_);
 413   return length($value) ? $value : $options{empty};
 414 }
 415
 416 sub build_activate_environment_vars_for {
 417   my ($class, $path, $interpolate) = @_;
 418   return (
 419     PERL_LOCAL_LIB_ROOT =>
 420             _env_list_value(
 421               { interpolate => $interpolate, exists => 0, empty => '' },
 422               \'PERL_LOCAL_LIB_ROOT',
 423               $path,
 424             ),
 425     PERL_MB_OPT => "--install_base ${path}",
 426     PERL_MM_OPT => "INSTALL_BASE=${path}",
 427     PERL5LIB =>
 428             _env_list_value(
 429               { interpolate => $interpolate, exists => 0, empty => '' },
 430               $class->install_base_perl_path($path),
 431               \'PERL5LIB',
 432             ),
 433     PATH => _env_list_value(
 434               { interpolate => $interpolate, exists => 0, empty => '' },
 435               $class->install_base_bin_path($path),
 436               \'PATH',
 437             ),
 438   )
 439 }
 440
 441 sub active_paths {
 442   my ($class) = @_;
 443
 444   return () unless defined $ENV{PERL_LOCAL_LIB_ROOT};
 445   return grep { $_ ne '' } split /\Q$Config{path_sep}/, $ENV{PERL_LOCAL_LIB_ROOT};
 446 }
 447
 448 sub build_deactivate_environment_vars_for {
 449   my ($class, $path, $interpolate) = @_;
 450
 451   my @active_lls = $class->active_paths;
 452
 453   if (!grep { $_ eq $path } @active_lls) {
 454     warn "Tried to deactivate inactive local::lib '$path'\n";
 455     return ();
 456   }
 457
 458   my $perl_path = $class->install_base_perl_path($path);
 459   my $arch_path = $class->install_base_arch_path($path);
 460   my $bin_path = $class->install_base_bin_path($path);
 461
 462
 463   my %env = (
 464     PERL_LOCAL_LIB_ROOT => _env_list_value(
 465       {
 466         exists => 0,
 467       },
 468       grep { $_ ne $path } @active_lls
 469     ),
 470     PERL5LIB => _env_list_value(
 471       {
 472         exists => 0,
 473         filter => sub {
 474           $_ ne $perl_path && $_ ne $arch_path
 475         },
 476       },
 477       \'PERL5LIB',
 478     ),
 479     PATH => _env_list_value(
 480       {
 481         exists => 0,
 482         filter => sub { $_ ne $bin_path },
 483       },
 484       \'PATH',
 485     ),
 486   );
 487
 488   # If removing ourselves from the "top of the stack", set install paths to
 489   # correspond with the new top of stack.
 490   if ($active_lls[-1] eq $path) {
 491     my $new_top = $active_lls[-2];
 492     $env{PERL_MB_OPT} = defined($new_top) ? "--install_base ${new_top}" : undef;
 493     $env{PERL_MM_OPT} = defined($new_top) ? "INSTALL_BASE=${new_top}" : undef;
 494   }
 495
 496   return %env;
 497 }
 498
 499 sub build_deact_all_environment_vars_for {
 500   my ($class, $path, $interpolate) = @_;
 501
 502   my @active_lls = $class->active_paths;
 503
 504   my %perl_paths = map { (
 505       $class->install_base_perl_path($_) => 1,
 506       $class->install_base_arch_path($_) => 1
 507     ) } @active_lls;
 508   my %bin_paths = map { (
 509       $class->install_base_bin_path($_) => 1,
 510     ) } @active_lls;
 511
 512   my %env = (
 513     PERL_LOCAL_LIB_ROOT => undef,
 514     PERL_MM_OPT => undef,
 515     PERL_MB_OPT => undef,
 516     PERL5LIB => _env_list_value(
 517       {
 518         exists => 0,
 519         filter => sub {
 520           ! scalar grep { exists $perl_paths{$_} } $_[0]
 521         },
 522       },
 523       \'PERL5LIB'
 524     ),
 525     PATH => _env_list_value(
 526       {
 527         exists => 0,
 528         filter => sub {
 529           ! scalar grep { exists $bin_paths{$_} } $_[0]
 530         },
 531       },
 532       \'PATH'
 533     ),
 534   );
 535
 536   return %env;
 537 }
 538
 539 =begin testing
 540
 541 #:: test classmethod
 542
 543 File::Path::rmtree('t/var/splat');
 544
 545 $c->ensure_dir_structure_for('t/var/splat');
 546
 547 ok(-d 't/var/splat');
 548
 549 =end testing
 550
 551 =encoding utf8
 552
 553 =head1 NAME
 554
 555 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 556
 557 =head1 SYNOPSIS
 558
 559 In code -
 560
 561   use local::lib; # sets up a local lib at ~/perl5
 562
 563   use local::lib '~/foo'; # same, but ~/foo
 564
 565   # Or...
 566   use FindBin;
 567   use local::lib "$FindBin::Bin/../support";  # app-local support library
 568
 569 From the shell -
 570
 571   # Install LWP and its missing dependencies to the '~/perl5' directory
 572   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 573
 574   # Just print out useful shell commands
 575   $ perl -Mlocal::lib
 576   export PERL_MB_OPT='--install_base /home/username/perl5'
 577   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 578   export PERL5LIB='/home/username/perl5/lib/perl5/i386-linux:/home/username/perl5/lib/perl5'
 579   export PATH="/home/username/perl5/bin:$PATH"
 580
 581 =head2 The bootstrapping technique
 582
 583 A typical way to install local::lib is using what is known as the
 584 "bootstrapping" technique.  You would do this if your system administrator
 585 hasn't already installed local::lib.  In this case, you'll need to install
 586 local::lib in your home directory.
 587
 588 If you do have administrative privileges, you will still want to set up your
 589 environment variables, as discussed in step 4. Without this, you would still
 590 install the modules into the system CPAN installation and also your Perl scripts
 591 will not use the lib/ path you bootstrapped with local::lib.
 592
 593 By default local::lib installs itself and the CPAN modules into ~/perl5.
 594
 595 Windows users must also see L</Differences when using this module under Win32>.
 596
 597 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 598 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 599 or administrator.  Unpack the file in your home directory or in any other
 600 convenient location.
 601
 602 2. Run this:
 603
 604   perl Makefile.PL --bootstrap
 605
 606 If the system asks you whether it should automatically configure as much
 607 as possible, you would typically answer yes.
 608
 609 In order to install local::lib into a directory other than the default, you need
 610 to specify the name of the directory when you call bootstrap, as follows:
 611
 612   perl Makefile.PL --bootstrap=~/foo
 613
 614 3. Run this: (local::lib assumes you have make installed on your system)
 615
 616   make test && make install
 617
 618 4. Now we need to setup the appropriate environment variables, so that Perl
 619 starts using our newly generated lib/ directory. If you are using bash or
 620 any other Bourne shells, you can add this to your shell startup script this
 621 way:
 622
 623   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 624
 625 If you are using C shell, you can do this as follows:
 626
 627   /bin/csh
 628   echo $SHELL
 629   /bin/csh
 630   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 631
 632 If you passed to bootstrap a directory other than default, you also need to give that as
 633 import parameter to the call of the local::lib module like this way:
 634
 635   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 636
 637 After writing your shell configuration file, be sure to re-read it to get the
 638 changed settings into your current shell's environment. Bourne shells use
 639 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 640
 641 If you're on a slower machine, or are operating under draconian disk space
 642 limitations, you can disable the automatic generation of manpages from POD when
 643 installing modules by using the C<--no-manpages> argument when bootstrapping:
 644
 645   perl Makefile.PL --bootstrap --no-manpages
 646
 647 To avoid doing several bootstrap for several Perl module environments on the
 648 same account, for example if you use it for several different deployed
 649 applications independently, you can use one bootstrapped local::lib
 650 installation to install modules in different directories directly this way:
 651
 652   cd ~/mydir1
 653   perl -Mlocal::lib=./
 654   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 655   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 656   perl -MCPAN -e install ...    ### whatever modules you want
 657   cd ../mydir2
 658   ... REPEAT ...
 659
 660 If you are working with several C<local::lib> environments, you may want to
 661 remove some of them from the current environment without disturbing the others.
 662 You can deactivate one environment like this (using bourne sh):
 663
 664   eval $(perl -Mlocal::lib=--deactivate,~/path)
 665
 666 which will generate and run the commands needed to remove C<~/path> from your
 667 various search paths. Whichever environment was B<activated most recently> will
 668 remain the target for module installations. That is, if you activate
 669 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 670 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 671 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 672 installed in C<~/pathB> because pathB was activated later.
 673
 674 You can also ask C<local::lib> to clean itself completely out of the current
 675 shell's environment with the C<--deactivate-all> option.
 676 For multiple environments for multiple apps you may need to include a modified
 677 version of the C<< use FindBin >> instructions in the "In code" sample above.
 678 If you did something like the above, you have a set of Perl modules at C<<
 679 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 680 you need to tell it where to find the modules you installed for it at C<<
 681 ~/mydir1/lib >>.
 682
 683 In C<< ~/mydir1/scripts/myscript.pl >>:
 684
 685   use strict;
 686   use warnings;
 687   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 688   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 689
 690 Put this before any BEGIN { ... } blocks that require the modules you installed.
 691
 692 =head2 Differences when using this module under Win32
 693
 694 To set up the proper environment variables for your current session of
 695 C<CMD.exe>, you can use this:
 696
 697   C:\>perl -Mlocal::lib
 698   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 699   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 700   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread
 701   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 702
 703   ### To set the environment for this shell alone
 704   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 705   ### instead of $(perl -Mlocal::lib=./)
 706
 707 If you want the environment entries to persist, you'll need to add then to the
 708 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 709
 710 The "~" is translated to the user's profile directory (the directory named for
 711 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 712 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 713 directory is translated to a short name (which means the directory must exist)
 714 and the subdirectories are created.
 715
 716 =head1 RATIONALE
 717
 718 The version of a Perl package on your machine is not always the version you
 719 need.  Obviously, the best thing to do would be to update to the version you
 720 need.  However, you might be in a situation where you're prevented from doing
 721 this.  Perhaps you don't have system administrator privileges; or perhaps you
 722 are using a package management system such as Debian, and nobody has yet gotten
 723 around to packaging up the version you need.
 724
 725 local::lib solves this problem by allowing you to create your own directory of
 726 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 727 be within your own home directory).  The existing system Perl installation is
 728 not affected; you simply invoke Perl with special options so that Perl uses the
 729 packages in your own local package directory rather than the system packages.
 730 local::lib arranges things so that your locally installed version of the Perl
 731 packages takes precedence over the system installation.
 732
 733 If you are using a package management system (such as Debian), you don't need to
 734 worry about Debian and CPAN stepping on each other's toes.  Your local version
 735 of the packages will be written to an entirely separate directory from those
 736 installed by Debian.
 737
 738 =head1 DESCRIPTION
 739
 740 This module provides a quick, convenient way of bootstrapping a user-local Perl
 741 module library located within the user's home directory. It also constructs and
 742 prints out for the user the list of environment variables using the syntax
 743 appropriate for the user's current shell (as specified by the C<SHELL>
 744 environment variable), suitable for directly adding to one's shell
 745 configuration file.
 746
 747 More generally, local::lib allows for the bootstrapping and usage of a
 748 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 749 easier to ship an application with an app-specific copy of a Perl module, or
 750 collection of modules. Useful in cases like when an upstream maintainer hasn't
 751 applied a patch to a module of theirs that you need for your application.
 752
 753 On import, local::lib sets the following environment variables to appropriate
 754 values:
 755
 756 =over 4
 757
 758 =item PERL_MB_OPT
 759
 760 =item PERL_MM_OPT
 761
 762 =item PERL5LIB
 763
 764 =item PATH
 765
 766 PATH is appended to, rather than clobbered.
 767
 768 =back
 769
 770 These values are then available for reference by any code after import.
 771
 772 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 773
 774 See L<lib::core::only> for one way to do this - but note that
 775 there are a number of caveats, and the best approach is always to perform a
 776 build against a clean perl (i.e. site and vendor as close to empty as possible).
 777
 778 =head1 OPTIONS
 779
 780 Options are values that can be passed to the C<local::lib> import besides the
 781 directory to use. They are specified as C<use local::lib '--option'[, path];>
 782 or C<perl -Mlocal::lib=--option[,path]>.
 783
 784 =head2 --deactivate
 785
 786 Remove the chosen path (or the default path) from the module search paths if it
 787 was added by C<local::lib>, instead of adding it.
 788
 789 =head2 --deactivate-all
 790
 791 Remove all directories that were added to search paths by C<local::lib> from the
 792 search paths.
 793
 794 =head1 METHODS
 795
 796 =head2 ensure_dir_structure_for
 797
 798 =over 4
 799
 800 =item Arguments: $path
 801
 802 =item Return value: None
 803
 804 =back
 805
 806 Attempts to create the given path, and all required parent directories. Throws
 807 an exception on failure.
 808
 809 =head2 print_environment_vars_for
 810
 811 =over 4
 812
 813 =item Arguments: $path
 814
 815 =item Return value: None
 816
 817 =back
 818
 819 Prints to standard output the variables listed above, properly set to use the
 820 given path as the base directory.
 821
 822 =head2 build_environment_vars_for
 823
 824 =over 4
 825
 826 =item Arguments: $path, $interpolate
 827
 828 =item Return value: \%environment_vars
 829
 830 =back
 831
 832 Returns a hash with the variables listed above, properly set to use the
 833 given path as the base directory.
 834
 835 =head2 setup_env_hash_for
 836
 837 =over 4
 838
 839 =item Arguments: $path
 840
 841 =item Return value: None
 842
 843 =back
 844
 845 Constructs the C<%ENV> keys for the given path, by calling
 846 L</build_environment_vars_for>.
 847
 848 =head2 active_paths
 849
 850 =over 4
 851
 852 =item Arguments: None
 853
 854 =item Return value: @paths
 855
 856 =back
 857
 858 Returns a list of active C<local::lib> paths, according to the
 859 C<PERL_LOCAL_LIB_ROOT> environment variable.
 860
 861 =head2 install_base_perl_path
 862
 863 =over 4
 864
 865 =item Arguments: $path
 866
 867 =item Return value: $install_base_perl_path
 868
 869 =back
 870
 871 Returns a path describing where to install the Perl modules for this local
 872 library installation. Appends the directories C<lib> and C<perl5> to the given
 873 path.
 874
 875 =head2 install_base_arch_path
 876
 877 =over 4
 878
 879 =item Arguments: $path
 880
 881 =item Return value: $install_base_arch_path
 882
 883 =back
 884
 885 Returns a path describing where to install the architecture-specific Perl
 886 modules for this local library installation. Based on the
 887 L</install_base_perl_path> method's return value, and appends the value of
 888 C<$Config{archname}>.
 889
 890 =head2 install_base_bin_path
 891
 892 =over 4
 893
 894 =item Arguments: $path
 895
 896 =item Return value: $install_base_bin_path
 897
 898 =back
 899
 900 Returns a path describing where to install the executable programs for this
 901 local library installation. Based on the L</install_base_perl_path> method's
 902 return value, and appends the directory C<bin>.
 903
 904 =head2 resolve_empty_path
 905
 906 =over 4
 907
 908 =item Arguments: $path
 909
 910 =item Return value: $base_path
 911
 912 =back
 913
 914 Builds and returns the base path into which to set up the local module
 915 installation. Defaults to C<~/perl5>.
 916
 917 =head2 resolve_home_path
 918
 919 =over 4
 920
 921 =item Arguments: $path
 922
 923 =item Return value: $home_path
 924
 925 =back
 926
 927 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 928 for this purpose. If no definite answer is available, throws an exception.
 929
 930 =head2 resolve_relative_path
 931
 932 =over 4
 933
 934 =item Arguments: $path
 935
 936 =item Return value: $absolute_path
 937
 938 =back
 939
 940 Translates the given path into an absolute path.
 941
 942 =head2 resolve_path
 943
 944 =over 4
 945
 946 =item Arguments: $path
 947
 948 =item Return value: $absolute_path
 949
 950 =back
 951
 952 Calls the following in a pipeline, passing the result from the previous to the
 953 next, in an attempt to find where to configure the environment for a local
 954 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 955 L</resolve_relative_path>. Passes the given path argument to
 956 L</resolve_empty_path> which then returns a result that is passed to
 957 L</resolve_home_path>, which then has its result passed to
 958 L</resolve_relative_path>. The result of this final call is returned from
 959 L</resolve_path>.
 960
 961 =head1 A WARNING ABOUT UNINST=1
 962
 963 Be careful about using local::lib in combination with "make install UNINST=1".
 964 The idea of this feature is that will uninstall an old version of a module
 965 before installing a new one. However it lacks a safety check that the old
 966 version and the new version will go in the same directory. Used in combination
 967 with local::lib, you can potentially delete a globally accessible version of a
 968 module while installing the new version in a local place. Only combine "make
 969 install UNINST=1" and local::lib if you understand these possible consequences.
 970
 971 =head1 LIMITATIONS
 972
 973 The perl toolchain is unable to handle directory names with spaces in it,
 974 so you cant put your local::lib bootstrap into a directory with spaces. What
 975 you can do is moving your local::lib to a directory with spaces B<after> you
 976 installed all modules inside your local::lib bootstrap. But be aware that you
 977 cant update or install CPAN modules after the move.
 978
 979 Rather basic shell detection. Right now anything with csh in its name is
 980 assumed to be a C shell or something compatible, and everything else is assumed
 981 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 982 not set, a Bourne-compatible shell is assumed.
 983
 984 Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you
 985 have CPANPLUS installed.
 986
 987 Kills any existing PERL5LIB, PERL_MM_OPT or PERL_MB_OPT.
 988
 989 Should probably auto-fixup CPAN config if not already done.
 990
 991 Patches very much welcome for any of the above.
 992
 993 On Win32 systems, does not have a way to write the created environment variables
 994 to the registry, so that they can persist through a reboot.
 995
 996 =head1 TROUBLESHOOTING
 997
 998 If you've configured local::lib to install CPAN modules somewhere in to your
 999 home directory, and at some point later you try to install a module with C<cpan
1000 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1001 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1002 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1003 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1004 you've somehow lost your updated ExtUtils::MakeMaker module.
1005
1006 To remedy this situation, rerun the bootstrapping procedure documented above.
1007
1008 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1009
1010 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1011
1012 =head1 ENVIRONMENT
1013
1014 =over 4
1015
1016 =item SHELL
1017
1018 =item COMSPEC
1019
1020 local::lib looks at the user's C<SHELL> environment variable when printing out
1021 commands to add to the shell configuration file.
1022
1023 On Win32 systems, C<COMSPEC> is also examined.
1024
1025 =back
1026
1027 =head1 SUPPORT
1028
1029 IRC:
1030
1031     Join #local-lib on irc.perl.org.
1032
1033 =head1 AUTHOR
1034
1035 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1036
1037 auto_install fixes kindly sponsored by http://www.takkle.com/
1038
1039 =head1 CONTRIBUTORS
1040
1041 Patches to correctly output commands for csh style shells, as well as some
1042 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1043
1044 Doc patches for a custom local::lib directory, more cleanups in the english
1045 documentation and a L<german documentation|POD2::DE::local::lib> contributed by Torsten Raudssus
1046 <torsten@raudssus.de>.
1047
1048 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1049 things will install properly, submitted a fix for the bug causing problems with
1050 writing Makefiles during bootstrapping, contributed an example program, and
1051 submitted yet another fix to ensure that local::lib can install and bootstrap
1052 properly. Many, many thanks!
1053
1054 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1055 section. Many thanks!
1056
1057 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1058
1059 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1060 by a patch from Marco Emilio Poleggi.
1061
1062 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1063 '--self-contained' option.
1064
1065 Documentation patches to make win32 usage clearer by
1066 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1067
1068 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc patches contributed by Breno
1069 G. de Oliveira <garu@cpan.org>.
1070
1071 Improvements to stacking multiple local::lib dirs and removing them from the
1072 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1073
1074 Patch for Carp version mismatch contributed by Hakim Cassimally <osfameron@cpan.org>.
1075
1076 =head1 COPYRIGHT
1077
1078 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1079 listed above.
1080
1081 =head1 LICENSE
1082
1083 This library is free software and may be distributed under the same terms
1084 as perl itself.
1085
1086 =cut
1087
1088 1;