lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.008001; # probably works with earlier versions but I'm not supporting them
   7               # (patches would, of course, be welcome)
   8
   9 use File::Spec ();
  10 use File::Path ();
  11 use Carp ();
  12 use Config;
  13
  14 our $VERSION = '1.008001'; # 1.8.1
  15
  16 our @KNOWN_FLAGS = qw(--self-contained --deactivate --deactivate-all);
  17
  18 sub DEACTIVATE_ONE () { 1 }
  19 sub DEACTIVATE_ALL () { 2 }
  20
  21 sub import {
  22   my ($class, @args) = @_;
  23
  24   # Remember what PERL5LIB was when we started
  25   my $perl5lib = $ENV{PERL5LIB} || '';
  26
  27   my %arg_store;
  28   for my $arg (@args) {
  29     # check for lethal dash first to stop processing before causing problems
  30     if ($arg =~ /−/) {
  31       die <<'DEATH';
  32 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  33 These are *not* the traditional -- dashes that software recognizes. You
  34 probably got these by copy-pasting from the perldoc for this module as
  35 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  36 terminal, but can happen elsewhere too. Please try again after replacing the
  37 dashes with normal minus signs.
  38 DEATH
  39     }
  40     elsif(grep { $arg eq $_ } @KNOWN_FLAGS) {
  41       (my $flag = $arg) =~ s/--//;
  42       $arg_store{$flag} = 1;
  43     }
  44     elsif($arg =~ /^--/) {
  45       die "Unknown import argument: $arg";
  46     }
  47     else {
  48       # assume that what's left is a path
  49       $arg_store{path} = $arg;
  50     }
  51   }
  52
  53   if($arg_store{'self-contained'}) {
  54     die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  55   }
  56
  57   my $deactivating = 0;
  58   if ($arg_store{deactivate}) {
  59     $deactivating = DEACTIVATE_ONE;
  60   }
  61   if ($arg_store{'deactivate-all'}) {
  62     $deactivating = DEACTIVATE_ALL;
  63   }
  64
  65   $arg_store{path} = $class->resolve_path($arg_store{path});
  66   $class->setup_local_lib_for($arg_store{path}, $deactivating);
  67
  68   for (@INC) { # Untaint @INC
  69     next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc.
  70     m/(.*)/ and $_ = $1;
  71   }
  72 }
  73
  74 sub pipeline;
  75
  76 sub pipeline {
  77   my @methods = @_;
  78   my $last = pop(@methods);
  79   if (@methods) {
  80     \sub {
  81       my ($obj, @args) = @_;
  82       $obj->${pipeline @methods}(
  83         $obj->$last(@args)
  84       );
  85     };
  86   } else {
  87     \sub {
  88       shift->$last(@_);
  89     };
  90   }
  91 }
  92
  93 =begin testing
  94
  95 #:: test pipeline
  96
  97 package local::lib;
  98
  99 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 100 my $foo = bless({}, 'Foo');
 101 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 102
 103 =end testing
 104
 105 =cut
 106
 107 sub _uniq {
 108     my %seen;
 109     grep { ! $seen{$_}++ } @_;
 110 }
 111
 112 sub resolve_path {
 113   my ($class, $path) = @_;
 114   $class->${pipeline qw(
 115     resolve_relative_path
 116     resolve_home_path
 117     resolve_empty_path
 118   )}($path);
 119 }
 120
 121 sub resolve_empty_path {
 122   my ($class, $path) = @_;
 123   if (defined $path) {
 124     $path;
 125   } else {
 126     '~/perl5';
 127   }
 128 }
 129
 130 =begin testing
 131
 132 #:: test classmethod setup
 133
 134 my $c = 'local::lib';
 135
 136 =end testing
 137
 138 =begin testing
 139
 140 #:: test classmethod
 141
 142 is($c->resolve_empty_path, '~/perl5');
 143 is($c->resolve_empty_path('foo'), 'foo');
 144
 145 =end testing
 146
 147 =cut
 148
 149 sub resolve_home_path {
 150   my ($class, $path) = @_;
 151   return $path unless ($path =~ /^~/);
 152   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 153   my $tried_file_homedir;
 154   my $homedir = do {
 155     if (eval { require File::HomeDir } && $File::HomeDir::VERSION >= 0.65) {
 156       $tried_file_homedir = 1;
 157       if (defined $user) {
 158         File::HomeDir->users_home($user);
 159       } else {
 160         File::HomeDir->my_home;
 161       }
 162     } else {
 163       if (defined $user) {
 164         (getpwnam $user)[7];
 165       } else {
 166         if (defined $ENV{HOME}) {
 167           $ENV{HOME};
 168         } else {
 169           (getpwuid $<)[7];
 170         }
 171       }
 172     }
 173   };
 174   unless (defined $homedir) {
 175     Carp::croak(
 176       "Couldn't resolve homedir for "
 177       .(defined $user ? $user : 'current user')
 178       .($tried_file_homedir ? '' : ' - consider installing File::HomeDir')
 179     );
 180   }
 181   $path =~ s/^~[^\/]*/$homedir/;
 182   $path;
 183 }
 184
 185 sub resolve_relative_path {
 186   my ($class, $path) = @_;
 187   $path = File::Spec->rel2abs($path);
 188 }
 189
 190 =begin testing
 191
 192 #:: test classmethod
 193
 194 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 195 is($c->resolve_relative_path('bar'),'FOObar');
 196
 197 =end testing
 198
 199 =cut
 200
 201 sub setup_local_lib_for {
 202   my ($class, $path, $deactivating) = @_;
 203   $path = $class->ensure_dir_structure_for($path) unless $deactivating;
 204   if ($0 eq '-') {
 205     $class->print_environment_vars_for($path, $deactivating);
 206     exit 0;
 207   } else {
 208     $class->setup_env_hash_for($path, $deactivating);
 209     @INC = _uniq(split($Config{path_sep}, $ENV{PERL5LIB}), @INC);
 210   }
 211 }
 212
 213 sub install_base_bin_path {
 214   my ($class, $path) = @_;
 215   File::Spec->catdir($path, 'bin');
 216 }
 217
 218 sub install_base_perl_path {
 219   my ($class, $path) = @_;
 220   File::Spec->catdir($path, 'lib', 'perl5');
 221 }
 222
 223 sub install_base_arch_path {
 224   my ($class, $path) = @_;
 225   File::Spec->catdir($class->install_base_perl_path($path), $Config{archname});
 226 }
 227
 228 sub ensure_dir_structure_for {
 229   my ($class, $path) = @_;
 230   unless (-d $path) {
 231     warn "Attempting to create directory ${path}\n";
 232   }
 233   File::Path::mkpath($path);
 234   # Need to have the path exist to make a short name for it, so
 235   # converting to a short name here.
 236   $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32';
 237
 238   return $path;
 239 }
 240
 241 sub INTERPOLATE_ENV () { 1 }
 242 sub LITERAL_ENV     () { 0 }
 243
 244 sub guess_shelltype {
 245   my $shellbin = 'sh';
 246   if(defined $ENV{'SHELL'}) {
 247       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 248       $shellbin = $shell_bin_path_parts[-1];
 249   }
 250   my $shelltype = do {
 251       local $_ = $shellbin;
 252       if(/csh/) {
 253           'csh'
 254       } else {
 255           'bourne'
 256       }
 257   };
 258
 259   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 260   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 261       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 262       $shellbin = $shell_bin_path_parts[-1];
 263          $shelltype = do {
 264                  local $_ = $shellbin;
 265                  if(/command\.com/) {
 266                          'win32'
 267                  } elsif(/cmd\.exe/) {
 268                          'win32'
 269                  } elsif(/4nt\.exe/) {
 270                          'win32'
 271                  } else {
 272                          $shelltype
 273                  }
 274          };
 275   }
 276   return $shelltype;
 277 }
 278
 279 sub print_environment_vars_for {
 280   my ($class, $path, $deactivating) = @_;
 281   print $class->environment_vars_string_for($path, $deactivating);
 282 }
 283
 284 sub environment_vars_string_for {
 285   my ($class, $path, $deactivating) = @_;
 286   my @envs = $class->build_environment_vars_for($path, $deactivating, LITERAL_ENV);
 287   my $out = '';
 288
 289   # rather basic csh detection, goes on the assumption that something won't
 290   # call itself csh unless it really is. also, default to bourne in the
 291   # pathological situation where a user doesn't have $ENV{SHELL} defined.
 292   # note also that shells with funny names, like zoid, are assumed to be
 293   # bourne.
 294
 295   my $shelltype = $class->guess_shelltype;
 296
 297   while (@envs) {
 298     my ($name, $value) = (shift(@envs), shift(@envs));
 299     $value =~ s/(\\")/\\$1/g if defined $value;
 300     $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value);
 301   }
 302   return $out;
 303 }
 304
 305 # simple routines that take two arguments: an %ENV key and a value. return
 306 # strings that are suitable for passing directly to the relevant shell to set
 307 # said key to said value.
 308 sub build_bourne_env_declaration {
 309   my $class = shift;
 310   my($name, $value) = @_;
 311   return defined($value) ? qq{export ${name}="${value}";\n} : qq{unset ${name};\n};
 312 }
 313
 314 sub build_csh_env_declaration {
 315   my $class = shift;
 316   my($name, $value) = @_;
 317   return defined($value) ? qq{setenv ${name} "${value}"\n} : qq{unsetenv ${name}\n};
 318 }
 319
 320 sub build_win32_env_declaration {
 321   my $class = shift;
 322   my($name, $value) = @_;
 323   return defined($value) ? qq{set ${name}=${value}\n} : qq{set ${name}=\n};
 324 }
 325
 326 sub setup_env_hash_for {
 327   my ($class, $path, $deactivating) = @_;
 328   my %envs = $class->build_environment_vars_for($path, $deactivating, INTERPOLATE_ENV);
 329   @ENV{keys %envs} = values %envs;
 330 }
 331
 332 sub build_environment_vars_for {
 333   my ($class, $path, $deactivating, $interpolate) = @_;
 334
 335   if ($deactivating == DEACTIVATE_ONE) {
 336     return $class->build_deactivate_environment_vars_for($path, $interpolate);
 337   } elsif ($deactivating == DEACTIVATE_ALL) {
 338     return $class->build_deact_all_environment_vars_for($path, $interpolate);
 339   } else {
 340     return $class->build_activate_environment_vars_for($path, $interpolate);
 341   }
 342 }
 343
 344 sub build_activate_environment_vars_for {
 345   my ($class, $path, $interpolate) = @_;
 346   return (
 347     PERL_LOCAL_LIB_ROOT => join($Config{path_sep},
 348               (($ENV{PERL_LOCAL_LIB_ROOT}||()) ?
 349                 ($interpolate == INTERPOLATE_ENV
 350                   ? ($ENV{PERL_LOCAL_LIB_ROOT}||())
 351                   : (($^O ne 'MSWin32') ? '$PERL_LOCAL_LIB_ROOT'
 352                     : '%PERL_LOCAL_LIB_ROOT%' ))
 353                 : ()),
 354                 $path
 355             ),
 356     PERL_MB_OPT => "--install_base ${path}",
 357     PERL_MM_OPT => "INSTALL_BASE=${path}",
 358     PERL5LIB => join($Config{path_sep},
 359                   $class->install_base_arch_path($path),
 360                   $class->install_base_perl_path($path),
 361                   (($ENV{PERL5LIB}||()) ?
 362                     ($interpolate == INTERPOLATE_ENV
 363                       ? ($ENV{PERL5LIB})
 364                       : (($^O ne 'MSWin32') ? '$PERL5LIB' : '%PERL5LIB%' ))
 365                     : ())
 366                 ),
 367     PATH => join($Config{path_sep},
 368               $class->install_base_bin_path($path),
 369               ($interpolate == INTERPOLATE_ENV
 370                 ? ($ENV{PATH}||())
 371                 : (($^O ne 'MSWin32') ? '$PATH' : '%PATH%' ))
 372              ),
 373   )
 374 }
 375
 376 sub build_deactivate_environment_vars_for {
 377   my ($class, $path, $interpolate) = @_;
 378
 379   my @active_lls = split /\Q$Config{path_sep}/, $ENV{PERL_LOCAL_LIB_ROOT} || '';
 380
 381   if (!grep { $_ eq $path } @active_lls) {
 382     warn "Tried to deactivate inactive local::lib '$path'\n";
 383     return ();
 384   }
 385
 386   my @new_ll_root = grep { $_ ne $path } @active_lls;
 387   my @new_perl5lib = grep {
 388     $_ ne $class->install_base_arch_path($path) &&
 389     $_ ne $class->install_base_perl_path($path)
 390   } split /\Q$Config{path_sep}/, $ENV{PERL5LIB};
 391
 392   my %env = (
 393     PERL_LOCAL_LIB_ROOT => (@new_ll_root ?
 394       join($Config{path_sep}, @new_ll_root) : undef
 395     ),
 396     PERL5LIB => (@new_perl5lib ?
 397       join($Config{path_sep}, @new_perl5lib) : undef
 398     ),
 399     PATH => join($Config{path_sep},
 400       grep { $_ ne $class->install_base_bin_path($path) }
 401       split /\Q$Config{path_sep}/, $ENV{PATH}
 402     ),
 403   );
 404
 405   # If removing ourselves from the "top of the stack", set install paths to
 406   # correspond with the new top of stack.
 407   if ($active_lls[-1] eq $path) {
 408     if (@active_lls > 1) {
 409       my $new_top = $active_lls[-2];
 410       %env = (%env,
 411         PERL_MB_OPT => "--install_base ${new_top}",
 412         PERL_MM_OPT => "INSTALL_BASE=${new_top}",
 413       );
 414     } else {
 415       %env = (%env,
 416         PERL_MB_OPT => undef,
 417         PERL_MM_OPT => undef,
 418       );
 419     }
 420   }
 421
 422   return %env;
 423 }
 424
 425 sub build_deact_all_environment_vars_for {
 426   my ($class, $path, $interpolate) = @_;
 427
 428   my @active_lls = split /\Q$Config{path_sep}/, $ENV{PERL_LOCAL_LIB_ROOT} || '';
 429
 430   my @new_perl5lib = split /\Q$Config{path_sep}/, $ENV{PERL5LIB};
 431   my @new_path = split /\Q$Config{path_sep}/, $ENV{PATH};
 432
 433   for my $path (@active_lls) {
 434     @new_perl5lib = grep {
 435       $_ ne $class->install_base_arch_path($path) &&
 436       $_ ne $class->install_base_perl_path($path)
 437     } @new_perl5lib;
 438
 439     @new_path = grep {
 440       $_ ne $class->install_base_bin_path($path)
 441     } @new_path;
 442   }
 443
 444   my %env = (
 445     PERL_LOCAL_LIB_ROOT => undef,
 446     PERL_MM_OPT => undef,
 447     PERL_MB_OPT => undef,
 448     PERL5LIB => (@new_perl5lib ?
 449       join($Config{path_sep}, @new_perl5lib) : undef
 450     ),
 451     PATH => join($Config{path_sep}, @new_path),
 452   );
 453
 454   return %env;
 455 }
 456
 457 =begin testing
 458
 459 #:: test classmethod
 460
 461 File::Path::rmtree('t/var/splat');
 462
 463 $c->ensure_dir_structure_for('t/var/splat');
 464
 465 ok(-d 't/var/splat');
 466
 467 =end testing
 468
 469 =encoding utf8
 470
 471 =head1 NAME
 472
 473 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 474
 475 =head1 SYNOPSIS
 476
 477 In code -
 478
 479   use local::lib; # sets up a local lib at ~/perl5
 480
 481   use local::lib '~/foo'; # same, but ~/foo
 482
 483   # Or...
 484   use FindBin;
 485   use local::lib "$FindBin::Bin/../support";  # app-local support library
 486
 487 From the shell -
 488
 489   # Install LWP and its missing dependencies to the '~/perl5' directory
 490   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 491
 492   # Just print out useful shell commands
 493   $ perl -Mlocal::lib
 494   export PERL_MB_OPT='--install_base /home/username/perl5'
 495   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 496   export PERL5LIB='/home/username/perl5/lib/perl5/i386-linux:/home/username/perl5/lib/perl5'
 497   export PATH="/home/username/perl5/bin:$PATH"
 498
 499 =head2 The bootstrapping technique
 500
 501 A typical way to install local::lib is using what is known as the
 502 "bootstrapping" technique.  You would do this if your system administrator
 503 hasn't already installed local::lib.  In this case, you'll need to install
 504 local::lib in your home directory.
 505
 506 If you do have administrative privileges, you will still want to set up your
 507 environment variables, as discussed in step 4. Without this, you would still
 508 install the modules into the system CPAN installation and also your Perl scripts
 509 will not use the lib/ path you bootstrapped with local::lib.
 510
 511 By default local::lib installs itself and the CPAN modules into ~/perl5.
 512
 513 Windows users must also see L</Differences when using this module under Win32>.
 514
 515 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 516 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 517 or administrator.  Unpack the file in your home directory or in any other
 518 convenient location.
 519
 520 2. Run this:
 521
 522   perl Makefile.PL --bootstrap
 523
 524 If the system asks you whether it should automatically configure as much
 525 as possible, you would typically answer yes.
 526
 527 In order to install local::lib into a directory other than the default, you need
 528 to specify the name of the directory when you call bootstrap, as follows:
 529
 530   perl Makefile.PL --bootstrap=~/foo
 531
 532 3. Run this: (local::lib assumes you have make installed on your system)
 533
 534   make test && make install
 535
 536 4. Now we need to setup the appropriate environment variables, so that Perl
 537 starts using our newly generated lib/ directory. If you are using bash or
 538 any other Bourne shells, you can add this to your shell startup script this
 539 way:
 540
 541   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 542
 543 If you are using C shell, you can do this as follows:
 544
 545   /bin/csh
 546   echo $SHELL
 547   /bin/csh
 548   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 549
 550 If you passed to bootstrap a directory other than default, you also need to give that as
 551 import parameter to the call of the local::lib module like this way:
 552
 553   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 554
 555 After writing your shell configuration file, be sure to re-read it to get the
 556 changed settings into your current shell's environment. Bourne shells use
 557 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 558
 559 If you're on a slower machine, or are operating under draconian disk space
 560 limitations, you can disable the automatic generation of manpages from POD when
 561 installing modules by using the C<--no-manpages> argument when bootstrapping:
 562
 563   perl Makefile.PL --bootstrap --no-manpages
 564
 565 To avoid doing several bootstrap for several Perl module environments on the
 566 same account, for example if you use it for several different deployed
 567 applications independently, you can use one bootstrapped local::lib
 568 installation to install modules in different directories directly this way:
 569
 570   cd ~/mydir1
 571   perl -Mlocal::lib=./
 572   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 573   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 574   perl -MCPAN -e install ...    ### whatever modules you want
 575   cd ../mydir2
 576   ... REPEAT ...
 577
 578 If you are working with several C<local::lib> environments, you may want to
 579 remove some of them from the current environment without disturbing the others.
 580 You can deactivate one environment like this (using bourne sh):
 581
 582   eval $(perl -Mlocal::lib=--deactivate,~/path)
 583
 584 which will generate and run the commands needed to remove C<~/path> from your
 585 various search paths. Whichever environment was B<activated most recently> will
 586 remain the target for module installations. That is, if you activate
 587 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 588 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 589 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 590 installed in C<~/pathB> because pathB was activated later.
 591
 592 You can also ask C<local::lib> to clean itself completely out of the current
 593 shell's environment with the C<--deactivate-all> option.
 594 For multiple environments for multiple apps you may need to include a modified
 595 version of the C<< use FindBin >> instructions in the "In code" sample above.
 596 If you did something like the above, you have a set of Perl modules at C<<
 597 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 598 you need to tell it where to find the modules you installed for it at C<<
 599 ~/mydir1/lib >>.
 600
 601 In C<< ~/mydir1/scripts/myscript.pl >>:
 602
 603   use strict;
 604   use warnings;
 605   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 606   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 607
 608 Put this before any BEGIN { ... } blocks that require the modules you installed.
 609
 610 =head2 Differences when using this module under Win32
 611
 612 To set up the proper environment variables for your current session of
 613 C<CMD.exe>, you can use this:
 614
 615   C:\>perl -Mlocal::lib
 616   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 617   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 618   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread
 619   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 620
 621   ### To set the environment for this shell alone
 622   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\temp.bat
 623   ### instead of $(perl -Mlocal::lib=./)
 624
 625 If you want the environment entries to persist, you'll need to add then to the
 626 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 627
 628 The "~" is translated to the user's profile directory (the directory named for
 629 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 630 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 631 directory is translated to a short name (which means the directory must exist)
 632 and the subdirectories are created.
 633
 634 =head1 RATIONALE
 635
 636 The version of a Perl package on your machine is not always the version you
 637 need.  Obviously, the best thing to do would be to update to the version you
 638 need.  However, you might be in a situation where you're prevented from doing
 639 this.  Perhaps you don't have system administrator privileges; or perhaps you
 640 are using a package management system such as Debian, and nobody has yet gotten
 641 around to packaging up the version you need.
 642
 643 local::lib solves this problem by allowing you to create your own directory of
 644 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 645 be within your own home directory).  The existing system Perl installation is
 646 not affected; you simply invoke Perl with special options so that Perl uses the
 647 packages in your own local package directory rather than the system packages.
 648 local::lib arranges things so that your locally installed version of the Perl
 649 packages takes precedence over the system installation.
 650
 651 If you are using a package management system (such as Debian), you don't need to
 652 worry about Debian and CPAN stepping on each other's toes.  Your local version
 653 of the packages will be written to an entirely separate directory from those
 654 installed by Debian.
 655
 656 =head1 DESCRIPTION
 657
 658 This module provides a quick, convenient way of bootstrapping a user-local Perl
 659 module library located within the user's home directory. It also constructs and
 660 prints out for the user the list of environment variables using the syntax
 661 appropriate for the user's current shell (as specified by the C<SHELL>
 662 environment variable), suitable for directly adding to one's shell
 663 configuration file.
 664
 665 More generally, local::lib allows for the bootstrapping and usage of a
 666 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 667 easier to ship an application with an app-specific copy of a Perl module, or
 668 collection of modules. Useful in cases like when an upstream maintainer hasn't
 669 applied a patch to a module of theirs that you need for your application.
 670
 671 On import, local::lib sets the following environment variables to appropriate
 672 values:
 673
 674 =over 4
 675
 676 =item PERL_MB_OPT
 677
 678 =item PERL_MM_OPT
 679
 680 =item PERL5LIB
 681
 682 =item PATH
 683
 684 PATH is appended to, rather than clobbered.
 685
 686 =back
 687
 688 These values are then available for reference by any code after import.
 689
 690 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 691
 692 See L<lib::core::only> for one way to do this - but note that
 693 there are a number of caveats, and the best approach is always to perform a
 694 build against a clean perl (i.e. site and vendor as close to empty as possible).
 695
 696 =head1 OPTIONS
 697
 698 Options are values that can be passed to the C<local::lib> import besides the
 699 directory to use. They are specified as C<use local::lib '--option'[, path];>
 700 or C<perl -Mlocal::lib=--option[,path]>.
 701
 702 =head2 --deactivate
 703
 704 Remove the chosen path (or the default path) from the module search paths if it
 705 was added by C<local::lib>, instead of adding it.
 706
 707 =head2 --deactivate-all
 708
 709 Remove all directories that were added to search paths by C<local::lib> from the
 710 search paths.
 711
 712 =head1 METHODS
 713
 714 =head2 ensure_dir_structure_for
 715
 716 =over 4
 717
 718 =item Arguments: $path
 719
 720 =item Return value: None
 721
 722 =back
 723
 724 Attempts to create the given path, and all required parent directories. Throws
 725 an exception on failure.
 726
 727 =head2 print_environment_vars_for
 728
 729 =over 4
 730
 731 =item Arguments: $path
 732
 733 =item Return value: None
 734
 735 =back
 736
 737 Prints to standard output the variables listed above, properly set to use the
 738 given path as the base directory.
 739
 740 =head2 build_environment_vars_for
 741
 742 =over 4
 743
 744 =item Arguments: $path, $interpolate
 745
 746 =item Return value: \%environment_vars
 747
 748 =back
 749
 750 Returns a hash with the variables listed above, properly set to use the
 751 given path as the base directory.
 752
 753 =head2 setup_env_hash_for
 754
 755 =over 4
 756
 757 =item Arguments: $path
 758
 759 =item Return value: None
 760
 761 =back
 762
 763 Constructs the C<%ENV> keys for the given path, by calling
 764 L</build_environment_vars_for>.
 765
 766 =head2 install_base_perl_path
 767
 768 =over 4
 769
 770 =item Arguments: $path
 771
 772 =item Return value: $install_base_perl_path
 773
 774 =back
 775
 776 Returns a path describing where to install the Perl modules for this local
 777 library installation. Appends the directories C<lib> and C<perl5> to the given
 778 path.
 779
 780 =head2 install_base_arch_path
 781
 782 =over 4
 783
 784 =item Arguments: $path
 785
 786 =item Return value: $install_base_arch_path
 787
 788 =back
 789
 790 Returns a path describing where to install the architecture-specific Perl
 791 modules for this local library installation. Based on the
 792 L</install_base_perl_path> method's return value, and appends the value of
 793 C<$Config{archname}>.
 794
 795 =head2 install_base_bin_path
 796
 797 =over 4
 798
 799 =item Arguments: $path
 800
 801 =item Return value: $install_base_bin_path
 802
 803 =back
 804
 805 Returns a path describing where to install the executable programs for this
 806 local library installation. Based on the L</install_base_perl_path> method's
 807 return value, and appends the directory C<bin>.
 808
 809 =head2 resolve_empty_path
 810
 811 =over 4
 812
 813 =item Arguments: $path
 814
 815 =item Return value: $base_path
 816
 817 =back
 818
 819 Builds and returns the base path into which to set up the local module
 820 installation. Defaults to C<~/perl5>.
 821
 822 =head2 resolve_home_path
 823
 824 =over 4
 825
 826 =item Arguments: $path
 827
 828 =item Return value: $home_path
 829
 830 =back
 831
 832 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 833 for this purpose. If no definite answer is available, throws an exception.
 834
 835 =head2 resolve_relative_path
 836
 837 =over 4
 838
 839 =item Arguments: $path
 840
 841 =item Return value: $absolute_path
 842
 843 =back
 844
 845 Translates the given path into an absolute path.
 846
 847 =head2 resolve_path
 848
 849 =over 4
 850
 851 =item Arguments: $path
 852
 853 =item Return value: $absolute_path
 854
 855 =back
 856
 857 Calls the following in a pipeline, passing the result from the previous to the
 858 next, in an attempt to find where to configure the environment for a local
 859 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 860 L</resolve_relative_path>. Passes the given path argument to
 861 L</resolve_empty_path> which then returns a result that is passed to
 862 L</resolve_home_path>, which then has its result passed to
 863 L</resolve_relative_path>. The result of this final call is returned from
 864 L</resolve_path>.
 865
 866 =head1 A WARNING ABOUT UNINST=1
 867
 868 Be careful about using local::lib in combination with "make install UNINST=1".
 869 The idea of this feature is that will uninstall an old version of a module
 870 before installing a new one. However it lacks a safety check that the old
 871 version and the new version will go in the same directory. Used in combination
 872 with local::lib, you can potentially delete a globally accessible version of a
 873 module while installing the new version in a local place. Only combine "make
 874 install UNINST=1" and local::lib if you understand these possible consequences.
 875
 876 =head1 LIMITATIONS
 877
 878 The perl toolchain is unable to handle directory names with spaces in it,
 879 so you cant put your local::lib bootstrap into a directory with spaces. What
 880 you can do is moving your local::lib to a directory with spaces B<after> you
 881 installed all modules inside your local::lib bootstrap. But be aware that you
 882 cant update or install CPAN modules after the move.
 883
 884 Rather basic shell detection. Right now anything with csh in its name is
 885 assumed to be a C shell or something compatible, and everything else is assumed
 886 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 887 not set, a Bourne-compatible shell is assumed.
 888
 889 Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you
 890 have CPANPLUS installed.
 891
 892 Kills any existing PERL5LIB, PERL_MM_OPT or PERL_MB_OPT.
 893
 894 Should probably auto-fixup CPAN config if not already done.
 895
 896 Patches very much welcome for any of the above.
 897
 898 On Win32 systems, does not have a way to write the created environment variables
 899 to the registry, so that they can persist through a reboot.
 900
 901 =head1 TROUBLESHOOTING
 902
 903 If you've configured local::lib to install CPAN modules somewhere in to your
 904 home directory, and at some point later you try to install a module with C<cpan
 905 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
 906 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
 907 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
 908 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
 909 you've somehow lost your updated ExtUtils::MakeMaker module.
 910
 911 To remedy this situation, rerun the bootstrapping procedure documented above.
 912
 913 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
 914
 915 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
 916
 917 =head1 ENVIRONMENT
 918
 919 =over 4
 920
 921 =item SHELL
 922
 923 =item COMSPEC
 924
 925 local::lib looks at the user's C<SHELL> environment variable when printing out
 926 commands to add to the shell configuration file.
 927
 928 On Win32 systems, C<COMSPEC> is also examined.
 929
 930 =back
 931
 932 =head1 SUPPORT
 933
 934 IRC:
 935
 936     Join #local-lib on irc.perl.org.
 937
 938 =head1 AUTHOR
 939
 940 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
 941
 942 auto_install fixes kindly sponsored by http://www.takkle.com/
 943
 944 =head1 CONTRIBUTORS
 945
 946 Patches to correctly output commands for csh style shells, as well as some
 947 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
 948
 949 Doc patches for a custom local::lib directory, more cleanups in the english
 950 documentation and a L<german documentation|POD2::DE::local::lib> contributed by Torsten Raudssus
 951 <torsten@raudssus.de>.
 952
 953 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
 954 things will install properly, submitted a fix for the bug causing problems with
 955 writing Makefiles during bootstrapping, contributed an example program, and
 956 submitted yet another fix to ensure that local::lib can install and bootstrap
 957 properly. Many, many thanks!
 958
 959 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
 960 section. Many thanks!
 961
 962 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
 963
 964 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
 965 by a patch from Marco Emilio Poleggi.
 966
 967 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
 968 '--self-contained' option.
 969
 970 Documentation patches to make win32 usage clearer by
 971 David Mertens <dcmertens.perl@gmail.com> (run4flat).
 972
 973 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc patches contributed by Breno
 974 G. de Oliveira <garu@cpan.org>.
 975
 976 =head1 COPYRIGHT
 977
 978 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
 979 listed above.
 980
 981 =head1 LICENSE
 982
 983 This library is free software and may be distributed under the same terms
 984 as perl itself.
 985
 986 =cut
 987
 988 1;