lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.008001; # probably works with earlier versions but I'm not supporting them
   7               # (patches would, of course, be welcome)
   8
   9 use File::Spec ();
  10 use File::Path ();
  11 use Carp ();
  12 use Config;
  13
  14 our $VERSION = '1.006002'; # 1.6.2
  15
  16 our @KNOWN_FLAGS = qw(--self-contained);
  17
  18 sub import {
  19   my ($class, @args) = @_;
  20
  21   # Remember what PERL5LIB was when we started
  22   my $perl5lib = $ENV{PERL5LIB} || '';
  23
  24   my %arg_store;
  25   for my $arg (@args) {
  26     # check for lethal dash first to stop processing before causing problems
  27     if ($arg =~ /−/) {
  28       die <<'DEATH';
  29 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  30 These are *not* the traditional -- dashes that software recognizes. You
  31 probably got these by copy-pasting from the perldoc for this module as
  32 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  33 terminal, but can happen elsewhere too. Please try again after replacing the
  34 dashes with normal minus signs.
  35 DEATH
  36     }
  37     elsif(grep { $arg eq $_ } @KNOWN_FLAGS) {
  38       (my $flag = $arg) =~ s/--//;
  39       $arg_store{$flag} = 1;
  40     }
  41     elsif($arg =~ /^--/) {
  42       die "Unknown import argument: $arg";
  43     }
  44     else {
  45       # assume that what's left is a path
  46       $arg_store{path} = $arg;
  47     }
  48   }
  49
  50   if($arg_store{'self-contained'}) {
  51     die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  52   }
  53
  54   $arg_store{path} = $class->resolve_path($arg_store{path});
  55   $class->setup_local_lib_for($arg_store{path});
  56
  57   for (@INC) { # Untaint @INC
  58     next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc.
  59     m/(.*)/ and $_ = $1;
  60   }
  61 }
  62
  63 sub pipeline;
  64
  65 sub pipeline {
  66   my @methods = @_;
  67   my $last = pop(@methods);
  68   if (@methods) {
  69     \sub {
  70       my ($obj, @args) = @_;
  71       $obj->${pipeline @methods}(
  72         $obj->$last(@args)
  73       );
  74     };
  75   } else {
  76     \sub {
  77       shift->$last(@_);
  78     };
  79   }
  80 }
  81
  82 =begin testing
  83
  84 #:: test pipeline
  85
  86 package local::lib;
  87
  88 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
  89 my $foo = bless({}, 'Foo');
  90 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
  91
  92 =end testing
  93
  94 =cut
  95
  96 sub _uniq {
  97     my %seen;
  98     grep { ! $seen{$_}++ } @_;
  99 }
 100
 101 sub resolve_path {
 102   my ($class, $path) = @_;
 103   $class->${pipeline qw(
 104     resolve_relative_path
 105     resolve_home_path
 106     resolve_empty_path
 107   )}($path);
 108 }
 109
 110 sub resolve_empty_path {
 111   my ($class, $path) = @_;
 112   if (defined $path) {
 113     $path;
 114   } else {
 115     '~/perl5';
 116   }
 117 }
 118
 119 =begin testing
 120
 121 #:: test classmethod setup
 122
 123 my $c = 'local::lib';
 124
 125 =end testing
 126
 127 =begin testing
 128
 129 #:: test classmethod
 130
 131 is($c->resolve_empty_path, '~/perl5');
 132 is($c->resolve_empty_path('foo'), 'foo');
 133
 134 =end testing
 135
 136 =cut
 137
 138 sub resolve_home_path {
 139   my ($class, $path) = @_;
 140   return $path unless ($path =~ /^~/);
 141   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 142   my $tried_file_homedir;
 143   my $homedir = do {
 144     if (eval { require File::HomeDir } && $File::HomeDir::VERSION >= 0.65) {
 145       $tried_file_homedir = 1;
 146       if (defined $user) {
 147         File::HomeDir->users_home($user);
 148       } else {
 149         File::HomeDir->my_home;
 150       }
 151     } else {
 152       if (defined $user) {
 153         (getpwnam $user)[7];
 154       } else {
 155         if (defined $ENV{HOME}) {
 156           $ENV{HOME};
 157         } else {
 158           (getpwuid $<)[7];
 159         }
 160       }
 161     }
 162   };
 163   unless (defined $homedir) {
 164     Carp::croak(
 165       "Couldn't resolve homedir for "
 166       .(defined $user ? $user : 'current user')
 167       .($tried_file_homedir ? '' : ' - consider installing File::HomeDir')
 168     );
 169   }
 170   $path =~ s/^~[^\/]*/$homedir/;
 171   $path;
 172 }
 173
 174 sub resolve_relative_path {
 175   my ($class, $path) = @_;
 176   $path = File::Spec->rel2abs($path);
 177 }
 178
 179 =begin testing
 180
 181 #:: test classmethod
 182
 183 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 184 is($c->resolve_relative_path('bar'),'FOObar');
 185
 186 =end testing
 187
 188 =cut
 189
 190 sub setup_local_lib_for {
 191   my ($class, $path) = @_;
 192   $path = $class->ensure_dir_structure_for($path);
 193   if ($0 eq '-') {
 194     $class->print_environment_vars_for($path);
 195     exit 0;
 196   } else {
 197     $class->setup_env_hash_for($path);
 198     @INC = _uniq(split($Config{path_sep}, $ENV{PERL5LIB}), @INC);
 199   }
 200 }
 201
 202 sub modulebuildrc_path {
 203   my ($class, $path) = @_;
 204   File::Spec->catfile($path, '.modulebuildrc');
 205 }
 206
 207 sub install_base_bin_path {
 208   my ($class, $path) = @_;
 209   File::Spec->catdir($path, 'bin');
 210 }
 211
 212 sub install_base_perl_path {
 213   my ($class, $path) = @_;
 214   File::Spec->catdir($path, 'lib', 'perl5');
 215 }
 216
 217 sub install_base_arch_path {
 218   my ($class, $path) = @_;
 219   File::Spec->catdir($class->install_base_perl_path($path), $Config{archname});
 220 }
 221
 222 sub ensure_dir_structure_for {
 223   my ($class, $path) = @_;
 224   unless (-d $path) {
 225     warn "Attempting to create directory ${path}\n";
 226   }
 227   File::Path::mkpath($path);
 228   # Need to have the path exist to make a short name for it, so
 229   # converting to a short name here.
 230   $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32';
 231   my $modulebuildrc_path = $class->modulebuildrc_path($path);
 232   if (-e $modulebuildrc_path) {
 233     unless (-f _) {
 234       Carp::croak("${modulebuildrc_path} exists but is not a plain file");
 235     }
 236   } else {
 237     warn "Attempting to create file ${modulebuildrc_path}\n";
 238     open MODULEBUILDRC, '>', $modulebuildrc_path
 239       || Carp::croak("Couldn't open ${modulebuildrc_path} for writing: $!");
 240     print MODULEBUILDRC qq{install  --install_base  ${path}\n}
 241       || Carp::croak("Couldn't write line to ${modulebuildrc_path}: $!");
 242     close MODULEBUILDRC
 243       || Carp::croak("Couldn't close file ${modulebuildrc_path}: $@");
 244   }
 245
 246   return $path;
 247 }
 248
 249 sub INTERPOLATE_ENV () { 1 }
 250 sub LITERAL_ENV     () { 0 }
 251
 252 sub print_environment_vars_for {
 253   my ($class, $path) = @_;
 254   my @envs = $class->build_environment_vars_for($path, LITERAL_ENV);
 255   my $out = '';
 256
 257   # rather basic csh detection, goes on the assumption that something won't
 258   # call itself csh unless it really is. also, default to bourne in the
 259   # pathological situation where a user doesn't have $ENV{SHELL} defined.
 260   # note also that shells with funny names, like zoid, are assumed to be
 261   # bourne.
 262   my $shellbin = 'sh';
 263   if(defined $ENV{'SHELL'}) {
 264       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 265       $shellbin = $shell_bin_path_parts[-1];
 266   }
 267   my $shelltype = do {
 268       local $_ = $shellbin;
 269       if(/csh/) {
 270           'csh'
 271       } else {
 272           'bourne'
 273       }
 274   };
 275
 276   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 277   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 278       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 279       $shellbin = $shell_bin_path_parts[-1];
 280          $shelltype = do {
 281                  local $_ = $shellbin;
 282                  if(/command\.com/) {
 283                          'win32'
 284                  } elsif(/cmd\.exe/) {
 285                          'win32'
 286                  } elsif(/4nt\.exe/) {
 287                          'win32'
 288                  } else {
 289                          $shelltype
 290                  }
 291          };
 292   }
 293
 294   while (@envs) {
 295     my ($name, $value) = (shift(@envs), shift(@envs));
 296     $value =~ s/(\\")/\\$1/g;
 297     $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value);
 298   }
 299   print $out;
 300 }
 301
 302 # simple routines that take two arguments: an %ENV key and a value. return
 303 # strings that are suitable for passing directly to the relevant shell to set
 304 # said key to said value.
 305 sub build_bourne_env_declaration {
 306   my $class = shift;
 307   my($name, $value) = @_;
 308   return qq{export ${name}="${value}"\n};
 309 }
 310
 311 sub build_csh_env_declaration {
 312   my $class = shift;
 313   my($name, $value) = @_;
 314   return qq{setenv ${name} "${value}"\n};
 315 }
 316
 317 sub build_win32_env_declaration {
 318   my $class = shift;
 319   my($name, $value) = @_;
 320   return qq{set ${name}=${value}\n};
 321 }
 322
 323 sub setup_env_hash_for {
 324   my ($class, $path) = @_;
 325   my %envs = $class->build_environment_vars_for($path, INTERPOLATE_ENV);
 326   @ENV{keys %envs} = values %envs;
 327 }
 328
 329 sub build_environment_vars_for {
 330   my ($class, $path, $interpolate) = @_;
 331   return (
 332     MODULEBUILDRC => $class->modulebuildrc_path($path),
 333     PERL_MM_OPT => "INSTALL_BASE=${path}",
 334     PERL5LIB => join($Config{path_sep},
 335                   $class->install_base_arch_path($path),
 336                   $class->install_base_perl_path($path),
 337                   (($ENV{PERL5LIB}||()) ?
 338                     ($interpolate == INTERPOLATE_ENV
 339                       ? ($ENV{PERL5LIB})
 340                       : (($^O ne 'MSWin32') ? '$PERL5LIB' : '%PERL5LIB%' ))
 341                     : ())
 342                 ),
 343     PATH => join($Config{path_sep},
 344               $class->install_base_bin_path($path),
 345               ($interpolate == INTERPOLATE_ENV
 346                 ? ($ENV{PATH}||())
 347                 : (($^O ne 'MSWin32') ? '$PATH' : '%PATH%' ))
 348              ),
 349   )
 350 }
 351
 352 =begin testing
 353
 354 #:: test classmethod
 355
 356 File::Path::rmtree('t/var/splat');
 357
 358 $c->ensure_dir_structure_for('t/var/splat');
 359
 360 ok(-d 't/var/splat');
 361
 362 ok(-f 't/var/splat/.modulebuildrc');
 363
 364 =end testing
 365
 366 =encoding utf8
 367
 368 =head1 NAME
 369
 370 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 371
 372 L<Deutsche Übersetzung|podloc::de_DE::local::lib>
 373
 374 =head1 SYNOPSIS
 375
 376 In code -
 377
 378   use local::lib; # sets up a local lib at ~/perl5
 379
 380   use local::lib '~/foo'; # same, but ~/foo
 381
 382   # Or...
 383   use FindBin;
 384   use local::lib "$FindBin::Bin/../support";  # app-local support library
 385
 386 From the shell -
 387
 388   # Install LWP and its missing dependencies to the '~/perl5' directory
 389   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 390
 391   # Just print out useful shell commands
 392   $ perl -Mlocal::lib
 393   export MODULEBUILDRC=/home/username/perl/.modulebuildrc
 394   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl'
 395   export PERL5LIB='/home/username/perl/lib/perl5:/home/username/perl/lib/perl5/i386-linux'
 396   export PATH="/home/username/perl/bin:$PATH"
 397
 398 =head2 The bootstrapping technique
 399
 400 A typical way to install local::lib is using what is known as the
 401 "bootstrapping" technique.  You would do this if your system administrator
 402 hasn't already installed local::lib.  In this case, you'll need to install
 403 local::lib in your home directory.
 404
 405 If you do have administrative privileges, you will still want to set up your
 406 environment variables, as discussed in step 4. Without this, you would still
 407 install the modules into the system CPAN installation and also your Perl scripts
 408 will not use the lib/ path you bootstrapped with local::lib.
 409
 410 Windows users must also see L</Differences when using this module under Win32>.
 411
 412 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 413 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 414 or administrator.  Unpack the file in your home directory or in any other
 415 convenient location.
 416
 417 2. Run this:
 418
 419   perl Makefile.PL --bootstrap
 420
 421 If the system asks you whether it should automatically configure as much
 422 as possible, you would typically answer yes.
 423
 424 In order to install local::lib into a directory other than default, you need
 425 to give that directory on the call of bootstrap like this:
 426
 427   perl Makefile.PL --bootstrap=~/foo
 428
 429 3. Run this: (local::lib assumes you have make installed on your system)
 430
 431   make test && make install
 432
 433 4. Now we need to setup the appropriate environment variables, so that Perl
 434 starts using our newly generated lib/ directory. If you are using bash or
 435 any other Bourne shells, you can add this to your shell startup script this
 436 way:
 437
 438   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 439
 440 If you are using C shell, you can do this as follows:
 441
 442   /bin/csh
 443   echo $SHELL
 444   /bin/csh
 445   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 446
 447 If you passed to bootstrap a directory other than default, you also need to give that as
 448 import parameter to the call of the local::lib module like this way:
 449
 450   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 451
 452 After writing your shell configuration file, be sure to re-read it to get the
 453 changed settings into your current shell's environment. Bourne shells use
 454 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 455
 456 If you're on a slower machine, or are operating under draconian disk space
 457 limitations, you can disable the automatic generation of manpages from POD when
 458 installing modules by using the C<--no-manpages> argument when bootstrapping:
 459
 460   perl Makefile.PL --bootstrap --no-manpages
 461
 462 To avoid doing several bootstrap for several Perl module environments on the
 463 same account, for example if you use it for several different deployed
 464 applications independently, you can use one bootstrapped local::lib
 465 installation to install modules in different directories directly this way:
 466
 467   cd ~/mydir1
 468   perl -Mlocal::lib=./
 469   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 470   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 471   perl -MCPAN -e install ...    ### whatever modules you want
 472   cd ../mydir2
 473   ... REPEAT ...
 474
 475 For multiple environments for multiple apps you may need to include a modified
 476 version of the C<< use FindBin >> instructions in the "In code" sample above.
 477 If you did something like the above, you have a set of Perl modules at C<<
 478 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 479 you need to tell it where to find the modules you installed for it at C<<
 480 ~/mydir1/lib >>.
 481
 482 In C<< ~/mydir1/scripts/myscript.pl >>:
 483
 484   use strict;
 485   use warnings;
 486   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 487   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 488
 489 Put this before any BEGIN { ... } blocks that require the modules you installed.
 490
 491 =head2 Differences when using this module under Win32
 492
 493 To set up the proper environment variables for your current session of
 494 C<CMD.exe>, you can use this:
 495
 496   C:\>perl -Mlocal::lib
 497   set MODULEBUILDRC=C:\DOCUME~1\ADMINI~1\perl5\.modulebuildrc
 498   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 499   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread
 500   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 501
 502   ### To set the environment for this shell alone
 503   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\temp.bat
 504   ### instead of $(perl -Mlocal::lib=./)
 505
 506 If you want the environment entries to persist, you'll need to add then to the
 507 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 508
 509 The "~" is translated to the user's profile directory (the directory named for
 510 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 511 (Windows Vista or later) unless $ENV{HOME} exists. After that, the home
 512 directory is translated to a short name (which means the directory must exist)
 513 and the subdirectories are created.
 514
 515 =head1 RATIONALE
 516
 517 The version of a Perl package on your machine is not always the version you
 518 need.  Obviously, the best thing to do would be to update to the version you
 519 need.  However, you might be in a situation where you're prevented from doing
 520 this.  Perhaps you don't have system administrator privileges; or perhaps you
 521 are using a package management system such as Debian, and nobody has yet gotten
 522 around to packaging up the version you need.
 523
 524 local::lib solves this problem by allowing you to create your own directory of
 525 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 526 be within your own home directory).  The existing system Perl installation is
 527 not affected; you simply invoke Perl with special options so that Perl uses the
 528 packages in your own local package directory rather than the system packages.
 529 local::lib arranges things so that your locally installed version of the Perl
 530 packages takes precedence over the system installation.
 531
 532 If you are using a package management system (such as Debian), you don't need to
 533 worry about Debian and CPAN stepping on each other's toes.  Your local version
 534 of the packages will be written to an entirely separate directory from those
 535 installed by Debian.
 536
 537 =head1 DESCRIPTION
 538
 539 This module provides a quick, convenient way of bootstrapping a user-local Perl
 540 module library located within the user's home directory. It also constructs and
 541 prints out for the user the list of environment variables using the syntax
 542 appropriate for the user's current shell (as specified by the C<SHELL>
 543 environment variable), suitable for directly adding to one's shell
 544 configuration file.
 545
 546 More generally, local::lib allows for the bootstrapping and usage of a
 547 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 548 easier to ship an application with an app-specific copy of a Perl module, or
 549 collection of modules. Useful in cases like when an upstream maintainer hasn't
 550 applied a patch to a module of theirs that you need for your application.
 551
 552 On import, local::lib sets the following environment variables to appropriate
 553 values:
 554
 555 =over 4
 556
 557 =item MODULEBUILDRC
 558
 559 =item PERL_MM_OPT
 560
 561 =item PERL5LIB
 562
 563 =item PATH
 564
 565 PATH is appended to, rather than clobbered.
 566
 567 =back
 568
 569 These values are then available for reference by any code after import.
 570
 571 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 572
 573 See L<lib::core::only|lib::core::only> for one way to do this - but note that
 574 there are a number of caveats, and the best approach is always to perform a
 575 build against a clean perl (i.e. site and vendor as close to empty as possible).
 576
 577 =head1 METHODS
 578
 579 =head2 ensure_directory_structure_for
 580
 581 =over 4
 582
 583 =item Arguments: path
 584
 585 =back
 586
 587 Attempts to create the given path, and all required parent directories. Throws
 588 an exception on failure.
 589
 590 =head2 print_environment_vars_for
 591
 592 =over 4
 593
 594 =item Arguments: path
 595
 596 =back
 597
 598 Prints to standard output the variables listed above, properly set to use the
 599 given path as the base directory.
 600
 601 =head2 setup_env_hash_for
 602
 603 =over 4
 604
 605 =item Arguments: path
 606
 607 =back
 608
 609 Constructs the C<%ENV> keys for the given path, by calling
 610 C<build_environment_vars_for>.
 611
 612 =head2 install_base_perl_path
 613
 614 =over 4
 615
 616 =item Arguments: path
 617
 618 =back
 619
 620 Returns a path describing where to install the Perl modules for this local
 621 library installation. Appends the directories C<lib> and C<perl5> to the given
 622 path.
 623
 624 =head2 install_base_arch_path
 625
 626 =over 4
 627
 628 =item Arguments: path
 629
 630 =back
 631
 632 Returns a path describing where to install the architecture-specific Perl
 633 modules for this local library installation. Based on the
 634 L</install_base_perl_path> method's return value, and appends the value of
 635 C<$Config{archname}>.
 636
 637 =head2 install_base_bin_path
 638
 639 =over 4
 640
 641 =item Arguments: path
 642
 643 =back
 644
 645 Returns a path describing where to install the executable programs for this
 646 local library installation. Based on the L</install_base_perl_path> method's
 647 return value, and appends the directory C<bin>.
 648
 649 =head2 modulebuildrc_path
 650
 651 =over 4
 652
 653 =item Arguments: path
 654
 655 =back
 656
 657 Returns a path describing where to install the C<.modulebuildrc> file, based on
 658 the given path.
 659
 660 =head2 resolve_empty_path
 661
 662 =over 4
 663
 664 =item Arguments: path
 665
 666 =back
 667
 668 Builds and returns the base path into which to set up the local module
 669 installation. Defaults to C<~/perl5>.
 670
 671 =head2 resolve_home_path
 672
 673 =over 4
 674
 675 =item Arguments: path
 676
 677 =back
 678
 679 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 680 for this purpose. If no definite answer is available, throws an exception.
 681
 682 =head2 resolve_relative_path
 683
 684 =over 4
 685
 686 =item Arguments: path
 687
 688 =back
 689
 690 Translates the given path into an absolute path.
 691
 692 =head2 resolve_path
 693
 694 =over 4
 695
 696 =item Arguments: path
 697
 698 =back
 699
 700 Calls the following in a pipeline, passing the result from the previous to the
 701 next, in an attempt to find where to configure the environment for a local
 702 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 703 L</resolve_relative_path>. Passes the given path argument to
 704 L</resolve_empty_path> which then returns a result that is passed to
 705 L</resolve_home_path>, which then has its result passed to
 706 L</resolve_relative_path>. The result of this final call is returned from
 707 L</resolve_path>.
 708
 709 =head1 A WARNING ABOUT UNINST=1
 710
 711 Be careful about using local::lib in combination with "make install UNINST=1".
 712 The idea of this feature is that will uninstall an old version of a module
 713 before installing a new one. However it lacks a safety check that the old
 714 version and the new version will go in the same directory. Used in combination
 715 with local::lib, you can potentially delete a globally accessible version of a
 716 module while installing the new version in a local place. Only combine "make
 717 install UNINST=1" and local::lib if you understand these possible consequences.
 718
 719 =head1 LIMITATIONS
 720
 721 Rather basic shell detection. Right now anything with csh in its name is
 722 assumed to be a C shell or something compatible, and everything else is assumed
 723 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 724 not set, a Bourne-compatible shell is assumed.
 725
 726 Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you
 727 have CPANPLUS installed.
 728
 729 Kills any existing PERL5LIB, PERL_MM_OPT or MODULEBUILDRC.
 730
 731 Should probably auto-fixup CPAN config if not already done.
 732
 733 Patches very much welcome for any of the above.
 734
 735 On Win32 systems, does not have a way to write the created environment variables
 736 to the registry, so that they can persist through a reboot.
 737
 738 =head1 TROUBLESHOOTING
 739
 740 If you've configured local::lib to install CPAN modules somewhere in to your
 741 home directory, and at some point later you try to install a module with C<cpan
 742 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
 743 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
 744 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
 745 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
 746 you've somehow lost your updated ExtUtils::MakeMaker module.
 747
 748 To remedy this situation, rerun the bootstrapping procedure documented above.
 749
 750 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
 751
 752 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
 753
 754 =head1 ENVIRONMENT
 755
 756 =over 4
 757
 758 =item SHELL
 759
 760 =item COMSPEC
 761
 762 local::lib looks at the user's C<SHELL> environment variable when printing out
 763 commands to add to the shell configuration file.
 764
 765 On Win32 systems, C<COMSPEC> is also examined.
 766
 767 =back
 768
 769 =head1 AUTHOR
 770
 771 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
 772
 773 auto_install fixes kindly sponsored by http://www.takkle.com/
 774
 775 =head1 CONTRIBUTORS
 776
 777 Patches to correctly output commands for csh style shells, as well as some
 778 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
 779
 780 Doc patches for a custom local::lib directory contributed by Torsten Raudssus
 781 <torsten@raudssus.de>.
 782
 783 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
 784 things will install properly, submitted a fix for the bug causing problems with
 785 writing Makefiles during bootstrapping, contributed an example program, and
 786 submitted yet another fix to ensure that local::lib can install and bootstrap
 787 properly. Many, many thanks!
 788
 789 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
 790 section. Many thanks!
 791
 792 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
 793
 794 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
 795 by a patch from Marco Emilio Poleggi.
 796
 797 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
 798 '--self-contained' option.
 799
 800 Documentation patches to make win32 usage clearer by
 801 David Mertens <dcmertens.perl@gmail.com> (run4flat).
 802
 803 =head1 COPYRIGHT
 804
 805 Copyright (c) 2007 - 2009 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
 806 listed above.
 807
 808 =head1 LICENSE
 809
 810 This library is free software and may be distributed under the same terms
 811 as perl itself.
 812
 813 =cut
 814
 815 1;