lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '1.008026'; # 1.8.26
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19
  20   while (@args) {
  21     my $arg = shift @args;
  22     # check for lethal dash first to stop processing before causing problems
  23     # the fancy dash is U+2212 or \xE2\x88\x92
  24     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  25       die <<'DEATH';
  26 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  27 These are *not* the traditional -- dashes that software recognizes. You
  28 probably got these by copy-pasting from the perldoc for this module as
  29 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  30 terminal, but can happen elsewhere too. Please try again after replacing the
  31 dashes with normal minus signs.
  32 DEATH
  33     }
  34     elsif ($arg eq '--self-contained') {
  35       die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  36     }
  37     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  38       my $path = defined $1 ? $1 : shift @args;
  39       push @steps, ['deactivate', $path];
  40     }
  41     elsif ( $arg eq '--deactivate-all' ) {
  42       push @steps, ['deactivate_all'];
  43     }
  44     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  45       my $shell = defined $1 ? $1 : shift @args;
  46       $opts{shelltype} = $shell;
  47     }
  48     elsif ( $arg eq '--no-create' ) {
  49       $opts{no_create} = 1;
  50     }
  51     elsif ( $arg =~ /^--/ ) {
  52       die "Unknown import argument: $arg";
  53     }
  54     else {
  55       push @steps, ['activate', $arg];
  56     }
  57   }
  58   if (!@steps) {
  59     push @steps, ['activate', undef];
  60   }
  61
  62   my $self = $class->new(%opts);
  63
  64   for (@steps) {
  65     my ($method, @args) = @$_;
  66     $self = $self->$method(@args);
  67   }
  68
  69   if ($0 eq '-') {
  70     $self->print_environment_vars_for;
  71     exit 0;
  72   }
  73   else {
  74     $self->setup_local_lib_for;
  75   }
  76 }
  77
  78 sub new {
  79   my $class = shift;
  80   bless {@_}, $class;
  81 }
  82
  83 sub clone {
  84   my $self = shift;
  85   bless {%$self, @_}, ref $self;
  86 }
  87
  88 sub inc { $_[0]->{inc}     ||= \@INC }
  89 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
  90 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
  91 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
  92 sub extra { $_[0]->{extra} ||= {} }
  93 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
  94 sub no_create { $_[0]->{no_create} }
  95
  96 my $_archname = $Config{archname};
  97 my $_version  = $Config{version};
  98 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
  99 my $_path_sep = $Config{path_sep};
 100
 101 sub _as_list {
 102   my $list = shift;
 103   grep length, map {
 104     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 105       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 106                         : ()
 107     )
 108   } ref $list ? @$list : $list;
 109 }
 110 sub _remove_from {
 111   my ($list, @remove) = @_;
 112   my %remove = map { $_ => 1 } @remove;
 113   grep !$remove{$_}, _as_list($list);
 114 }
 115
 116 my @_lib_subdirs = (
 117   [$_version, $_archname],
 118   [$_version],
 119   [$_archname],
 120   (@_inc_version_list ? \@_inc_version_list : ()),
 121   [],
 122 );
 123
 124 sub install_base_bin_path {
 125   my ($class, $path) = @_;
 126   return File::Spec->catdir($path, 'bin');
 127 }
 128 sub install_base_perl_path {
 129   my ($class, $path) = @_;
 130   return File::Spec->catdir($path, 'lib', 'perl5');
 131 }
 132 sub install_base_arch_path {
 133   my ($class, $path) = @_;
 134   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 135 }
 136
 137 sub lib_paths_for {
 138   my ($class, $path) = @_;
 139   my $base = $class->install_base_perl_path($path);
 140   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 141 }
 142
 143 sub _mm_escape_path {
 144   my $path = shift;
 145   $path =~ s/\\/\\\\\\\\/g;
 146   if ($path =~ s/ /\\ /g) {
 147     $path = qq{"\\"$path\\""};
 148   }
 149   return $path;
 150 }
 151
 152 sub _mb_escape_path {
 153   my $path = shift;
 154   $path =~ s/\\/\\\\/g;
 155   return qq{"$path"};
 156 }
 157
 158 sub installer_options_for {
 159   my ($class, $path) = @_;
 160   return {
 161     PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 162     PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef,
 163   };
 164 }
 165
 166 sub active_paths {
 167   my ($self) = @_;
 168   $self = ref $self ? $self : $self->new;
 169
 170   return grep {
 171     # screen out entries that aren't actually reflected in @INC
 172     my $active_ll = $self->install_base_perl_path($_);
 173     grep { $_ eq $active_ll } @{$self->inc};
 174   } _as_list($self->roots);
 175 }
 176
 177
 178 sub deactivate {
 179   my ($self, $path) = @_;
 180   $self = $self->new unless ref $self;
 181   $path = $self->resolve_path($path);
 182
 183   my @active_lls = $self->active_paths;
 184
 185   if (!grep { $_ eq $path } @active_lls) {
 186     warn "Tried to deactivate inactive local::lib '$path'\n";
 187     return $self;
 188   }
 189
 190   my %args = (
 191     bins  => [ _remove_from($self->bins,  $self->install_base_bin_path($path)) ],
 192     libs  => [ _remove_from($self->libs,  $self->install_base_perl_path($path)) ],
 193     inc   => [ _remove_from($self->inc,   $self->lib_paths_for($path)) ],
 194     roots => [ _remove_from($self->roots, $path) ],
 195   );
 196
 197   $args{extra} = $self->installer_options_for($args{roots}[0]);
 198
 199   $self->clone(%args);
 200 }
 201
 202 sub deactivate_all {
 203   my ($self) = @_;
 204   $self = $self->new unless ref $self;
 205
 206   my @active_lls = $self->active_paths;
 207
 208   my %args = (
 209     bins => [ _remove_from($self->bins,
 210       map $self->install_base_bin_path($_), @active_lls) ],
 211     libs => [ _remove_from($self->libs,
 212       map $self->install_base_perl_path($_), @active_lls) ],
 213     inc => [ _remove_from($self->inc,
 214       map $self->lib_paths_for($_), @active_lls) ],
 215     roots => [ _remove_from($self->roots, @active_lls) ],
 216   );
 217
 218   $args{extra} = $self->installer_options_for(undef);
 219
 220   $self->clone(%args);
 221 }
 222
 223 sub activate {
 224   my ($self, $path) = @_;
 225   $self = $self->new unless ref $self;
 226   $path = $self->resolve_path($path);
 227   $self->ensure_dir_structure_for($path)
 228     unless $self->no_create;
 229
 230   $path = ( Win32::GetShortPathName($path) || $path )
 231     if $^O eq 'MSWin32';
 232
 233   my @active_lls = $self->active_paths;
 234
 235   if (grep { $_ eq $path } @active_lls) {
 236     $self = $self->deactivate($path);
 237   }
 238
 239   my %args = (
 240     bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 241     libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 242     inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 243     roots => [ $path, @{$self->roots} ],
 244   );
 245
 246   $args{extra} = $self->installer_options_for($path);
 247
 248   $self->clone(%args);
 249 }
 250
 251 sub _legacy {
 252   my ($self, $path) = @_;
 253   $self = $self->new unless ref $self;
 254   if (defined $path) {
 255     $self = $self->activate($path);
 256   }
 257   $self;
 258 }
 259
 260 sub build_environment_vars_for {
 261   my ($self) = _legacy(@_);
 262   (
 263     PATH                => join($_path_sep, _as_list($self->bins)),
 264     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 265     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 266     %{$self->extra},
 267   );
 268 }
 269
 270 sub setup_local_lib_for {
 271   my ($self) = _legacy(@_);
 272   $self->setup_env_hash_for;
 273   @INC = @{$self->inc};
 274 }
 275
 276 sub setup_env_hash_for {
 277   my $self = shift;
 278   my %env = $self->build_environment_vars_for(@_);
 279   for my $key (keys %env) {
 280     if (defined $env{$key}) {
 281       $ENV{$key} = $env{$key};
 282     }
 283     else {
 284       delete $ENV{$key};
 285     }
 286   }
 287 }
 288
 289 sub print_environment_vars_for {
 290   my $self = shift;
 291   print $self->environment_vars_string_for(@_);
 292 }
 293
 294 sub environment_vars_string_for {
 295   my $self = _legacy(@_);
 296
 297   my $build_method = 'build_' . $self->shelltype . '_env_declaration';
 298
 299   my @envs = (
 300     PATH                => $self->bins,
 301     PERL5LIB            => $self->libs,
 302     PERL_LOCAL_LIB_ROOT => $self->roots,
 303     %{$self->extra},
 304   );
 305   my $out = '';
 306   while (@envs) {
 307     my ($name, $value) = (shift(@envs), shift(@envs));
 308     if (
 309         ref $value
 310         && @$value == 1
 311         && ref $value->[0]
 312         && ref $value->[0] eq 'SCALAR'
 313         && ${$value->[0]} eq $name) {
 314       next;
 315     }
 316     if (!ref $value
 317         && defined $value ? $value eq $ENV{$name} : !defined $ENV{$name}
 318     ) {
 319       next;
 320     }
 321     $out .= $self->$build_method($name, $value);
 322   }
 323   return $out;
 324 }
 325
 326 sub build_bourne_env_declaration {
 327   my ($class, $name, $args) = @_;
 328   my $value = $class->_interpolate($args);
 329   $value =~ s/"/\\"/g
 330     if defined $value;
 331   return defined($value) ? qq{export ${name}="${value}"\n} : qq{unset ${name}\n};
 332 }
 333 sub build_csh_env_declaration {
 334   my ($class, $name, $args) = @_;
 335   my ($value, @vars) = $class->_interpolate($args);
 336   @vars = grep { $_ ne $name || defined $value } @vars;
 337   $value =~ s/"/"\\""/g
 338     if defined $value;
 339   join '',
 340     (map qq{if ! \$?$_ setenv $_ "";\n}, @vars),
 341     (defined($value)
 342       ? qq{setenv $name "$value";\n}
 343       : qq{unsetenv $name;\n});
 344 }
 345 sub build_cmd_env_declaration {
 346   my ($class, $name, $args) = @_;
 347   my $value = $class->_interpolate($args, '%', '%');
 348   $value =~ s/"/\\"/g
 349     if defined $value;
 350   return qq{set $name=} . (defined($value) ? qq{"$value"} : '') . "\n";
 351 }
 352 sub build_powershell_env_declaration {
 353   my ($class, $name, $args) = @_;
 354   my $value = $class->_interpolate($args, '$env:');
 355   if (defined $value) {
 356     $value =~ s/"/\\"/g;
 357     return qq{\$env:$name = "$value"\n};
 358   }
 359   return "Remove-Item Env:\\$name\n";
 360 }
 361
 362
 363 sub _interpolate {
 364   my ($class, $args, $start, $end) = @_;
 365   return
 366     unless defined $args;
 367   return $args
 368     unless ref $args;
 369   return
 370     unless @$args;
 371   $start = '$' unless defined $start;
 372   $end = '' unless defined $end;
 373   my @vars;
 374   my $string = join($Config{path_sep}, map {
 375     (ref $_ && ref $_ eq 'SCALAR') ? do { push @vars, $$_; $start.$$_.$end }
 376       : $_
 377   } @$args);
 378   return wantarray ? ($string, @vars) : $string;
 379 }
 380
 381 sub pipeline;
 382
 383 sub pipeline {
 384   my @methods = @_;
 385   my $last = pop(@methods);
 386   if (@methods) {
 387     \sub {
 388       my ($obj, @args) = @_;
 389       $obj->${pipeline @methods}(
 390         $obj->$last(@args)
 391       );
 392     };
 393   } else {
 394     \sub {
 395       shift->$last(@_);
 396     };
 397   }
 398 }
 399
 400 =begin testing
 401
 402 #:: test pipeline
 403
 404 package local::lib;
 405
 406 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 407 my $foo = bless({}, 'Foo');
 408 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 409
 410 =end testing
 411
 412 =cut
 413
 414 sub resolve_path {
 415   my ($class, $path) = @_;
 416
 417   $path = $class->${pipeline qw(
 418     resolve_relative_path
 419     resolve_home_path
 420     resolve_empty_path
 421   )}($path);
 422
 423   $path;
 424 }
 425
 426 sub resolve_empty_path {
 427   my ($class, $path) = @_;
 428   if (defined $path) {
 429     $path;
 430   } else {
 431     '~/perl5';
 432   }
 433 }
 434
 435 =begin testing
 436
 437 #:: test classmethod setup
 438
 439 my $c = 'local::lib';
 440
 441 =end testing
 442
 443 =begin testing
 444
 445 #:: test classmethod
 446
 447 is($c->resolve_empty_path, '~/perl5');
 448 is($c->resolve_empty_path('foo'), 'foo');
 449
 450 =end testing
 451
 452 =cut
 453
 454 sub resolve_home_path {
 455   my ($class, $path) = @_;
 456   return $path unless ($path =~ /^~/);
 457   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 458   my $homedir = do {
 459     if (!defined $user && defined $ENV{HOME}) {
 460       $ENV{HOME}
 461     }
 462     else {
 463       require File::Glob;
 464       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 465     }
 466   };
 467   unless (defined $homedir) {
 468     require Carp;
 469     Carp::croak(
 470       "Couldn't resolve homedir for "
 471       .(defined $user ? $user : 'current user')
 472     );
 473   }
 474   $path =~ s/^~[^\/]*/$homedir/;
 475   $path;
 476 }
 477
 478 sub resolve_relative_path {
 479   my ($class, $path) = @_;
 480   $path = File::Spec->rel2abs($path);
 481 }
 482
 483 =begin testing
 484
 485 #:: test classmethod
 486
 487 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 488 is($c->resolve_relative_path('bar'),'FOObar');
 489
 490 =end testing
 491
 492 =cut
 493
 494 sub ensure_dir_structure_for {
 495   my ($class, $path) = @_;
 496   unless (-d $path) {
 497     warn "Attempting to create directory ${path}\n";
 498   }
 499   require File::Basename;
 500   my @dirs;
 501   while(!-d $path) {
 502     push @dirs, $path;
 503     $path = File::Basename::dirname($path);
 504   }
 505   mkdir $_ for reverse @dirs;
 506   return;
 507 }
 508
 509 =begin testing
 510
 511 #:: test classmethod
 512
 513 File::Path::rmtree('t/var/splat');
 514
 515 $c->ensure_dir_structure_for('t/var/splat');
 516
 517 ok(-d 't/var/splat');
 518
 519 =end testing
 520
 521 =cut
 522
 523 sub guess_shelltype {
 524   my $shellbin
 525     = defined $ENV{SHELL}
 526       ? (File::Spec->splitpath($ENV{SHELL}))[-1]
 527     : ( $^O eq 'MSWin32' && exists $ENV{'!EXITCODE'} )
 528       ? 'bash'
 529     : ( $^O eq 'MSWin32' && $ENV{PROMPT} && $ENV{COMSPEC} )
 530       ? (File::Spec->splitpath($ENV{COMSPEC}))[-1]
 531     : ( $^O eq 'MSWin32' && !$ENV{PROMPT} )
 532       ? 'powershell.exe'
 533     : 'sh';
 534
 535   for ($shellbin) {
 536     return
 537         /csh/             ? 'csh'
 538       : /command\.com/    ? 'cmd'
 539       : /cmd\.exe/        ? 'cmd'
 540       : /4nt\.exe/        ? 'cmd'
 541       : /powershell\.exe/ ? 'powershell'
 542                           : 'bourne';
 543   }
 544 }
 545
 546 1;
 547 __END__
 548
 549 =encoding utf8
 550
 551 =head1 NAME
 552
 553 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 554
 555 =head1 SYNOPSIS
 556
 557 In code -
 558
 559   use local::lib; # sets up a local lib at ~/perl5
 560
 561   use local::lib '~/foo'; # same, but ~/foo
 562
 563   # Or...
 564   use FindBin;
 565   use local::lib "$FindBin::Bin/../support";  # app-local support library
 566
 567 From the shell -
 568
 569   # Install LWP and its missing dependencies to the '~/perl5' directory
 570   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 571
 572   # Just print out useful shell commands
 573   $ perl -Mlocal::lib
 574   export PERL_MB_OPT='--install_base /home/username/perl5'
 575   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 576   export PERL5LIB="/home/username/perl5/lib/perl5"
 577   export PATH="/home/username/perl5/bin:$PATH"
 578
 579 =head2 The bootstrapping technique
 580
 581 A typical way to install local::lib is using what is known as the
 582 "bootstrapping" technique.  You would do this if your system administrator
 583 hasn't already installed local::lib.  In this case, you'll need to install
 584 local::lib in your home directory.
 585
 586 Even if you do have administrative privileges, you will still want to set up your
 587 environment variables, as discussed in step 4. Without this, you would still
 588 install the modules into the system CPAN installation and also your Perl scripts
 589 will not use the lib/ path you bootstrapped with local::lib.
 590
 591 By default local::lib installs itself and the CPAN modules into ~/perl5.
 592
 593 Windows users must also see L</Differences when using this module under Win32>.
 594
 595 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 596 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 597 or administrator.  Unpack the file in your home directory or in any other
 598 convenient location.
 599
 600 2. Run this:
 601
 602   perl Makefile.PL --bootstrap
 603
 604 If the system asks you whether it should automatically configure as much
 605 as possible, you would typically answer yes.
 606
 607 In order to install local::lib into a directory other than the default, you need
 608 to specify the name of the directory when you call bootstrap, as follows:
 609
 610   perl Makefile.PL --bootstrap=~/foo
 611
 612 3. Run this: (local::lib assumes you have make installed on your system)
 613
 614   make test && make install
 615
 616 4. Now we need to setup the appropriate environment variables, so that Perl
 617 starts using our newly generated lib/ directory. If you are using bash or
 618 any other Bourne shells, you can add this to your shell startup script this
 619 way:
 620
 621   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 622
 623 If you are using C shell, you can do this as follows:
 624
 625   /bin/csh
 626   echo $SHELL
 627   /bin/csh
 628   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 629
 630 If you passed to bootstrap a directory other than default, you also need to
 631 give that as import parameter to the call of the local::lib module like this
 632 way:
 633
 634   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 635
 636 After writing your shell configuration file, be sure to re-read it to get the
 637 changed settings into your current shell's environment. Bourne shells use
 638 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 639
 640 If you're on a slower machine, or are operating under draconian disk space
 641 limitations, you can disable the automatic generation of manpages from POD when
 642 installing modules by using the C<--no-manpages> argument when bootstrapping:
 643
 644   perl Makefile.PL --bootstrap --no-manpages
 645
 646 To avoid doing several bootstrap for several Perl module environments on the
 647 same account, for example if you use it for several different deployed
 648 applications independently, you can use one bootstrapped local::lib
 649 installation to install modules in different directories directly this way:
 650
 651   cd ~/mydir1
 652   perl -Mlocal::lib=./
 653   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 654   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 655   perl -MCPAN -e install ...    ### whatever modules you want
 656   cd ../mydir2
 657   ... REPEAT ...
 658
 659 If you are working with several C<local::lib> environments, you may want to
 660 remove some of them from the current environment without disturbing the others.
 661 You can deactivate one environment like this (using bourne sh):
 662
 663   eval $(perl -Mlocal::lib=--deactivate,~/path)
 664
 665 which will generate and run the commands needed to remove C<~/path> from your
 666 various search paths. Whichever environment was B<activated most recently> will
 667 remain the target for module installations. That is, if you activate
 668 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 669 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 670 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 671 installed in C<~/pathB> because pathB was activated later.
 672
 673 You can also ask C<local::lib> to clean itself completely out of the current
 674 shell's environment with the C<--deactivate-all> option.
 675 For multiple environments for multiple apps you may need to include a modified
 676 version of the C<< use FindBin >> instructions in the "In code" sample above.
 677 If you did something like the above, you have a set of Perl modules at C<<
 678 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 679 you need to tell it where to find the modules you installed for it at C<<
 680 ~/mydir1/lib >>.
 681
 682 In C<< ~/mydir1/scripts/myscript.pl >>:
 683
 684   use strict;
 685   use warnings;
 686   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 687   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 688
 689 Put this before any BEGIN { ... } blocks that require the modules you installed.
 690
 691 =head2 Differences when using this module under Win32
 692
 693 To set up the proper environment variables for your current session of
 694 C<CMD.exe>, you can use this:
 695
 696   C:\>perl -Mlocal::lib
 697   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 698   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 699   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 700   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 701
 702   ### To set the environment for this shell alone
 703   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 704   ### instead of $(perl -Mlocal::lib=./)
 705
 706 If you want the environment entries to persist, you'll need to add then to the
 707 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 708
 709 The "~" is translated to the user's profile directory (the directory named for
 710 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 711 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 712 directory is translated to a short name (which means the directory must exist)
 713 and the subdirectories are created.
 714
 715 =head1 RATIONALE
 716
 717 The version of a Perl package on your machine is not always the version you
 718 need.  Obviously, the best thing to do would be to update to the version you
 719 need.  However, you might be in a situation where you're prevented from doing
 720 this.  Perhaps you don't have system administrator privileges; or perhaps you
 721 are using a package management system such as Debian, and nobody has yet gotten
 722 around to packaging up the version you need.
 723
 724 local::lib solves this problem by allowing you to create your own directory of
 725 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 726 be within your own home directory).  The existing system Perl installation is
 727 not affected; you simply invoke Perl with special options so that Perl uses the
 728 packages in your own local package directory rather than the system packages.
 729 local::lib arranges things so that your locally installed version of the Perl
 730 packages takes precedence over the system installation.
 731
 732 If you are using a package management system (such as Debian), you don't need to
 733 worry about Debian and CPAN stepping on each other's toes.  Your local version
 734 of the packages will be written to an entirely separate directory from those
 735 installed by Debian.
 736
 737 =head1 DESCRIPTION
 738
 739 This module provides a quick, convenient way of bootstrapping a user-local Perl
 740 module library located within the user's home directory. It also constructs and
 741 prints out for the user the list of environment variables using the syntax
 742 appropriate for the user's current shell (as specified by the C<SHELL>
 743 environment variable), suitable for directly adding to one's shell
 744 configuration file.
 745
 746 More generally, local::lib allows for the bootstrapping and usage of a
 747 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 748 easier to ship an application with an app-specific copy of a Perl module, or
 749 collection of modules. Useful in cases like when an upstream maintainer hasn't
 750 applied a patch to a module of theirs that you need for your application.
 751
 752 On import, local::lib sets the following environment variables to appropriate
 753 values:
 754
 755 =over 4
 756
 757 =item PERL_MB_OPT
 758
 759 =item PERL_MM_OPT
 760
 761 =item PERL5LIB
 762
 763 =item PATH
 764
 765 =back
 766
 767 When possible, these will be appended to instead of overwritten entirely.
 768
 769 These values are then available for reference by any code after import.
 770
 771 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 772
 773 See L<lib::core::only> for one way to do this - but note that
 774 there are a number of caveats, and the best approach is always to perform a
 775 build against a clean perl (i.e. site and vendor as close to empty as possible).
 776
 777 =head1 OPTIONS
 778
 779 Options are values that can be passed to the C<local::lib> import besides the
 780 directory to use. They are specified as C<use local::lib '--option'[, path];>
 781 or C<perl -Mlocal::lib=--option[,path]>.
 782
 783 =head2 --deactivate
 784
 785 Remove the chosen path (or the default path) from the module search paths if it
 786 was added by C<local::lib>, instead of adding it.
 787
 788 =head2 --deactivate-all
 789
 790 Remove all directories that were added to search paths by C<local::lib> from the
 791 search paths.
 792
 793 =head2 --shelltype
 794
 795 Specify the shell type to use for output.  By default, the shell will be
 796 detected based on the environment.  Should be one of: C<bourne>, C<csh>,
 797 C<cmd>, or C<powershell>.
 798
 799 =head2 --no-create
 800
 801 Prevents C<local::lib> from creating directories when activating dirs.  This is
 802 likely to cause issues on Win32 systems.
 803
 804 =head1 METHODS
 805
 806 =head2 ensure_dir_structure_for
 807
 808 =over 4
 809
 810 =item Arguments: $path
 811
 812 =item Return value: None
 813
 814 =back
 815
 816 Attempts to create the given path, and all required parent directories. Throws
 817 an exception on failure.
 818
 819 =head2 print_environment_vars_for
 820
 821 =over 4
 822
 823 =item Arguments: $path
 824
 825 =item Return value: None
 826
 827 =back
 828
 829 Prints to standard output the variables listed above, properly set to use the
 830 given path as the base directory.
 831
 832 =head2 build_environment_vars_for
 833
 834 =over 4
 835
 836 =item Arguments: $path
 837
 838 =item Return value: %environment_vars
 839
 840 =back
 841
 842 Returns a hash with the variables listed above, properly set to use the
 843 given path as the base directory.
 844
 845 =head2 setup_env_hash_for
 846
 847 =over 4
 848
 849 =item Arguments: $path
 850
 851 =item Return value: None
 852
 853 =back
 854
 855 Constructs the C<%ENV> keys for the given path, by calling
 856 L</build_environment_vars_for>.
 857
 858 =head2 active_paths
 859
 860 =over 4
 861
 862 =item Arguments: None
 863
 864 =item Return value: @paths
 865
 866 =back
 867
 868 Returns a list of active C<local::lib> paths, according to the
 869 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 870 what is really in C<@INC>.
 871
 872 =head2 install_base_perl_path
 873
 874 =over 4
 875
 876 =item Arguments: $path
 877
 878 =item Return value: $install_base_perl_path
 879
 880 =back
 881
 882 Returns a path describing where to install the Perl modules for this local
 883 library installation. Appends the directories C<lib> and C<perl5> to the given
 884 path.
 885
 886 =head2 install_base_bin_path
 887
 888 =over 4
 889
 890 =item Arguments: $path
 891
 892 =item Return value: $install_base_bin_path
 893
 894 =back
 895
 896 Returns a path describing where to install the executable programs for this
 897 local library installation. Appends the directory C<bin> to the given path.
 898
 899 =head2 resolve_empty_path
 900
 901 =over 4
 902
 903 =item Arguments: $path
 904
 905 =item Return value: $base_path
 906
 907 =back
 908
 909 Builds and returns the base path into which to set up the local module
 910 installation. Defaults to C<~/perl5>.
 911
 912 =head2 resolve_home_path
 913
 914 =over 4
 915
 916 =item Arguments: $path
 917
 918 =item Return value: $home_path
 919
 920 =back
 921
 922 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 923 for this purpose. If no definite answer is available, throws an exception.
 924
 925 =head2 resolve_relative_path
 926
 927 =over 4
 928
 929 =item Arguments: $path
 930
 931 =item Return value: $absolute_path
 932
 933 =back
 934
 935 Translates the given path into an absolute path.
 936
 937 =head2 resolve_path
 938
 939 =over 4
 940
 941 =item Arguments: $path
 942
 943 =item Return value: $absolute_path
 944
 945 =back
 946
 947 Calls the following in a pipeline, passing the result from the previous to the
 948 next, in an attempt to find where to configure the environment for a local
 949 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 950 L</resolve_relative_path>. Passes the given path argument to
 951 L</resolve_empty_path> which then returns a result that is passed to
 952 L</resolve_home_path>, which then has its result passed to
 953 L</resolve_relative_path>. The result of this final call is returned from
 954 L</resolve_path>.
 955
 956 =head1 A WARNING ABOUT UNINST=1
 957
 958 Be careful about using local::lib in combination with "make install UNINST=1".
 959 The idea of this feature is that will uninstall an old version of a module
 960 before installing a new one. However it lacks a safety check that the old
 961 version and the new version will go in the same directory. Used in combination
 962 with local::lib, you can potentially delete a globally accessible version of a
 963 module while installing the new version in a local place. Only combine "make
 964 install UNINST=1" and local::lib if you understand these possible consequences.
 965
 966 =head1 LIMITATIONS
 967
 968 =over 4
 969
 970 =item * Directory names with spaces in them are not well supported by the perl
 971 toolchain and the programs it uses.  Pure-perl distributions should support
 972 spaces, but problems are more likely with dists that require compilation. A
 973 workaround you can do is moving your local::lib to a directory with spaces
 974 B<after> you installed all modules inside your local::lib bootstrap. But be
 975 aware that you can't update or install CPAN modules after the move.
 976
 977 =item * Rather basic shell detection. Right now anything with csh in its name is
 978 assumed to be a C shell or something compatible, and everything else is assumed
 979 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 980 not set, a Bourne-compatible shell is assumed.
 981
 982 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
 983
 984 =item * Should probably auto-fixup CPAN config if not already done.
 985
 986 =back
 987
 988 Patches very much welcome for any of the above.
 989
 990 =over 4
 991
 992 =item * On Win32 systems, does not have a way to write the created environment
 993 variables to the registry, so that they can persist through a reboot.
 994
 995 =back
 996
 997 =head1 TROUBLESHOOTING
 998
 999 If you've configured local::lib to install CPAN modules somewhere in to your
1000 home directory, and at some point later you try to install a module with C<cpan
1001 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
1002 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
1003 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
1004 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
1005 you've somehow lost your updated ExtUtils::MakeMaker module.
1006
1007 To remedy this situation, rerun the bootstrapping procedure documented above.
1008
1009 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
1010
1011 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1012
1013 =head1 ENVIRONMENT
1014
1015 =over 4
1016
1017 =item SHELL
1018
1019 =item COMSPEC
1020
1021 local::lib looks at the user's C<SHELL> environment variable when printing out
1022 commands to add to the shell configuration file.
1023
1024 On Win32 systems, C<COMSPEC> is also examined.
1025
1026 =back
1027
1028 =head1 SEE ALSO
1029
1030 =over 4
1031
1032 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1033
1034 =back
1035
1036 =head1 SUPPORT
1037
1038 IRC:
1039
1040     Join #local-lib on irc.perl.org.
1041
1042 =head1 AUTHOR
1043
1044 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1045
1046 auto_install fixes kindly sponsored by http://www.takkle.com/
1047
1048 =head1 CONTRIBUTORS
1049
1050 Patches to correctly output commands for csh style shells, as well as some
1051 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1052
1053 Doc patches for a custom local::lib directory, more cleanups in the english
1054 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1055 Torsten Raudssus <torsten@raudssus.de>.
1056
1057 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1058 things will install properly, submitted a fix for the bug causing problems with
1059 writing Makefiles during bootstrapping, contributed an example program, and
1060 submitted yet another fix to ensure that local::lib can install and bootstrap
1061 properly. Many, many thanks!
1062
1063 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1064 section. Many thanks!
1065
1066 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1067
1068 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1069 by a patch from Marco Emilio Poleggi.
1070
1071 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1072 '--self-contained' option.
1073
1074 Documentation patches to make win32 usage clearer by
1075 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1076
1077 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1078 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1079
1080 Improvements to stacking multiple local::lib dirs and removing them from the
1081 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1082
1083 Patch for Carp version mismatch contributed by Hakim Cassimally
1084 <osfameron@cpan.org>.
1085
1086 =head1 COPYRIGHT
1087
1088 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1089 listed above.
1090
1091 =head1 LICENSE
1092
1093 This is free software; you can redistribute it and/or modify it under
1094 the same terms as the Perl 5 programming language system itself.
1095
1096 =cut