lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.006;
   7
   8 use File::Spec ();
   9 use Config;
  10
  11 our $VERSION = '1.008026'; # 1.8.26
  12 $VERSION = eval $VERSION;
  13
  14 sub import {
  15   my ($class, @args) = @_;
  16
  17   my @steps;
  18   my %opts;
  19
  20   while (@args) {
  21     my $arg = shift @args;
  22     # check for lethal dash first to stop processing before causing problems
  23     # the fancy dash is U+2212 or \xE2\x88\x92
  24     if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) {
  25       die <<'DEATH';
  26 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  27 These are *not* the traditional -- dashes that software recognizes. You
  28 probably got these by copy-pasting from the perldoc for this module as
  29 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  30 terminal, but can happen elsewhere too. Please try again after replacing the
  31 dashes with normal minus signs.
  32 DEATH
  33     }
  34     elsif ($arg eq '--self-contained') {
  35       die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n";
  36     }
  37     elsif( $arg =~ /^--deactivate(?:=(.*))?$/ ) {
  38       my $path = defined $1 ? $1 : shift @args;
  39       push @steps, ['deactivate', $path];
  40     }
  41     elsif ( $arg eq '--deactivate-all' ) {
  42       push @steps, ['deactivate_all'];
  43     }
  44     elsif ( $arg =~ /^--shelltype(?:=(.*))?$/ ) {
  45       my $shell = defined $1 ? $1 : shift @args;
  46       $opts{shelltype} = $shell;
  47     }
  48     elsif ( $arg =~ /^--/ ) {
  49       die "Unknown import argument: $arg";
  50     }
  51     else {
  52       push @steps, ['activate', $arg];
  53     }
  54   }
  55   if (!@steps) {
  56     push @steps, ['activate', undef];
  57   }
  58
  59   my $self = $class->new(%opts);
  60
  61   for (@steps) {
  62     my ($method, @args) = @$_;
  63     $self = $self->$method(@args);
  64   }
  65
  66   if ($0 eq '-') {
  67     $self->print_environment_vars_for;
  68     exit 0;
  69   }
  70   else {
  71     $self->setup_local_lib_for;
  72   }
  73 }
  74
  75 sub new {
  76   my $class = shift;
  77   bless {@_}, $class;
  78 }
  79
  80 sub clone {
  81   my $self = shift;
  82   bless {%$self, @_}, ref $self;
  83 }
  84
  85 sub inc { $_[0]->{inc}     ||= \@INC }
  86 sub libs { $_[0]->{libs}   ||= [ \'PERL5LIB' ] }
  87 sub bins { $_[0]->{bins}   ||= [ \'PATH' ] }
  88 sub roots { $_[0]->{roots} ||= [ \'PERL_LOCAL_LIB_ROOT' ] }
  89 sub extra { $_[0]->{extra} ||= {} }
  90 sub shelltype { $_[0]->{shelltype} ||= $_[0]->guess_shelltype }
  91
  92 my $_archname = $Config{archname};
  93 my $_version  = $Config{version};
  94 my @_inc_version_list = reverse split / /, $Config{inc_version_list};
  95 my $_path_sep = $Config{path_sep};
  96
  97 sub _as_list {
  98   my $list = shift;
  99   grep length, map {
 100     !(ref $_ && ref $_ eq 'SCALAR') ? $_ : (
 101       defined $ENV{$$_} ? split(/\Q$_path_sep/, $ENV{$$_})
 102                         : ()
 103     )
 104   } ref $list ? @$list : $list;
 105 }
 106 sub _remove_from {
 107   my ($list, @remove) = @_;
 108   my %remove = map { $_ => 1 } @remove;
 109   grep !$remove{$_}, _as_list($list);
 110 }
 111
 112 my @_lib_subdirs = (
 113   [$_version, $_archname],
 114   [$_version],
 115   [$_archname],
 116   (@_inc_version_list ? \@_inc_version_list : ()),
 117   [],
 118 );
 119
 120 sub install_base_bin_path {
 121   my ($class, $path) = @_;
 122   return File::Spec->catdir($path, 'bin');
 123 }
 124 sub install_base_perl_path {
 125   my ($class, $path) = @_;
 126   return File::Spec->catdir($path, 'lib', 'perl5');
 127 }
 128 sub install_base_arch_path {
 129   my ($class, $path) = @_;
 130   File::Spec->catdir($class->install_base_perl_path($path), $_archname);
 131 }
 132
 133 sub lib_paths_for {
 134   my ($class, $path) = @_;
 135   my $base = $class->install_base_perl_path($path);
 136   return map { File::Spec->catdir($base, @$_) } @_lib_subdirs;
 137 }
 138
 139 sub _mm_escape_path {
 140   my $path = shift;
 141   $path =~ s/\\/\\\\\\\\/g;
 142   if ($path =~ s/ /\\ /g) {
 143     $path = qq{"\\"$path\\""};
 144   }
 145   return $path;
 146 }
 147
 148 sub _mb_escape_path {
 149   my $path = shift;
 150   $path =~ s/\\/\\\\/g;
 151   return qq{"$path"};
 152 }
 153
 154 sub installer_options_for {
 155   my ($class, $path) = @_;
 156   return {
 157     PERL_MM_OPT => defined $path ? "INSTALL_BASE="._mm_escape_path($path) : undef,
 158     PERL_MB_OPT => defined $path ? "--install_base "._mb_escape_path($path) : undef,
 159   };
 160 }
 161
 162 sub active_paths {
 163   my ($self) = @_;
 164   $self = ref $self ? $self : $self->new;
 165
 166   return grep {
 167     # screen out entries that aren't actually reflected in @INC
 168     my $active_ll = $self->install_base_perl_path($_);
 169     grep { $_ eq $active_ll } @{$self->inc};
 170   } _as_list($self->roots);
 171 }
 172
 173
 174 sub deactivate {
 175   my ($self, $path) = @_;
 176   $self = $self->new unless ref $self;
 177   $path = $self->resolve_path($path);
 178
 179   my @active_lls = $self->active_paths;
 180
 181   if (!grep { $_ eq $path } @active_lls) {
 182     warn "Tried to deactivate inactive local::lib '$path'\n";
 183     return;
 184   }
 185
 186   my %args = (
 187     bins  => [ _remove_from($self->bins,  $self->install_base_bin_path($path)) ],
 188     libs  => [ _remove_from($self->libs,  $self->install_base_perl_path($path)) ],
 189     inc   => [ _remove_from($self->inc,   $self->lib_paths_for($path)) ],
 190     roots => [ _remove_from($self->roots, $path) ],
 191   );
 192
 193   $args{extra} = $self->installer_options_for($args{roots}[0]);
 194
 195   $self->clone(%args);
 196 }
 197
 198 sub deactivate_all {
 199   my ($self) = @_;
 200   $self = $self->new unless ref $self;
 201
 202   my @active_lls = $self->active_paths;
 203
 204   my %args = (
 205     bins => [ _remove_from($self->bins,
 206       map $self->install_base_bin_path($_), @active_lls) ],
 207     libs => [ _remove_from($self->libs,
 208       map $self->install_base_perl_path($_), @active_lls) ],
 209     inc => [ _remove_from($self->inc,
 210       map $self->lib_paths_for($_), @active_lls) ],
 211     roots => [ _remove_from($self->roots, @active_lls) ],
 212   );
 213
 214   $args{extra} = $self->installer_options_for(undef);
 215
 216   $self->clone(%args);
 217 }
 218
 219 sub activate {
 220   my ($self, $path) = @_;
 221   $self = $self->new unless ref $self;
 222   $path = $self->resolve_path($path);
 223   $self->ensure_dir_structure_for($path);
 224
 225   my @active_lls = $self->active_paths;
 226
 227   if (grep { $_ eq $path } @active_lls) {
 228     $self = $self->deactivate($path);
 229   }
 230
 231   my %args = (
 232     bins  => [ $self->install_base_bin_path($path), @{$self->bins} ],
 233     libs  => [ $self->install_base_perl_path($path), @{$self->libs} ],
 234     inc   => [ $self->lib_paths_for($path), @{$self->inc} ],
 235     roots => [ $path, @{$self->roots} ],
 236   );
 237
 238   $args{extra} = $self->installer_options_for($path);
 239
 240   $self->clone(%args);
 241 }
 242
 243 sub _legacy {
 244   my ($self, $path, $deactivating) = @_;
 245   $self = $self->new unless ref $self;
 246   $self = $self->${\($deactivating ? 'deactivate' : 'activate')}($path) if defined $path;
 247   $self;
 248 }
 249
 250 sub build_environment_vars_for {
 251   my ($self) = _legacy(@_);
 252   (
 253     PATH                => join($_path_sep, _as_list($self->bins)),
 254     PERL5LIB            => join($_path_sep, _as_list($self->libs)),
 255     PERL_LOCAL_LIB_ROOT => join($_path_sep, _as_list($self->roots)),
 256     %{$self->extra},
 257   );
 258 }
 259
 260 sub setup_local_lib_for {
 261   my ($self) = _legacy(@_);
 262   $self->setup_env_hash_for;
 263   @INC = @{$self->inc};
 264 }
 265
 266 sub setup_env_hash_for {
 267   my $self = shift;
 268   my %env = $self->build_environment_vars_for(@_);
 269   for my $key (keys %env) {
 270     if (defined $env{$key}) {
 271       $ENV{$key} = $env{$key};
 272     }
 273     else {
 274       delete $ENV{$key};
 275     }
 276   }
 277 }
 278
 279 sub print_environment_vars_for {
 280   my $self = shift;
 281   print $self->environment_vars_string_for(@_);
 282 }
 283
 284 sub environment_vars_string_for {
 285   my $self = _legacy(@_);
 286
 287   my $build_method = 'build_' . $self->shelltype . '_env_declaration';
 288
 289   my @envs = (
 290     PATH                => $self->bins,
 291     PERL5LIB            => $self->libs,
 292     PERL_LOCAL_LIB_ROOT => $self->roots,
 293     %{$self->extra},
 294   );
 295   my $out = '';
 296   while (@envs) {
 297     my ($name, $value) = (shift(@envs), shift(@envs));
 298     if (
 299         ref $value
 300         && @$value == 1
 301         && ref $value->[0]
 302         && ref $value->[0] eq 'SCALAR'
 303         && ${$value->[0]} eq $name) {
 304       next;
 305     }
 306     $out .= $self->$build_method($name, $value);
 307   }
 308   return $out;
 309 }
 310
 311 sub build_bourne_env_declaration {
 312   my ($class, $name, $args) = @_;
 313   my $value = $class->_interpolate($args);
 314   $value =~ s/"/\\"/g
 315     if defined $value;
 316   return defined($value) ? qq{export ${name}="${value}"\n} : qq{unset ${name}\n};
 317 }
 318 sub build_csh_env_declaration {
 319   my ($class, $name, $args) = @_;
 320   my ($value, @vars) = $class->_interpolate($args);
 321   @vars = grep { $_ ne $name || defined $value } @vars;
 322   $value =~ s/"/"\\""/g
 323     if defined $value;
 324   join '',
 325     (map qq{if ! \$?$_ setenv $_ "";\n}, @vars),
 326     (defined($value)
 327       ? qq{setenv $name "$value";\n}
 328       : qq{unsetenv $name;\n});
 329 }
 330 sub build_cmd_env_declaration {
 331   my ($class, $name, $args) = @_;
 332   my $value = $class->_interpolate($args, '%', '%');
 333   $value =~ s/"/\\"/g
 334     if defined $value;
 335   return qq{set $name=} . (defined($value) ? qq{"$value"} : '') . "\n";
 336 }
 337 sub build_powershell_env_declaration {
 338   my ($class, $name, $args) = @_;
 339   my $value = $class->_interpolate($args, '$env:');
 340   if (defined $value) {
 341     $value =~ s/"/\\"/g;
 342     return qq{\$env:$name = "$value"\n};
 343   }
 344   return "Remove-Item Env:\\$name\n";
 345 }
 346
 347
 348 sub _interpolate {
 349   my ($class, $args, $start, $end) = @_;
 350   return
 351     unless defined $args;
 352   return $args
 353     unless ref $args;
 354   return
 355     unless @$args;
 356   $start = '$' unless defined $start;
 357   $end = '' unless defined $end;
 358   my @vars;
 359   my $string = join($Config{path_sep}, map {
 360     (ref $_ && ref $_ eq 'SCALAR') ? do { push @vars, $$_; $start.$$_.$end }
 361       : $_
 362   } @$args);
 363   return wantarray ? ($string, @vars) : $string;
 364 }
 365
 366 sub pipeline;
 367
 368 sub pipeline {
 369   my @methods = @_;
 370   my $last = pop(@methods);
 371   if (@methods) {
 372     \sub {
 373       my ($obj, @args) = @_;
 374       $obj->${pipeline @methods}(
 375         $obj->$last(@args)
 376       );
 377     };
 378   } else {
 379     \sub {
 380       shift->$last(@_);
 381     };
 382   }
 383 }
 384
 385 =begin testing
 386
 387 #:: test pipeline
 388
 389 package local::lib;
 390
 391 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 392 my $foo = bless({}, 'Foo');
 393 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 394
 395 =end testing
 396
 397 =cut
 398
 399 sub resolve_path {
 400   my ($class, $path) = @_;
 401
 402   $path = $class->${pipeline qw(
 403     resolve_relative_path
 404     resolve_home_path
 405     resolve_empty_path
 406   )}($path);
 407
 408   $path = Win32::GetShortPathName($path)
 409     if $^O eq 'MSWin32';
 410
 411   $path;
 412 }
 413
 414 sub resolve_empty_path {
 415   my ($class, $path) = @_;
 416   if (defined $path) {
 417     $path;
 418   } else {
 419     '~/perl5';
 420   }
 421 }
 422
 423 =begin testing
 424
 425 #:: test classmethod setup
 426
 427 my $c = 'local::lib';
 428
 429 =end testing
 430
 431 =begin testing
 432
 433 #:: test classmethod
 434
 435 is($c->resolve_empty_path, '~/perl5');
 436 is($c->resolve_empty_path('foo'), 'foo');
 437
 438 =end testing
 439
 440 =cut
 441
 442 sub resolve_home_path {
 443   my ($class, $path) = @_;
 444   return $path unless ($path =~ /^~/);
 445   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 446   my $homedir = do {
 447     if (!defined $user && defined $ENV{HOME}) {
 448       $ENV{HOME}
 449     }
 450     else {
 451       require File::Glob;
 452       File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE());
 453     }
 454   };
 455   unless (defined $homedir) {
 456     require Carp;
 457     Carp::croak(
 458       "Couldn't resolve homedir for "
 459       .(defined $user ? $user : 'current user')
 460     );
 461   }
 462   $path =~ s/^~[^\/]*/$homedir/;
 463   $path;
 464 }
 465
 466 sub resolve_relative_path {
 467   my ($class, $path) = @_;
 468   $path = File::Spec->rel2abs($path);
 469 }
 470
 471 =begin testing
 472
 473 #:: test classmethod
 474
 475 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 476 is($c->resolve_relative_path('bar'),'FOObar');
 477
 478 =end testing
 479
 480 =cut
 481
 482 sub ensure_dir_structure_for {
 483   my ($class, $path) = @_;
 484   unless (-d $path) {
 485     warn "Attempting to create directory ${path}\n";
 486   }
 487   require File::Basename;
 488   my @dirs;
 489   while(!-d $path) {
 490     push @dirs, $path;
 491     $path = File::Basename::dirname($path);
 492   }
 493   mkdir $_ for reverse @dirs;
 494   return;
 495 }
 496
 497 =begin testing
 498
 499 #:: test classmethod
 500
 501 File::Path::rmtree('t/var/splat');
 502
 503 $c->ensure_dir_structure_for('t/var/splat');
 504
 505 ok(-d 't/var/splat');
 506
 507 =end testing
 508
 509 =cut
 510
 511 sub guess_shelltype {
 512   my $shellbin = 'sh';
 513   if(defined $ENV{'SHELL'}) {
 514       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 515       $shellbin = $shell_bin_path_parts[-1];
 516   }
 517   my $shelltype = do {
 518       local $_ = $shellbin;
 519       if(/csh/) {
 520           'csh'
 521       } else {
 522           'bourne'
 523       }
 524   };
 525
 526   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 527   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 528       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 529       $shellbin = $shell_bin_path_parts[-1];
 530          $shelltype = do {
 531                  local $_ = $shellbin;
 532                  if(/command\.com/) {
 533                          'cmd'
 534                  } elsif(/cmd\.exe/) {
 535                          'cmd'
 536                  } elsif(/4nt\.exe/) {
 537                          'cmd'
 538                  } else {
 539                          $shelltype
 540                  }
 541          };
 542   }
 543   return $shelltype;
 544 }
 545
 546 1;
 547 __END__
 548
 549 =encoding utf8
 550
 551 =head1 NAME
 552
 553 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 554
 555 =head1 SYNOPSIS
 556
 557 In code -
 558
 559   use local::lib; # sets up a local lib at ~/perl5
 560
 561   use local::lib '~/foo'; # same, but ~/foo
 562
 563   # Or...
 564   use FindBin;
 565   use local::lib "$FindBin::Bin/../support";  # app-local support library
 566
 567 From the shell -
 568
 569   # Install LWP and its missing dependencies to the '~/perl5' directory
 570   perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)'
 571
 572   # Just print out useful shell commands
 573   $ perl -Mlocal::lib
 574   export PERL_MB_OPT='--install_base /home/username/perl5'
 575   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5'
 576   export PERL5LIB="/home/username/perl5/lib/perl5"
 577   export PATH="/home/username/perl5/bin:$PATH"
 578
 579 =head2 The bootstrapping technique
 580
 581 A typical way to install local::lib is using what is known as the
 582 "bootstrapping" technique.  You would do this if your system administrator
 583 hasn't already installed local::lib.  In this case, you'll need to install
 584 local::lib in your home directory.
 585
 586 Even if you do have administrative privileges, you will still want to set up your
 587 environment variables, as discussed in step 4. Without this, you would still
 588 install the modules into the system CPAN installation and also your Perl scripts
 589 will not use the lib/ path you bootstrapped with local::lib.
 590
 591 By default local::lib installs itself and the CPAN modules into ~/perl5.
 592
 593 Windows users must also see L</Differences when using this module under Win32>.
 594
 595 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 596 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 597 or administrator.  Unpack the file in your home directory or in any other
 598 convenient location.
 599
 600 2. Run this:
 601
 602   perl Makefile.PL --bootstrap
 603
 604 If the system asks you whether it should automatically configure as much
 605 as possible, you would typically answer yes.
 606
 607 In order to install local::lib into a directory other than the default, you need
 608 to specify the name of the directory when you call bootstrap, as follows:
 609
 610   perl Makefile.PL --bootstrap=~/foo
 611
 612 3. Run this: (local::lib assumes you have make installed on your system)
 613
 614   make test && make install
 615
 616 4. Now we need to setup the appropriate environment variables, so that Perl
 617 starts using our newly generated lib/ directory. If you are using bash or
 618 any other Bourne shells, you can add this to your shell startup script this
 619 way:
 620
 621   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 622
 623 If you are using C shell, you can do this as follows:
 624
 625   /bin/csh
 626   echo $SHELL
 627   /bin/csh
 628   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 629
 630 If you passed to bootstrap a directory other than default, you also need to
 631 give that as import parameter to the call of the local::lib module like this
 632 way:
 633
 634   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 635
 636 After writing your shell configuration file, be sure to re-read it to get the
 637 changed settings into your current shell's environment. Bourne shells use
 638 C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>.
 639
 640 If you're on a slower machine, or are operating under draconian disk space
 641 limitations, you can disable the automatic generation of manpages from POD when
 642 installing modules by using the C<--no-manpages> argument when bootstrapping:
 643
 644   perl Makefile.PL --bootstrap --no-manpages
 645
 646 To avoid doing several bootstrap for several Perl module environments on the
 647 same account, for example if you use it for several different deployed
 648 applications independently, you can use one bootstrapped local::lib
 649 installation to install modules in different directories directly this way:
 650
 651   cd ~/mydir1
 652   perl -Mlocal::lib=./
 653   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 654   printenv                      ### You will see that ~/mydir1 is in the PERL5LIB
 655   perl -MCPAN -e install ...    ### whatever modules you want
 656   cd ../mydir2
 657   ... REPEAT ...
 658
 659 If you are working with several C<local::lib> environments, you may want to
 660 remove some of them from the current environment without disturbing the others.
 661 You can deactivate one environment like this (using bourne sh):
 662
 663   eval $(perl -Mlocal::lib=--deactivate,~/path)
 664
 665 which will generate and run the commands needed to remove C<~/path> from your
 666 various search paths. Whichever environment was B<activated most recently> will
 667 remain the target for module installations. That is, if you activate
 668 C<~/path_A> and then you activate C<~/path_B>, new modules you install will go
 669 in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed
 670 into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be
 671 installed in C<~/pathB> because pathB was activated later.
 672
 673 You can also ask C<local::lib> to clean itself completely out of the current
 674 shell's environment with the C<--deactivate-all> option.
 675 For multiple environments for multiple apps you may need to include a modified
 676 version of the C<< use FindBin >> instructions in the "In code" sample above.
 677 If you did something like the above, you have a set of Perl modules at C<<
 678 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 679 you need to tell it where to find the modules you installed for it at C<<
 680 ~/mydir1/lib >>.
 681
 682 In C<< ~/mydir1/scripts/myscript.pl >>:
 683
 684   use strict;
 685   use warnings;
 686   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 687   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 688
 689 Put this before any BEGIN { ... } blocks that require the modules you installed.
 690
 691 =head2 Differences when using this module under Win32
 692
 693 To set up the proper environment variables for your current session of
 694 C<CMD.exe>, you can use this:
 695
 696   C:\>perl -Mlocal::lib
 697   set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5
 698   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 699   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5
 700   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 701
 702   ### To set the environment for this shell alone
 703   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat
 704   ### instead of $(perl -Mlocal::lib=./)
 705
 706 If you want the environment entries to persist, you'll need to add then to the
 707 Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>.
 708
 709 The "~" is translated to the user's profile directory (the directory named for
 710 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 711 (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home
 712 directory is translated to a short name (which means the directory must exist)
 713 and the subdirectories are created.
 714
 715 =head1 RATIONALE
 716
 717 The version of a Perl package on your machine is not always the version you
 718 need.  Obviously, the best thing to do would be to update to the version you
 719 need.  However, you might be in a situation where you're prevented from doing
 720 this.  Perhaps you don't have system administrator privileges; or perhaps you
 721 are using a package management system such as Debian, and nobody has yet gotten
 722 around to packaging up the version you need.
 723
 724 local::lib solves this problem by allowing you to create your own directory of
 725 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 726 be within your own home directory).  The existing system Perl installation is
 727 not affected; you simply invoke Perl with special options so that Perl uses the
 728 packages in your own local package directory rather than the system packages.
 729 local::lib arranges things so that your locally installed version of the Perl
 730 packages takes precedence over the system installation.
 731
 732 If you are using a package management system (such as Debian), you don't need to
 733 worry about Debian and CPAN stepping on each other's toes.  Your local version
 734 of the packages will be written to an entirely separate directory from those
 735 installed by Debian.
 736
 737 =head1 DESCRIPTION
 738
 739 This module provides a quick, convenient way of bootstrapping a user-local Perl
 740 module library located within the user's home directory. It also constructs and
 741 prints out for the user the list of environment variables using the syntax
 742 appropriate for the user's current shell (as specified by the C<SHELL>
 743 environment variable), suitable for directly adding to one's shell
 744 configuration file.
 745
 746 More generally, local::lib allows for the bootstrapping and usage of a
 747 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 748 easier to ship an application with an app-specific copy of a Perl module, or
 749 collection of modules. Useful in cases like when an upstream maintainer hasn't
 750 applied a patch to a module of theirs that you need for your application.
 751
 752 On import, local::lib sets the following environment variables to appropriate
 753 values:
 754
 755 =over 4
 756
 757 =item PERL_MB_OPT
 758
 759 =item PERL_MM_OPT
 760
 761 =item PERL5LIB
 762
 763 =item PATH
 764
 765 =back
 766
 767 When possible, these will be appended to instead of overwritten entirely.
 768
 769 These values are then available for reference by any code after import.
 770
 771 =head1 CREATING A SELF-CONTAINED SET OF MODULES
 772
 773 See L<lib::core::only> for one way to do this - but note that
 774 there are a number of caveats, and the best approach is always to perform a
 775 build against a clean perl (i.e. site and vendor as close to empty as possible).
 776
 777 =head1 OPTIONS
 778
 779 Options are values that can be passed to the C<local::lib> import besides the
 780 directory to use. They are specified as C<use local::lib '--option'[, path];>
 781 or C<perl -Mlocal::lib=--option[,path]>.
 782
 783 =head2 --deactivate
 784
 785 Remove the chosen path (or the default path) from the module search paths if it
 786 was added by C<local::lib>, instead of adding it.
 787
 788 =head2 --deactivate-all
 789
 790 Remove all directories that were added to search paths by C<local::lib> from the
 791 search paths.
 792
 793 =head1 METHODS
 794
 795 =head2 ensure_dir_structure_for
 796
 797 =over 4
 798
 799 =item Arguments: $path
 800
 801 =item Return value: None
 802
 803 =back
 804
 805 Attempts to create the given path, and all required parent directories. Throws
 806 an exception on failure.
 807
 808 =head2 print_environment_vars_for
 809
 810 =over 4
 811
 812 =item Arguments: $path
 813
 814 =item Return value: None
 815
 816 =back
 817
 818 Prints to standard output the variables listed above, properly set to use the
 819 given path as the base directory.
 820
 821 =head2 build_environment_vars_for
 822
 823 =over 4
 824
 825 =item Arguments: $path, $interpolate
 826
 827 =item Return value: %environment_vars
 828
 829 =back
 830
 831 Returns a hash with the variables listed above, properly set to use the
 832 given path as the base directory.
 833
 834 =head2 setup_env_hash_for
 835
 836 =over 4
 837
 838 =item Arguments: $path
 839
 840 =item Return value: None
 841
 842 =back
 843
 844 Constructs the C<%ENV> keys for the given path, by calling
 845 L</build_environment_vars_for>.
 846
 847 =head2 active_paths
 848
 849 =over 4
 850
 851 =item Arguments: None
 852
 853 =item Return value: @paths
 854
 855 =back
 856
 857 Returns a list of active C<local::lib> paths, according to the
 858 C<PERL_LOCAL_LIB_ROOT> environment variable and verified against
 859 what is really in C<@INC>.
 860
 861 =head2 install_base_perl_path
 862
 863 =over 4
 864
 865 =item Arguments: $path
 866
 867 =item Return value: $install_base_perl_path
 868
 869 =back
 870
 871 Returns a path describing where to install the Perl modules for this local
 872 library installation. Appends the directories C<lib> and C<perl5> to the given
 873 path.
 874
 875 =head2 install_base_bin_path
 876
 877 =over 4
 878
 879 =item Arguments: $path
 880
 881 =item Return value: $install_base_bin_path
 882
 883 =back
 884
 885 Returns a path describing where to install the executable programs for this
 886 local library installation. Appends the directory C<bin> to the given path.
 887
 888 =head2 resolve_empty_path
 889
 890 =over 4
 891
 892 =item Arguments: $path
 893
 894 =item Return value: $base_path
 895
 896 =back
 897
 898 Builds and returns the base path into which to set up the local module
 899 installation. Defaults to C<~/perl5>.
 900
 901 =head2 resolve_home_path
 902
 903 =over 4
 904
 905 =item Arguments: $path
 906
 907 =item Return value: $home_path
 908
 909 =back
 910
 911 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 912 for this purpose. If no definite answer is available, throws an exception.
 913
 914 =head2 resolve_relative_path
 915
 916 =over 4
 917
 918 =item Arguments: $path
 919
 920 =item Return value: $absolute_path
 921
 922 =back
 923
 924 Translates the given path into an absolute path.
 925
 926 =head2 resolve_path
 927
 928 =over 4
 929
 930 =item Arguments: $path
 931
 932 =item Return value: $absolute_path
 933
 934 =back
 935
 936 Calls the following in a pipeline, passing the result from the previous to the
 937 next, in an attempt to find where to configure the environment for a local
 938 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 939 L</resolve_relative_path>. Passes the given path argument to
 940 L</resolve_empty_path> which then returns a result that is passed to
 941 L</resolve_home_path>, which then has its result passed to
 942 L</resolve_relative_path>. The result of this final call is returned from
 943 L</resolve_path>.
 944
 945 =head1 A WARNING ABOUT UNINST=1
 946
 947 Be careful about using local::lib in combination with "make install UNINST=1".
 948 The idea of this feature is that will uninstall an old version of a module
 949 before installing a new one. However it lacks a safety check that the old
 950 version and the new version will go in the same directory. Used in combination
 951 with local::lib, you can potentially delete a globally accessible version of a
 952 module while installing the new version in a local place. Only combine "make
 953 install UNINST=1" and local::lib if you understand these possible consequences.
 954
 955 =head1 LIMITATIONS
 956
 957 =over 4
 958
 959 =item * Directory names with spaces in them are not well supported by the perl
 960 toolchain and the programs it uses.  Pure-perl distributions should support
 961 spaces, but problems are more likely with dists that require compilation. A
 962 workaround you can do is moving your local::lib to a directory with spaces
 963 B<after> you installed all modules inside your local::lib bootstrap. But be
 964 aware that you can't update or install CPAN modules after the move.
 965
 966 =item * Rather basic shell detection. Right now anything with csh in its name is
 967 assumed to be a C shell or something compatible, and everything else is assumed
 968 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 969 not set, a Bourne-compatible shell is assumed.
 970
 971 =item * Kills any existing PERL_MM_OPT or PERL_MB_OPT.
 972
 973 =item * Should probably auto-fixup CPAN config if not already done.
 974
 975 =back
 976
 977 Patches very much welcome for any of the above.
 978
 979 =over 4
 980
 981 =item * On Win32 systems, does not have a way to write the created environment
 982 variables to the registry, so that they can persist through a reboot.
 983
 984 =back
 985
 986 =head1 TROUBLESHOOTING
 987
 988 If you've configured local::lib to install CPAN modules somewhere in to your
 989 home directory, and at some point later you try to install a module with C<cpan
 990 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
 991 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
 992 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
 993 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
 994 you've somehow lost your updated ExtUtils::MakeMaker module.
 995
 996 To remedy this situation, rerun the bootstrapping procedure documented above.
 997
 998 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
 999
1000 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
1001
1002 =head1 ENVIRONMENT
1003
1004 =over 4
1005
1006 =item SHELL
1007
1008 =item COMSPEC
1009
1010 local::lib looks at the user's C<SHELL> environment variable when printing out
1011 commands to add to the shell configuration file.
1012
1013 On Win32 systems, C<COMSPEC> is also examined.
1014
1015 =back
1016
1017 =head1 SEE ALSO
1018
1019 =over 4
1020
1021 =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html>
1022
1023 =back
1024
1025 =head1 SUPPORT
1026
1027 IRC:
1028
1029     Join #local-lib on irc.perl.org.
1030
1031 =head1 AUTHOR
1032
1033 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
1034
1035 auto_install fixes kindly sponsored by http://www.takkle.com/
1036
1037 =head1 CONTRIBUTORS
1038
1039 Patches to correctly output commands for csh style shells, as well as some
1040 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
1041
1042 Doc patches for a custom local::lib directory, more cleanups in the english
1043 documentation and a L<german documentation|POD2::DE::local::lib> contributed by
1044 Torsten Raudssus <torsten@raudssus.de>.
1045
1046 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
1047 things will install properly, submitted a fix for the bug causing problems with
1048 writing Makefiles during bootstrapping, contributed an example program, and
1049 submitted yet another fix to ensure that local::lib can install and bootstrap
1050 properly. Many, many thanks!
1051
1052 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
1053 section. Many thanks!
1054
1055 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
1056
1057 Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced
1058 by a patch from Marco Emilio Poleggi.
1059
1060 Mark Stosberg <mark@summersault.com> provided the code for the now deleted
1061 '--self-contained' option.
1062
1063 Documentation patches to make win32 usage clearer by
1064 David Mertens <dcmertens.perl@gmail.com> (run4flat).
1065
1066 Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc
1067 patches contributed by Breno G. de Oliveira <garu@cpan.org>.
1068
1069 Improvements to stacking multiple local::lib dirs and removing them from the
1070 environment later on contributed by Andrew Rodland <arodland@cpan.org>.
1071
1072 Patch for Carp version mismatch contributed by Hakim Cassimally
1073 <osfameron@cpan.org>.
1074
1075 =head1 COPYRIGHT
1076
1077 Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
1078 listed above.
1079
1080 =head1 LICENSE
1081
1082 This is free software; you can redistribute it and/or modify it under
1083 the same terms as the Perl 5 programming language system itself.
1084
1085 =cut