lib/local/lib.pm

   1 use strict;
   2 use warnings;
   3
   4 package local::lib;
   5
   6 use 5.008001; # probably works with earlier versions but I'm not supporting them
   7               # (patches would, of course, be welcome)
   8
   9 use File::Spec ();
  10 use File::Path ();
  11 use Carp ();
  12 use Config;
  13
  14 our $VERSION = '1.004008'; # 1.4.7
  15 my @KNOWN_FLAGS = (qw/--self-contained/);
  16
  17 sub import {
  18   my ($class, @args) = @_;
  19   @args <= 1 + @KNOWN_FLAGS or die <<'DEATH';
  20 Please see `perldoc local::lib` for directions on using this module.
  21 DEATH
  22
  23   # Remember what PERL5LIB was when we started
  24   my $perl5lib = $ENV{PERL5LIB};
  25
  26   my %arg_store;
  27   for my $arg (@args) {
  28     # check for lethal dash first to stop processing before causing problems
  29     if ($arg =~ /−/) {
  30       die <<'DEATH';
  31 WHOA THERE! It looks like you've got some fancy dashes in your commandline!
  32 These are *not* the traditional -- dashes that software recognizes. You
  33 probably got these by copy-pasting from the perldoc for this module as
  34 rendered by a UTF8-capable formatter. This most typically happens on an OS X
  35 terminal, but can happen elsewhere too. Please try again after replacing the
  36 dashes with normal minus signs.
  37 DEATH
  38     }
  39     elsif(grep { $arg eq $_ } @KNOWN_FLAGS) {
  40       (my $flag = $arg) =~ s/--//;
  41       $arg_store{$flag} = 1;
  42     }
  43     elsif($arg =~ /^--/) {
  44       die "Unknown import argument: $arg";
  45     }
  46     else {
  47       # assume that what's left is a path
  48       $arg_store{path} = $arg;
  49     }
  50   }
  51
  52   if($arg_store{'self-contained'}) {
  53     # The only directories that remain are those that we just defined and those
  54     # where core modules are stored.  We put PERL5LIB first, so it'll be favored
  55     # over privlibexp and archlibexp
  56
  57     @INC = _uniq(
  58       $class->install_base_perl_path($arg_store{path}),
  59       $class->install_base_arch_path($arg_store{path}),
  60       split( $Config{path_sep}, $perl5lib ),
  61       $Config::Config{privlibexp},
  62       $Config::Config{archlibexp}
  63     );
  64
  65     # We explicitly set PERL5LIB here to the above de-duped list to prevent
  66     # @INC from growing with each invocation
  67     $ENV{PERL5LIB} = join( $Config{path_sep}, @INC );
  68   }
  69
  70   $arg_store{path} = $class->resolve_path($arg_store{path});
  71   $class->setup_local_lib_for($arg_store{path});
  72
  73   for (@INC) { # Untaint @INC
  74     next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc.
  75     m/(.*)/ and $_ = $1;
  76   }
  77 }
  78
  79 sub pipeline;
  80
  81 sub pipeline {
  82   my @methods = @_;
  83   my $last = pop(@methods);
  84   if (@methods) {
  85     \sub {
  86       my ($obj, @args) = @_;
  87       $obj->${pipeline @methods}(
  88         $obj->$last(@args)
  89       );
  90     };
  91   } else {
  92     \sub {
  93       shift->$last(@_);
  94     };
  95   }
  96 }
  97
  98 =begin testing
  99
 100 #:: test pipeline
 101
 102 package local::lib;
 103
 104 { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } }
 105 my $foo = bless({}, 'Foo');
 106 Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15);
 107
 108 =end testing
 109
 110 =cut
 111
 112 sub _uniq {
 113     my %seen;
 114     grep { ! $seen{$_}++ } @_;
 115 }
 116
 117 sub resolve_path {
 118   my ($class, $path) = @_;
 119   $class->${pipeline qw(
 120     resolve_relative_path
 121     resolve_home_path
 122     resolve_empty_path
 123   )}($path);
 124 }
 125
 126 sub resolve_empty_path {
 127   my ($class, $path) = @_;
 128   if (defined $path) {
 129     $path;
 130   } else {
 131     '~/perl5';
 132   }
 133 }
 134
 135 =begin testing
 136
 137 #:: test classmethod setup
 138
 139 my $c = 'local::lib';
 140
 141 =end testing
 142
 143 =begin testing
 144
 145 #:: test classmethod
 146
 147 is($c->resolve_empty_path, '~/perl5');
 148 is($c->resolve_empty_path('foo'), 'foo');
 149
 150 =end testing
 151
 152 =cut
 153
 154 sub resolve_home_path {
 155   my ($class, $path) = @_;
 156   return $path unless ($path =~ /^~/);
 157   my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us'
 158   my $tried_file_homedir;
 159   my $homedir = do {
 160     if (
 161         eval { require File::HomeDir }
 162         # Use CPAN::Version if available as it deals correctly with dev releases
 163         && (eval { require CPAN::Version; } ? CPAN::Version->vgt($File::HomeDir::VERSION, 0.65) : $File::HomeDir::VERSION >= 0.65
 164     )) {
 165       $tried_file_homedir = 1;
 166       if (defined $user) {
 167         File::HomeDir->users_home($user);
 168       } else {
 169         File::HomeDir->my_home;
 170       }
 171     } else {
 172       if (defined $user) {
 173         (getpwnam $user)[7];
 174       } else {
 175         if (defined $ENV{HOME}) {
 176           $ENV{HOME};
 177         } else {
 178           (getpwuid $<)[7];
 179         }
 180       }
 181     }
 182   };
 183   unless (defined $homedir) {
 184     Carp::croak(
 185       "Couldn't resolve homedir for "
 186       .(defined $user ? $user : 'current user')
 187       .($tried_file_homedir ? '' : ' - consider installing File::HomeDir')
 188     );
 189   }
 190   $path =~ s/^~[^\/]*/$homedir/;
 191   $path;
 192 }
 193
 194 sub resolve_relative_path {
 195   my ($class, $path) = @_;
 196   $path = File::Spec->rel2abs($path);
 197 }
 198
 199 =begin testing
 200
 201 #:: test classmethod
 202
 203 local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; };
 204 is($c->resolve_relative_path('bar'),'FOObar');
 205
 206 =end testing
 207
 208 =cut
 209
 210 sub setup_local_lib_for {
 211   my ($class, $path) = @_;
 212   $path = $class->ensure_dir_structure_for($path);
 213   if ($0 eq '-') {
 214     $class->print_environment_vars_for($path);
 215     exit 0;
 216   } else {
 217     $class->setup_env_hash_for($path);
 218     @INC = _uniq(split($Config{path_sep}, $ENV{PERL5LIB}), @INC);
 219   }
 220 }
 221
 222 sub modulebuildrc_path {
 223   my ($class, $path) = @_;
 224   File::Spec->catfile($path, '.modulebuildrc');
 225 }
 226
 227 sub install_base_bin_path {
 228   my ($class, $path) = @_;
 229   File::Spec->catdir($path, 'bin');
 230 }
 231
 232 sub install_base_perl_path {
 233   my ($class, $path) = @_;
 234   File::Spec->catdir($path, 'lib', 'perl5');
 235 }
 236
 237 sub install_base_arch_path {
 238   my ($class, $path) = @_;
 239   File::Spec->catdir($class->install_base_perl_path($path), $Config{archname});
 240 }
 241
 242 sub ensure_dir_structure_for {
 243   my ($class, $path) = @_;
 244   unless (-d $path) {
 245     warn "Attempting to create directory ${path}\n";
 246   }
 247   File::Path::mkpath($path);
 248   # Need to have the path exist to make a short name for it, so
 249   # converting to a short name here.
 250   $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32';
 251   my $modulebuildrc_path = $class->modulebuildrc_path($path);
 252   if (-e $modulebuildrc_path) {
 253     unless (-f _) {
 254       Carp::croak("${modulebuildrc_path} exists but is not a plain file");
 255     }
 256   } else {
 257     warn "Attempting to create file ${modulebuildrc_path}\n";
 258     open MODULEBUILDRC, '>', $modulebuildrc_path
 259       || Carp::croak("Couldn't open ${modulebuildrc_path} for writing: $!");
 260     print MODULEBUILDRC qq{install  --install_base  ${path}\n}
 261       || Carp::croak("Couldn't write line to ${modulebuildrc_path}: $!");
 262     close MODULEBUILDRC
 263       || Carp::croak("Couldn't close file ${modulebuildrc_path}: $@");
 264   }
 265
 266   return $path;
 267 }
 268
 269 sub INTERPOLATE_ENV () { 1 }
 270 sub LITERAL_ENV     () { 0 }
 271
 272 sub print_environment_vars_for {
 273   my ($class, $path) = @_;
 274   my @envs = $class->build_environment_vars_for($path, LITERAL_ENV);
 275   my $out = '';
 276
 277   # rather basic csh detection, goes on the assumption that something won't
 278   # call itself csh unless it really is. also, default to bourne in the
 279   # pathological situation where a user doesn't have $ENV{SHELL} defined.
 280   # note also that shells with funny names, like zoid, are assumed to be
 281   # bourne.
 282   my $shellbin = 'sh';
 283   if(defined $ENV{'SHELL'}) {
 284       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'});
 285       $shellbin = $shell_bin_path_parts[-1];
 286   }
 287   my $shelltype = do {
 288       local $_ = $shellbin;
 289       if(/csh/) {
 290           'csh'
 291       } else {
 292           'bourne'
 293       }
 294   };
 295
 296   # Both Win32 and Cygwin have $ENV{COMSPEC} set.
 297   if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') {
 298       my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'});
 299       $shellbin = $shell_bin_path_parts[-1];
 300          $shelltype = do {
 301                  local $_ = $shellbin;
 302                  if(/command\.com/) {
 303                          'win32'
 304                  } elsif(/cmd\.exe/) {
 305                          'win32'
 306                  } elsif(/4nt\.exe/) {
 307                          'win32'
 308                  } else {
 309                          $shelltype
 310                  }
 311          };
 312   }
 313
 314   while (@envs) {
 315     my ($name, $value) = (shift(@envs), shift(@envs));
 316     $value =~ s/(\\")/\\$1/g;
 317     $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value);
 318   }
 319   print $out;
 320 }
 321
 322 # simple routines that take two arguments: an %ENV key and a value. return
 323 # strings that are suitable for passing directly to the relevant shell to set
 324 # said key to said value.
 325 sub build_bourne_env_declaration {
 326   my $class = shift;
 327   my($name, $value) = @_;
 328   return qq{export ${name}="${value}"\n};
 329 }
 330
 331 sub build_csh_env_declaration {
 332   my $class = shift;
 333   my($name, $value) = @_;
 334   return qq{setenv ${name} "${value}"\n};
 335 }
 336
 337 sub build_win32_env_declaration {
 338   my $class = shift;
 339   my($name, $value) = @_;
 340   return qq{set ${name}=${value}\n};
 341 }
 342
 343 sub setup_env_hash_for {
 344   my ($class, $path) = @_;
 345   my %envs = $class->build_environment_vars_for($path, INTERPOLATE_ENV);
 346   @ENV{keys %envs} = values %envs;
 347 }
 348
 349 sub build_environment_vars_for {
 350   my ($class, $path, $interpolate) = @_;
 351   return (
 352     MODULEBUILDRC => $class->modulebuildrc_path($path),
 353     PERL_MM_OPT => "INSTALL_BASE=${path}",
 354     PERL5LIB => join($Config{path_sep},
 355                   $class->install_base_perl_path($path),
 356                   $class->install_base_arch_path($path),
 357                   ($ENV{PERL5LIB} ?
 358                     ($interpolate == INTERPOLATE_ENV
 359                       ? ($ENV{PERL5LIB})
 360                       : (($^O ne 'MSWin32') ? '$PERL5LIB' : '%PERL5LIB%' ))
 361                     : ())
 362                 ),
 363     PATH => join($Config{path_sep},
 364               $class->install_base_bin_path($path),
 365               ($interpolate == INTERPOLATE_ENV
 366                 ? $ENV{PATH}
 367                 : (($^O ne 'MSWin32') ? '$PATH' : '%PATH%' ))
 368              ),
 369   )
 370 }
 371
 372 =begin testing
 373
 374 #:: test classmethod
 375
 376 File::Path::rmtree('t/var/splat');
 377
 378 $c->ensure_dir_structure_for('t/var/splat');
 379
 380 ok(-d 't/var/splat');
 381
 382 ok(-f 't/var/splat/.modulebuildrc');
 383
 384 =end testing
 385
 386 =head1 NAME
 387
 388 local::lib - create and use a local lib/ for perl modules with PERL5LIB
 389
 390 =head1 SYNOPSIS
 391
 392 In code -
 393
 394   use local::lib; # sets up a local lib at ~/perl5
 395
 396   use local::lib '~/foo'; # same, but ~/foo
 397
 398   # Or...
 399   use FindBin;
 400   use local::lib "$FindBin::Bin/../support";  # app-local support library
 401
 402 From the shell -
 403
 404   # Install LWP and it's missing dependencies to the 'my_lwp' directory
 405   perl -MCPAN -Mlocal::lib=my_lwp -e 'CPAN::install(LWP)'
 406
 407   # Install LWP and *all non-core* dependencies to the 'my_lwp' directory
 408   perl -MCPAN -Mlocal::lib=--self-contained,my_lwp -e 'CPAN::install(LWP)'
 409
 410   # Just print out useful shell commands
 411   $ perl -Mlocal::lib
 412   export MODULEBUILDRC=/home/username/perl/.modulebuildrc
 413   export PERL_MM_OPT='INSTALL_BASE=/home/username/perl'
 414   export PERL5LIB='/home/username/perl/lib/perl5:/home/username/perl/lib/perl5/i386-linux'
 415   export PATH="/home/username/perl/bin:$PATH"
 416
 417 =head2 The bootstrapping technique
 418
 419 A typical way to install local::lib is using what is known as the
 420 "bootstrapping" technique.  You would do this if your system administrator
 421 hasn't already installed local::lib.  In this case, you'll need to install
 422 local::lib in your home directory.
 423
 424 1. Download and unpack the local::lib tarball from CPAN (search for "Download"
 425 on the CPAN page about local::lib).  Do this as an ordinary user, not as root
 426 or administrator.  Unpack the file in your home directory or in any other
 427 convenient location.
 428
 429 2. Run this:
 430
 431   perl Makefile.PL --bootstrap
 432
 433 If the system asks you whether it should automatically configure as much
 434 as possible, you would typically answer yes.
 435
 436 3. Run this:
 437
 438   make test && make install
 439
 440 4. Arrange for Perl to use your own packages instead of the system
 441 packages.  If you are using bash, you can do this as follows:
 442
 443   echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc
 444
 445 If you are using C shell, you can do this as follows:
 446
 447   /bin/csh
 448   echo $SHELL
 449   /bin/csh
 450   perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc
 451
 452 You can also pass --bootstrap=~/foo to get a different location -
 453
 454   perl Makefile.PL --bootstrap=~/foo
 455   make test && make install
 456
 457   echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc
 458
 459 After writing your shell configuration file, be sure to re-read it to get the
 460 changed settings into your current shell's environment. Bourne shells use C<.
 461 ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>. Replace .bashrc or
 462 .cshrc with the name of the file you wrote above with the echo command.
 463
 464 If you're on a slower machine, or are operating under draconian disk space
 465 limitations, you can disable the automatic generation of manpages from POD when
 466 installing modules by using the C<--no-manpages> argument when bootstrapping:
 467
 468   perl Makefile.PL --bootstrap --no-manpages
 469
 470 If you want to install multiple Perl module environments, say for application evelopment,
 471 install local::lib globally and then:
 472
 473   cd ~/mydir1
 474   perl -Mlocal::lib=./
 475   eval $(perl -Mlocal::lib=./)  ### To set the environment for this shell alone
 476   printenv  ### You will see that ~/mydir1 is in the PERL5LIB
 477   perl -MCPAN -e install ...    ### whatever modules you want
 478   cd ../mydir2
 479   ... REPEAT ...
 480
 481 For multiple environments for multiple apps you may need to include a modified
 482 version of the C<< use FindBin >> instructions in the "In code" sample above.
 483 If you did something like the above, you have a set of Perl modules at C<<
 484 ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>,
 485 you need to tell it where to find the modules you installed for it at C<<
 486 ~/mydir1/lib >>.
 487
 488 In C<< ~/mydir1/scripts/myscript.pl >>:
 489
 490   use strict;
 491   use warnings;
 492   use local::lib "$FindBin::Bin/..";  ### points to ~/mydir1 and local::lib finds lib
 493   use lib "$FindBin::Bin/../lib";     ### points to ~/mydir1/lib
 494
 495 Put this before any BEGIN { ... } blocks that require the modules you installed.
 496
 497 =head2 Differences when using this module under Win32
 498
 499   C:\>perl -Mlocal::lib
 500   set MODULEBUILDRC=C:\DOCUME~1\ADMINI~1\perl5\.modulebuildrc
 501   set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5
 502   set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread
 503   set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH%
 504
 505     ### To set the environment for this shell alone
 506   C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\temp.bat
 507   ### instead of $(perl -Mlocal::lib=./)
 508
 509 If you want the environment entries to persist, you'll need to add then to the
 510 Control Panel's System applet yourself at the moment.
 511
 512 The "~" is translated to the user's profile directory (the directory named for
 513 the user under "Documents and Settings" (Windows XP or earlier) or "Users"
 514 (Windows Vista or later) unless $ENV{HOME} exists. After that, the home
 515 directory is translated to a short name (which means the directory must exist)
 516 and the subdirectories are created.
 517
 518 =head1 RATIONALE
 519
 520 The version of a Perl package on your machine is not always the version you
 521 need.  Obviously, the best thing to do would be to update to the version you
 522 need.  However, you might be in a situation where you're prevented from doing
 523 this.  Perhaps you don't have system administrator privileges; or perhaps you
 524 are using a package management system such as Debian, and nobody has yet gotten
 525 around to packaging up the version you need.
 526
 527 local::lib solves this problem by allowing you to create your own directory of
 528 Perl packages downloaded from CPAN (in a multi-user system, this would typically
 529 be within your own home directory).  The existing system Perl installation is
 530 not affected; you simply invoke Perl with special options so that Perl uses the
 531 packages in your own local package directory rather than the system packages.
 532 local::lib arranges things so that your locally installed version of the Perl
 533 packages takes precedence over the system installation.
 534
 535 If you are using a package management system (such as Debian), you don't need to
 536 worry about Debian and CPAN stepping on each other's toes.  Your local version
 537 of the packages will be written to an entirely separate directory from those
 538 installed by Debian.
 539
 540 =head1 DESCRIPTION
 541
 542 This module provides a quick, convenient way of bootstrapping a user-local Perl
 543 module library located within the user's home directory. It also constructs and
 544 prints out for the user the list of environment variables using the syntax
 545 appropriate for the user's current shell (as specified by the C<SHELL>
 546 environment variable), suitable for directly adding to one's shell
 547 configuration file.
 548
 549 More generally, local::lib allows for the bootstrapping and usage of a
 550 directory containing Perl modules outside of Perl's C<@INC>. This makes it
 551 easier to ship an application with an app-specific copy of a Perl module, or
 552 collection of modules. Useful in cases like when an upstream maintainer hasn't
 553 applied a patch to a module of theirs that you need for your application.
 554
 555 On import, local::lib sets the following environment variables to appropriate
 556 values:
 557
 558 =over 4
 559
 560 =item MODULEBUILDRC
 561
 562 =item PERL_MM_OPT
 563
 564 =item PERL5LIB
 565
 566 =item PATH
 567
 568 PATH is appended to, rather than clobbered.
 569
 570 =back
 571
 572 These values are then available for reference by any code after import.
 573
 574 =head1 METHODS
 575
 576 =head2 ensure_directory_structure_for
 577
 578 =over 4
 579
 580 =item Arguments: path
 581
 582 =back
 583
 584 Attempts to create the given path, and all required parent directories. Throws
 585 an exception on failure.
 586
 587 =head2 print_environment_vars_for
 588
 589 =over 4
 590
 591 =item Arguments: path
 592
 593 =back
 594
 595 Prints to standard output the variables listed above, properly set to use the
 596 given path as the base directory.
 597
 598 =head2 setup_env_hash_for
 599
 600 =over 4
 601
 602 =item Arguments: path
 603
 604 =back
 605
 606 Constructs the C<%ENV> keys for the given path, by calling
 607 C<build_environment_vars_for>.
 608
 609 =head2 install_base_perl_path
 610
 611 =over 4
 612
 613 =item Arguments: path
 614
 615 =back
 616
 617 Returns a path describing where to install the Perl modules for this local
 618 library installation. Appends the directories C<lib> and C<perl5> to the given
 619 path.
 620
 621 =head2 install_base_arch_path
 622
 623 =over 4
 624
 625 =item Arguments: path
 626
 627 =back
 628
 629 Returns a path describing where to install the architecture-specific Perl
 630 modules for this local library installation. Based on the
 631 L</install_base_perl_path> method's return value, and appends the value of
 632 C<$Config{archname}>.
 633
 634 =head2 install_base_bin_path
 635
 636 =over 4
 637
 638 =item Arguments: path
 639
 640 =back
 641
 642 Returns a path describing where to install the executable programs for this
 643 local library installation. Based on the L</install_base_perl_path> method's
 644 return value, and appends the directory C<bin>.
 645
 646 =head2 modulebuildrc_path
 647
 648 =over 4
 649
 650 =item Arguments: path
 651
 652 =back
 653
 654 Returns a path describing where to install the C<.modulebuildrc> file, based on
 655 the given path.
 656
 657 =head2 resolve_empty_path
 658
 659 =over 4
 660
 661 =item Arguments: path
 662
 663 =back
 664
 665 Builds and returns the base path into which to set up the local module
 666 installation. Defaults to C<~/perl5>.
 667
 668 =head2 resolve_home_path
 669
 670 =over 4
 671
 672 =item Arguments: path
 673
 674 =back
 675
 676 Attempts to find the user's home directory. If installed, uses C<File::HomeDir>
 677 for this purpose. If no definite answer is available, throws an exception.
 678
 679 =head2 resolve_relative_path
 680
 681 =over 4
 682
 683 =item Arguments: path
 684
 685 =back
 686
 687 Translates the given path into an absolute path.
 688
 689 =head2 resolve_path
 690
 691 =over 4
 692
 693 =item Arguments: path
 694
 695 =back
 696
 697 Calls the following in a pipeline, passing the result from the previous to the
 698 next, in an attempt to find where to configure the environment for a local
 699 library installation: L</resolve_empty_path>, L</resolve_home_path>,
 700 L</resolve_relative_path>. Passes the given path argument to
 701 L</resolve_empty_path> which then returns a result that is passed to
 702 L</resolve_home_path>, which then has its result passed to
 703 L</resolve_relative_path>. The result of this final call is returned from
 704 L</resolve_path>.
 705
 706 =head1 A WARNING ABOUT UNINST=1
 707
 708 Be careful about using local::lib in combination with "make install UNINST=1".
 709 The idea of this feature is that will uninstall an old version of a module
 710 before installing a new one. However it lacks a safety check that the old
 711 version and the new version will go in the same directory. Used in combination
 712 with local::lib, you can potentially delete a globally accessible version of a
 713 module while installing the new version in a local place. Only combine "make
 714 install UNINST=1" and local::lib if you understand these possible consequences.
 715
 716 =head1 LIMITATIONS
 717
 718 Rather basic shell detection. Right now anything with csh in its name is
 719 assumed to be a C shell or something compatible, and everything else is assumed
 720 to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is
 721 not set, a Bourne-compatible shell is assumed.
 722
 723 Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you
 724 have CPANPLUS installed.
 725
 726 Kills any existing PERL5LIB, PERL_MM_OPT or MODULEBUILDRC.
 727
 728 Should probably auto-fixup CPAN config if not already done.
 729
 730 Patches very much welcome for any of the above.
 731
 732 On Win32 systems, does not have a way to write the created environment variables
 733 to the registry, so that they can persist through a reboot.
 734
 735 =head1 TROUBLESHOOTING
 736
 737 If you've configured local::lib to install CPAN modules somewhere in to your
 738 home directory, and at some point later you try to install a module with C<cpan
 739 -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have
 740 permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at
 741 /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an
 742 error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then
 743 you've somehow lost your updated ExtUtils::MakeMaker module.
 744
 745 To remedy this situation, rerun the bootstrapping procedure documented above.
 746
 747 Then, run C<rm -r ~/.cpan/build/Foo-Bar*>
 748
 749 Finally, re-run C<cpan -i Foo::Bar> and it should install without problems.
 750
 751 =head1 ENVIRONMENT
 752
 753 =over 4
 754
 755 =item SHELL
 756
 757 =item COMSPEC
 758
 759 local::lib looks at the user's C<SHELL> environment variable when printing out
 760 commands to add to the shell configuration file.
 761
 762 On Win32 systems, C<COMSPEC> is also examined.
 763
 764 =back
 765
 766 =head1 AUTHOR
 767
 768 Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/
 769
 770 auto_install fixes kindly sponsored by http://www.takkle.com/
 771
 772 =head1 CONTRIBUTORS
 773
 774 Patches to correctly output commands for csh style shells, as well as some
 775 documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>.
 776
 777 '--self-contained' feature contributed by Mark Stosberg <mark@summersault.com>.
 778
 779 Ability to pass '--self-contained' without a directory inspired by frew on
 780 irc.perl.org/#catalyst.
 781
 782 Doc patches for a custom local::lib directory contributed by Torsten Raudssus
 783 <torsten@raudssus.de>.
 784
 785 Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring
 786 things will install properly, submitted a fix for the bug causing problems with
 787 writing Makefiles during bootstrapping, contributed an example program, and
 788 submitted yet another fix to ensure that local::lib can install and bootstrap
 789 properly. Many, many thanks!
 790
 791 pattern of Freenode IRC contributed the beginnings of the Troubleshooting
 792 section. Many thanks!
 793
 794 Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>.
 795
 796 =head1 COPYRIGHT
 797
 798 Copyright (c) 2007 - 2009 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as
 799 listed above.
 800
 801 =head1 LICENSE
 802
 803 This library is free software and may be distributed under the same terms
 804 as perl itself.
 805
 806 =cut
 807
 808 1;